Alt bilgi değişikliği

[gkocsoy]

Yüzlerce word dosyam var bunların alt bilgisinde adres bilgileri mevcut tek tek dosyaları açmadan bu bilgiyi nasıl güncelleyebilirim.
Bir de bütün bu dosyalardaki alt bilgiye yeni bir bilgiyi toptan nasıl girebilirim.
Saygılarımla.....

 

[MAD_QUEEN]

sanırım bu istediğiniz şeyi ayrı ayrı dosyalarda yapmak imkansız.Ama yinede ümitsizliğe kapılmayın. Kolay bi yöntem bulursam size bildiririm.

 

[PrivateSub]

Bu Word makrosu, "C:\WordDocs" dizininde tüm Word belgelerindeki alt bilgileri değiştirir ...

Sub AltBilgiGuncelle()
    Dim strPath As String
    Dim objSection As Section
    Dim objFooter As HeaderFooter
    Dim i As Long
    
    strPath = "C:\WordDocs"
    If Dir(strPath, vbDirectory) = Empty Then
        MsgBox strPath & " klasoru bulunamadi ..."
        Exit Sub
    End If
    Application.ScreenUpdating = False
    With Application.FileSearch
        .NewSearch
        .LookIn = strPath
        .FileName = "*.doc"
        .SearchSubFolders = True
        .Execute
        For i = 1 To .FoundFiles.Count
            Documents.Open .FoundFiles(i)
            For Each objSection In Documents(.FoundFiles(i)).Sections
                For Each objFooter In objSection.Footers
                    If objFooter.Exists Then
                         objFooter.Range.Text = "Bu yeni alt bilgidir ..."
                         objFooter.Range.Font.Size = 8
                         objFooter.Range.ParagraphFormat.Alignment = wdAlignParagraphRight
                        With objFooter.Range.Borders(wdBorderTop)
                            .LineStyle = wdLineStyleSingle
                            .LineWidth = wdLineWidth050pt
                            .Color = wdColorAutomatic
                        End With
                    End If
                Next
            Next
        Documents(.FoundFiles(i)).Close SaveChanges:=True
        Next
    End With
    Application.ScreenUpdating = True
End Sub

 

[dEdE]

Sayın MAD_QUEEN,
Sayın PrivateSub,
Bu soru Word sorusu, dolayısı ile burada olmaması lazım. Kaldı ki, arkadaşımız aynı soruyu word başlığı altında da sormuş. Burada yanıtlamak yerine arkadaşımızı Forum Kuralları hakkında uyarmak forumun düzeni açısından daha isabetli olurdu diye düşünüyorum.
Saygılar.

Not: Başlık doğru bölüme taşınmıştır. (mehmett)