Belli bir süre sonunda excelin kapanması

[jacob90]

Merhabalar
Kullandığım excel dosyasının belli süre sonunda (örn 15 dakika sonra) herhangi bir uyarı vermeden kaydedip kapanmasını istiyorum. Tüm excellerin değil. Sadece kodu yazacağım excelin. Aşağıdaki kodu kullandım fakat uyarı veriyor. Yardımcı olursanız sevinirim.

Sub Autpen()
Application.DisplayAlerts = False

Application.OnTime Now + TimeValue("00:01:00"), "Kapat"

ThisWorkbook.Save
Application.DisplayAlerts = True
End Sub
Sub Kapat()
ThisWorkbook.Close
End Sub

 

[PLİNT]

Merhaba
Aşağıdaki gibi yeterli olacaktır.

[SIZE="2"]Sub Auto_Open()
Application.OnTime Now + TimeValue("00:15:00"), "Kapat"
End Sub

Sub Kapat()
ThisWorkbook.Close [COLOR="Blue"]savechanges:=True[/COLOR]
End Sub
[/SIZE]

 

[jacob90]

Çok teşekkürler geri dönüşünüz için. Kodu çalıştırdığımda excel görüntüsü kalıyor ekranda.Birde bu kod o o excel dosyasında hareket olmadığı zaman çalışacak değil mi?

 

[PLİNT]

Çok teşekkürler geri dönüşünüz için. Kodu çalıştırdığımda excel görüntüsü kalıyor ekranda.Birde bu kod o o excel dosyasında hareket olmadığı zaman çalışacak değil mi?

Merhaba
Yukarıdaki kodlarla olmaz, aşağıdaki gibi kullanın.
Kırmızı başlık altındakilerden istemediğinizi silersiniz

"BuÇalışma" ("Thisworkbook") kod sayfasına:

[SIZE="2"]Private Sub Workbook_Open()
Call basla
End Sub


[COLOR="red"]'Hücre içeriği değiştikçe zaman kazan[/COLOR]
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Call dur
Call basla


End Sub


[COLOR="red"]'hücre seçtikçe zaman kazan[/COLOR]
Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
Call dur
Call basla

End Sub

[COLOR="red"]'sayfa değiştikçe zaman kazan[/COLOR]
Private Sub Workbook_SheetActivate(ByVal Sh As Object)
Call dur
Call basla

End Sub[/SIZE]

"Modül1" kod sayfasına:

[SIZE="2"]Private g
Sub basla()
If g <> Empty Then
If Application.Workbooks.Count = 1 Then Application.Quit
ThisWorkbook.Close savechanges:=True
End If
g = Now + TimeSerial([COLOR="Red"]0, 15, 0[/COLOR])
Application.OnTime g, "basla", , True
End Sub

Sub dur()
If g <> Empty Then
Application.OnTime g, "basla", , False
g = Empty
End If
End Sub[/SIZE]

Ek dosyada kapanış 10 saniyeye ayarlı
http://s3.dosya.tc/server13/hfn4xm/Zamanli_Kapat.zip.html

 

[jacob90]

Çok teşekkürler emeğiniz için. Tam olarak istediğimde buydu.