Başka sayfaya kayıt

[A1982K58]

arkadaşlar excel çok yeni olduğum için biraz öğrenmeye çalışağım. Ben excel sayfasındaki c sütunundaki (ab) yazdıklarım yıla göre sayfa2 gitmesini, (ac) yazdıklarımı yine yıla göre sayfa3 gitmesini istiyorum. bunu açıklamalı olarak cevaplandırırsanız çok memnun kalacağım. şimdiden ilginize teşekkür ederim.

 

[Necdet]

Başka Sayfaya Aktarma

İyi akşamlar,

Public Sub Aktar()
Set s1 = Sheets("Sayfa1")   's1 diye kullandığımız değer Sheets("Sayfa1") anlamına gelir
Set s2 = Sheets("Sayfa2")
Set s3 = Sheets("Sayfa3")
s1.Activate                     'Sayfa1 i seçmiş oluyoruz
s2.[A2:C65536].ClearContents    'Sayfa2 nin değerleri siliniyor
s3.[A2:C65536].ClearContents    'Sayfa3 ün değerleri siliniyor
For i = 2 To [A65536].End(xlUp).Row
    If Cells(i, "C") = "ab" Then
       Adet1 = Adet1 + 1
       Satır = s2.[A65536].End(3).Row + 1
       Range("A" & i & ":C" & i).Copy s2.Cells(Satır, "A")
       '----- Ya da şöyle aktarılır ------------------
       '    s2.cells(Satır, "A") = cells(i, "A")
       '    s2.cells(Satır, "B") = cells(i, "B")
       '    s2.cells(Satır, "C") = cells(i, "C")
       '----------------------------------------------
     ElseIf Cells(i, "C") = "ac" Then
        Adet2 = Adet2 + 1
        Satır = s3.[A65536].End(3).Row + 1
        Range("A" & i & ":C" & i).Copy s3.Cells(Satır, "A")
       '----- Ya da şöyle aktarılır ------------------
       '    s3.cells(Satır, "A") = cells(i, "A")
       '    s3.cells(Satır, "B") = cells(i, "B")
       '    s3.cells(Satır, "C") = cells(i, "C")
       '----------------------------------------------
    End If
     
Next i
s2.Activate     'Sayfa2 seçiliyor, aktive ediliyor
Range("A2:C" & [A65536].End(3).Row).Sort Key1:=[A2] '-- Sayfa2 Sıralanmıştır
s3.Activate     'Sayfa3 seçiliyor, aktive ediliyor
Range("A2:C" & [A65536].End(3).Row).Sort Key1:=[A2] '-- Sayfa3 Sıralanmıştır
s1.Activate
MsgBox Adet1 & " Adet Kayıt Sayfa2'ye, " & Adet2 & " Adet Kayıt Sayfa3'e Aktarılmıştır"
End Sub