belli kritere göre bir veri aralığında benzersiz kayıtlar

[modoste]

merhaba sayın hocalarım dosya eklemden (dosya boyutu büyük)birşey yapılabilirmi merak ediyorum

mesela C5:C1002 arasındaki (plakaların olduğu veriler) benzersiz verilerin sayısını bulan formül
=TOPLA(EĞER(SIKLIK(EĞER(C5:C1002<>"";KAÇINCI("~"&C5:C1002;C5:C1002&"";0));SATIR(C5:C1002)-SATIR(C5)+1);1))
cevap = 16

bu 16 veriyi H5 den itibaren yatay biçimde buldurma formülü
=EĞER(SÜTUNSAY($H5:H$5)<=$H$4;İNDİS($C$5:$C$1002;KÜÇÜK(EĞER(SIKLIK(EĞER($C$5:$C$1002<>"";KAÇINCI("~"&$C$5:$C$1002;$C$5:$C$1002&"";0));SATIR($C$5:$C$1002)-SATIR($C$5)+1);SATIR($C$5:$C$1002)-SATIR($C$5)+1);SÜTUNSAY($C5:C$5)));"")


benim sorum şu sayın hocalarım
A5:A1002 arasında tarihler var
C5:C1002 arasında plakalar var (benzersiz sıralancak grup)
H3 hücresine 03.06.2010 tarihi yazdığım anda
A5:A1002 arasından 03.06.2010 tarihlerine karşılık gelenlerin C5:C1002 aralığındaki karşılıklarının benzersiz sıralanması
yine ilk veri H5 hücresine buldurulcak ve yatay çekilerek yatayda devam edecek

 

[Ömer]

Merhaba,

Orjinal dosyanızı eklemenize gerek yoktur. Sorunuzla ilgili küçük bir dosya ekleyerek açıklarsanız sorunuzla ilgilenenler için kolaylık sağlamış olursunuz..

.

 

[modoste]

hocam sanırım sizin çalışmanızdı aynı dosyayı ekleyecem ama o hali zaten sonuca ulaşmış bi çalışma
bir aralıktaki tüm kamyon plakalarını benzersiz kayıtları bulma ve listelemesi yapılmış

ama işte ben tüm kamyonları değilde hangi tarihin dökümünü alcaksam o tarihdeki kamyonların benzersiz kayıtları buldurup sonuca gitmek.

 

[Ömer]

H4:

=TOPLA(EĞER(SIKLIK(EĞER((A5:A1002=H3)*(C5:C1002<>"");KAÇINCI("~"&C5:C1002;
C5:C1002&"";0));SATIR(C5:C1002)-SATIR(C5)+1);1))

H5:

=eğer(sütunsay($h5:h$5)<=$h$4;indis($c$5:$c$1002;küçük(eğer(sıklık(eğer((
$a$5:$a$1002=$h$3)*($c$5:$c$1002<>"");kaçıncı("~"&$c$5:$c$1002;$c$5:$c$1002&"";0
));satır($c$5:$c$1002)-satır($c$5)+1);satır($c$5:$c$1002)-satır($c$5)+1);
sütunsay($c5:c$5)));"")

Dizi formülleridir..

.

 

[modoste]

sayın hocam çok teşekkür ettim 2 farklı tarih için kontrol ettim sonuçlar mükemmel
hocam formüllü bi hücrenin sol üstündeki yeşil renkli üçgen işareti tam olarak ne demektir ve nasıl kaldırabilirim.
hücreye sağ tıklayıp içeriği temizle dediğimde kalktı o işaret ama anlayamadım

 

[modoste]

sayın hocam birşey daha sorcam çalışmanızı incelerken
mesela 02.08.2009 yazdığımda

kamyon plakaları benzersiz verilerden oluştuğuna göre
H5 hücresindeki ilk plaka 53 EF 436 olucak bu doğru
ama yanındaki I5 hücresi 28 K 8231 olması gerekmezmi
çünkü veri listesinde 19. satırda 02.08.2009 başlıyo ve ilk plaka 19. satırda 53 EF 436
20. satırdada yine 53 EF 436 var ama peşine 21. satırda 28 K 8231 var
benzersiz yatay listelencek plakalar listesinde I5 = 28 K 8231 olması gerekmez mi :?

 

[Ömer]

Belirttiğiniz veriyi sıralama esnasında formül buluyor fakat sırasını sizin yazdığınız sırada bulmuyor.

Formüldeki mantık sizin yazdığınız sıra ile çalışmaz. Formülün çalışma mantığını formül denetleme çubuğundan adım adım izleyebilirsiniz..

.

 

[modoste]

evet hocam tüm plakalrı buluyo ve dediğiniz gibi benim istediğim sırada bulmuyor
2010 yılı haziran ayı itibariyle çalışma şeklini tamamen değiştirmiş oluyorum
teşekkür ederim sabahtan beri bir yığın değişik firmaların tablolarını bu hale getirdim ve nakliye dağılımlarını doğru sonuçlarla aldım aynı çalışma tablosuna ekleme yada anlayamadığım bişe olursa yine size danışcam hocam
emeğinize sağlık