Aktif Excel Sekmesini Farklı Çalışma Kitabı Olarak Kaydet Kod Yardımı

[Believing]

Sayın Uzman Arkadaşlar,

Aşağıdaki kod yardımı ile aktif sayfayı kitap adı, sayfa adı ve kayıt tarihi şeklinde, kitabın bulunduğu klasör içine Pdf formatında kaydediyorum.

Sub PdfKaydet()
yol = ThisWorkbook.Path & "\"
isim = CreateObject("Scripting.FileSystemObject").GetBaseName(ThisWorkbook.Name) & " - " & _
        ThisWorkbook.ActiveSheet.Name & " - " & Format(Now, "ddmmyyyy_hhss") & ".pdf"
ThisWorkbook.ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=yol & isim
End Sub

Yukarıdaki işlemi Excel (.xlsx) formatında kayıt etmek için, mevcut kodlarda nasıl bir düzenleme yapmalıyım.
Konuya hakim uzman arkadaşların yardımlarını rica ederim.

Saygılarımla,
Ömer Ali ÜZÜMCÜ

 

[Korhan Ayhan]

Deneyiniz.

Sub XLSXKaydet()
    Yol = ThisWorkbook.Path & "\"
    isim = CreateObject("Scripting.FileSystemObject").GetBaseName(ThisWorkbook.Name) & " - " & _
            ThisWorkbook.ActiveSheet.Name & " - " & Format(Now, "ddmmyyyy_hhnn") & ".xlsx"
    ThisWorkbook.ActiveSheet.Copy
    Application.DisplayAlerts = False
    ActiveWorkbook.Close True, Yol & isim
    Application.DisplayAlerts = True
End Sub

 

[muhasebeciyiz]

Deneyiniz.

Sub XLSXKaydet()
    Yol = ThisWorkbook.Path & "\"
    isim = CreateObject("Scripting.FileSystemObject").GetBaseName(ThisWorkbook.Name) & " - " & _
            ThisWorkbook.ActiveSheet.Name & " - " & Format(Now, "ddmmyyyy_hhnn") & ".xlsx"
    ThisWorkbook.ActiveSheet.Copy
    Application.DisplayAlerts = False
    ActiveWorkbook.Close True, Yol & isim
    Application.DisplayAlerts = True
End Sub

Korhan bey ;
Aktif sayfayı makrosuz ve formülsüz kayıt yapabilmek için yardımcı olurmusunuz ? Saygılar...

 

[Believing]

Sayın Korhan Ayhan ve Muhasebeciyİz,

Konuya gösterdiğiniz ilgi ve yardım için sizlere çok teşekkür ederim.
ALLAH sizlerden razı olsun.

Saygılarımla,
Ömer Ali ÜZÜMCÜ

 

[tugkan]

Korhan bey ;
Aktif sayfayı makrosuz ve formülsüz kayıt yapabilmek için yardımcı olurmusunuz ? Saygılar...

Merhaba,
Sadece aktif sayfayı makrosuz ve formülsüz farklı çalışma kitabı olarak kaydetmek için, sayfa adına sağ tuşla tıklayıp => taşı veya kopyala=> yukarıdaki kitap yazan yerden ise yeni kitabı seçip kopyalarsanız sanırım isteğiniz gerçekleşir.

 

[Korhan Ayhan]

Korhan bey ;
Aktif sayfayı makrosuz ve formülsüz kayıt yapabilmek için yardımcı olurmusunuz ? Saygılar...

Merhaba,

Aşağıdaki kod yeni versiyonlara göre dosyayı makrosuz ve formülsüz kayıt eder.

Ben hücre aralığı olarak A1:Z100 olarak ayarladım. Siz kendi sayfanıza göre uyarlarsınız.

Sub XLSXKaydet()
    Yol = ThisWorkbook.Path & "\"
    isim = CreateObject("Scripting.FileSystemObject").GetBaseName(ThisWorkbook.Name) & " - " & _
            ThisWorkbook.ActiveSheet.Name & " - " & Format(Now, "ddmmyyyy_hhnn") & ".xlsx"
    Application.Calculate
    Application.Calculation = xlCalculationManual
    ThisWorkbook.ActiveSheet.Copy
    ActiveSheet.Range("A1:Z100").Copy
    ActiveSheet.Range("A1:Z100").PasteSpecial xlValues
    Range("A1").Select
    Application.DisplayAlerts = False
    ActiveWorkbook.Close True, Yol & isim
    Application.DisplayAlerts = True
End Sub

Eğer eski sürüm excel kullanıyorsanız aşağıdaki kodu deneyebilirsiniz. Tabi ki kodun sağlıklı çalışması için resimdeki ayarı yapmanız gerekiyor.

Sub XLSXKaydet()
    Yol = ThisWorkbook.Path & "\"
    isim = CreateObject("Scripting.FileSystemObject").GetBaseName(ThisWorkbook.Name) & " - " & _
            ThisWorkbook.ActiveSheet.Name & " - " & Format(Now, "ddmmyyyy_hhnn")
    Application.Calculate
    Application.Calculation = xlCalculationManual
    ThisWorkbook.ActiveSheet.Copy
    ActiveSheet.Range("A1:Z100").Copy
    ActiveSheet.Range("A1:Z100").PasteSpecial xlValues
    Range("A1").Select
    With ActiveWorkbook.VBProject.VBComponents(ActiveSheet.CodeName).CodeModule
        .DeleteLines 1, .CountOfLines
    End With
    Application.DisplayAlerts = False
    ActiveWorkbook.SaveAs Yol & isim, -4143
    ActiveWorkbook.Close
    Application.DisplayAlerts = True
End Sub

 

[muhasebeciyiz]

Teşekkürler Korhan bey ;