Excel sayfasını kaydeden kim.

[kaydoldum]

Biz bir excel sayfasını 5 kişi ayrı zamanlarda açıp üzerine kayıt oluşturuyoruz. Acaba bizim ayrı bilgisayarlardan hangisinden açılıp da kayıt oluşturulduğunu ayı sayfa üzerine kayıt edebileceğimiz. Mesel bizim bilgisayarların harddisk nosu bilgisayar kullanıcısı adı veya herhangi bir ayırtedici değer'e bakarak hücre içersine o değerin yazıldığı macro varmıdır. Kısaca anlatmak gerekirse hangi bilgisayardan kaydedildiyse o bilgisayarın harddisk nosu falan sayfanın herhangi belirli bir hücresine kaydedilebilir mi ?

 

[kaydoldum]

Her bir kayıt için tek tek olmak üzere

 

[alpi]

Aşağıdaki kodu ThisWorkbook kod editorüne yazınız

Option Explicit
Sub KayıtKontrol()
    Dim str As String
    Dim i As Long
    Dim No As Long
    Dim KaydıYapan As String
    Dim Say As Long
    i = 199
    str = String$(200, 0)
    No = GetUserName(str, i)
    If No <> 0 Then KaydıYapan = Left$(str, i) Else KaydıYapan = ""
    Say = WorksheetFunction.CountA(ThisWorkbook.Sheets("Sayfa1").Range("A1:A65500")) + 1
    ThisWorkbook.Sheets("Sayfa1").Range("A" & Say) = KaydıYapan
End Sub
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    KayıtKontrol
End Sub

Aşağıdaki Api yi de yeni bir modül içerisine yazınız

Declare Function GetUserName Lib "advapi32.dll" Alias _
"GetUserNameA" (ByVal lpBuffer As String, nSize As Long) _
As Long

Bu kod Sayfa1 adlı sayfanın A sutünuna bilgisayar oturumunu açan kullanıcının adını yazar. Sayfa1 yerine başka bir sayfaya kaydedilmesini isterseniz Kodlardaki Sayfa1 i kendi sayfa isminizle değiştirin.

 

[kaydoldum]

database adındaki sayfaya userform ile kayıt yapıyorum. Her kayıt sonrası bir alttakine kayıt yapıyor. yapılan her kaydın karşısına kim kaydetmişse birde o kullanıcı ile ilgili bilgiyi nasıl yazdırabilirim. L sütunundan itibaren yazacak

 

[Kemal Demir]

Aşagıdaki kod Son olarak yazdıgınız ile ilgilidir.Umarım yardımcı olabilmişimdir.

sonsat = WorksheetFunction.CountA(ActiveSheet.Range("a1:a65536")) + 1
Range("L" & sonsat).Value = Application.UserName & "-" & Date

NOT:Kim saat kaçta kaydetmiş bilgisi işlenmiştir.

 

[kaydoldum]

Bu arada bununla ilgili bir sorum daha var.

Bu kodlar ile username "kullanıcı adı" kaydı oluşuyor. Bunu denedim ve oldu. Tüm yardımlarınız ve bilgilendirmeniz için teşekkürler.Şimdi yapılması gereken ise, önceden veri girişi için oluşturmuş olduğum frmparts adındaki bir userform üzerinde bulunan textbox'da username'in görüntülenmesi olacak. Bunu hangi kodlarla başarabilirim. İstediğim şu ki, bu kayıt sayfa üzerindeki satır ve sütunlara değil de tek seferde userform üzerindeki textbox üzerinde görüntülensin. Ben ordan kaydet yaptığımda veriyi satıra veya sütuna yazdıracağım. Yukarıdaki kodlar değiştirilerek bu yapılabilirmi fazla kısımlar çıkartılabilir mi ?

 

[alpi]

Oturum açan Kullanıcı adını form üzerindeki metin kutusuna yazdırmak için aşağıdaki kodları kullanabilirsiniz.

Option Explicit
Private Declare Function GetUserName Lib "advapi32.dll" Alias _
"GetUserNameA" (ByVal lpBuffer As String, nSize As Long) _
As Long
Function KullanıcıAdı() As String
    Dim str As String
    Dim i As Long
    Dim No As Long
    Dim KaydıYapan As String
    i = 199
    str = String$(200, 0)
    No = GetUserName(str, i)
    If No <> 0 Then KaydıYapan = Left$(str, i) Else KaydıYapan = ""
    KullanıcıAdı = KaydıYapan
End Function
Private Sub UserForm_Initialize()
    TextBox1.Text = KullanıcıAdı
End Sub

 

[kaydoldum]

Çooooooook sağolun.