ayın iş günlerine aynı tabloyu otomatik olarak kopyalamak

[drkerim]

Değerli liste üyeleri

Bir ayın (örnek haziran) her işgünü için ayrı ayrı sayfalar oluşturup aynı tabloyu (örneğin ekteki) her bir iş gününe kopyalamak ve kopyalarken de tablonun içindeki tarih hücresine o günün tarihini yazdırmak için bir makro yapmak veya kod yazmak mümkünmüdür ? Bana bu konuda yardım sağlayacak bir üstad arıyorum.

Saygılarımla,

 

[Korhan Ayhan]

Selamlar,

Aşağıdaki kodu boş bir modüle ekleyip denermisiniz.

Option Explicit
 
Sub İŞ_GÜNLERİ_İÇİN_SAYFA_OLUŞTUR()
    Dim AY As Variant, YIL As Variant
    Dim İLK_TARİH As Date, SON_TARİH As Date, GÜN As Date
    
    AY = Application.InputBox("Oluşturmak istediğiniz ay bilgisini giriniz !", , Format(Date, "mm"))
    If AY = False Or AY = "" Then Exit Sub
    
    YIL = Application.InputBox("Oluşturmak istediğiniz yıl bilgisini giriniz !", , Format(Date, "yyyy"))
    If YIL = False Or YIL = "" Then Exit Sub
    
    İLK_TARİH = DateSerial(YIL, AY, 1)
    SON_TARİH = DateSerial(Year(İLK_TARİH), Month(İLK_TARİH) + 1, 0)
    
    Application.ScreenUpdating = False
    
    For GÜN = İLK_TARİH To SON_TARİH
        If Weekday(GÜN, vbMonday) <= 5 Then
            If Not SAYFA_VARMI(CStr(GÜN)) Then
            Sheets("Sayfa1").Copy After:=Sheets(Worksheets.Count)
            ActiveSheet.Name = GÜN
            Range("D1") = GÜN
            End If
        End If
    Next
    
    Application.ScreenUpdating = True
    
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub
 
Function SAYFA_VARMI(SAYFA_ADI As String) As Boolean
    On Error Resume Next
    SAYFA_VARMI = CBool(Len(Worksheets(SAYFA_ADI).Name) > 0)
End Function

 

[drkerim]

Korhan bey,

Çok tşkler, modül çalışıyor. Cehaletimi bağışlarsanız şayet, benim tabloyu her iş günü için oluşturduğu sayfaya kopyalamasını istemek mümkünmü dür ?

Saygılarımla,

 

[Korhan Ayhan]

Selamlar,

Örnek dosyanızdaki "Sayfa1" isimli sayfa sizin şablon sayfanızdır. Kod içinde kırmızı renkli bölümü kendi dosyanızdaki şablon sayfanızın adına göre değiştirmeniz gerekiyor.