AYRINTILI FATURA RAPORUNDA KDV AYRIMI ve YİNELENEN SATIRLARIN TEKE DÜŞÜRÜLMESİ

[toprak2515]

Elimde E-fatura gönderim ve alım raporu bulunmakta. Bu rapor iki farklı sayfadan oluşuyor. Sayfalardan biri fatura toplamına göre düzenlenmiş, diğeri satır ayrıntılı bir şekilde hazırlanmış. Benim istediğim bu ayrıntılı olan sayfada farklı kdv değeri olan satırları başka bir sayfada ayrı ayrı matrahlarıyla birlikte tek satırda görmek. Yardımcı olursanız sevinirim.

 

[veyselemre]

Sayfa1 ekleyin, Giden faturaların matrah ve kdv lerini birleştirir.

Sub test()
    
    Dim con As Object, rs As Object
    Dim sql As String

    Set con = CreateObject("ADODB.Connection")
    Set rs = CreateObject("ADODB.Recordset")
    con.Open = "Provider=Microsoft.Ace.OLEDB.12.0;Data Source=" & ThisWorkbook.FullName & _
               ";Extended Properties=""Excel 12.0;HDR=YES;Imex=1;"""

    sql = "SELECT TARİH, [FATURA NO],KİME,'Toptan Satış Faturası', " & _
          "SUM(IIF([KDV ORANI]=0, [SATIR TOPLAMI], 0)) AS MTRH0, " & _
          "SUM(IIF([KDV ORANI]=1, [SATIR TOPLAMI], 0)) AS MTRH1, SUM(IIF([KDV ORANI]=1, [KDV], 0)) as KDV1, " & _
          "SUM(IIF([KDV ORANI]=8, [SATIR TOPLAMI], 0)) AS MTRH8, SUM(IIF([KDV ORANI]=8, [KDV], 0)) as KDV8, " & _
          "SUM(IIF([KDV ORANI]=18, [SATIR TOPLAMI], 0)) AS MTRH18, SUM(IIF([KDV ORANI]=18, [KDV], 0)) as KDV18, " & _
          "(MTRH0+MTRH1+MTRH8+MTRH18) AS MATRAHTOP, " & _
          "(KDV1+KDV8+KDV18) AS KDVTOP, " & _
          "(MATRAHTOP+KDVTOP) AS TOPLAMTUT " & _
          "FROM [GİDEN$] GROUP BY TARİH, [FATURA NO], KİME"
    rs.Open sql, con, 1, 1
    With Sheets("Sayfa1")
        .Cells.ClearContents
        .Range("A1").Resize(, 14).Value = Array("Tarihi", "Fatura No.", "CH Unvani", "Fatura Türü", "%0 Matrah", "%1 Matrah", "%1 KDV", "%8 Matrah", "%8 KDV", "%18 Matrah", "%18 KDV", "Matrah Toplam", "KDV Toplam", "Fatura Toplam")
        .Range("A2").CopyFromRecordset rs
    End With

    con.Close
    Set con = Nothing
    Set rs = Nothing

End Sub

 

[toprak2515]

Çok teşekkür ederim. Emeğinize sağlık. Beni büyük bir yükten kurtardınız.