Soru Bir hücredeki sayıyı hücrelere ritmik dağıt

Katılım
11 Şubat 2010
Mesajlar
202
Excel Vers. ve Dili
13 türkçe
Selamlar,

Listeye veri eklendikçe K2 hücresindeki değeri ritmik sayı olarak örnekteki gibi P2 hücresindeki sayıya kadar yandaki hücreler dağıtmak istiyorum. Mümkünse Formül ile değilse kod ile yardımcı olur musunuz?

Teşekkürler..
 

Ekli dosyalar

Ömer BARAN

Uzman
Katılım
8 Mart 2011
Mesajlar
13,002
Excel Vers. ve Dili
Office 2013 ( 32 bit ) TÜRKÇE
Merhaba.
D3 hücresine uygulayıp sağa ve aşağı doğru kopyalayın.
=EĞER(YADA($B3="";$P$2<$K$2*(SATIR($A1)+(KAÇINCI("ZZZ";$B:$B;1)-2)*(SÜTUN(A$1)-1)));"";$K$2*(SATIR($A1)+(KAÇINCI("ZZZ";$B:$B;1)-2)*(SÜTUN(A$1)-1)))
=EĞER(YADA($B3="";SÜTUN(A$1)>$P$2/$K$2/(KAÇINCI("ZZZ";$B:$B;1)-2));"";$K$2*(SATIR($A1)+(KAÇINCI("ZZZ";$B:$B;1)-2)*(SÜTUN(A$1)-1)))
 
Son düzenleme:
Katılım
11 Şubat 2010
Mesajlar
202
Excel Vers. ve Dili
13 türkçe
Ömer Bey,
Benim için büyük bir sorunu çözdünüz. Sağolun , varolun..
 

Ali

Uzman
Katılım
21 Temmuz 2005
Mesajlar
7,893
Excel Vers. ve Dili
İş:Excel 2016-Türkçe
Ömer Bey, elinize sağlık. Güzel düşünülmüş ve hazırlanmış bir formül olmuş.
 

Ali

Uzman
Katılım
21 Temmuz 2005
Mesajlar
7,893
Excel Vers. ve Dili
İş:Excel 2016-Türkçe
V3 hücresine

Kod:
=İNDİS($B$3:$B$17;KÜÇÜK(EĞER($D3:$S17=$U3;SATIR($B$3:$B$17)-SATIR($B$3)+1);1))
yazıp CTRL+SHIFT+ENTER tuşlarına basarak formül girişini tamamlayınız.
 

Ömer BARAN

Uzman
Katılım
8 Mart 2011
Mesajlar
13,002
Excel Vers. ve Dili
Office 2013 ( 32 bit ) TÜRKÇE
Merhaba.
Dizi formülü yerine biraz çarpma, bölme ile sonuç almak isterseniz, alternatif olsun.
Rich (BB code):
=EĞER(YADA(MOD(U3/K2;1)>0;U3>P2);"HATA";KAYDIR($B$2;EĞER(MOD(U3/K2/(KAÇINCI("ZZZ";$B:$B;1)-2);1)=0;(KAÇINCI("ZZZ";$B:$B;1)-2);MOD(U3/K2/(KAÇINCI("ZZZ";$B:$B;1)-2);1)*K2);0))
 
Katılım
11 Şubat 2010
Mesajlar
202
Excel Vers. ve Dili
13 türkçe
Ömer ve Ali bey,
İkinize de teşekkür ederim. Sonuçlar harika. Ömer bey, Listede 4 kişi olunca sonucu başlığı yani "liste" yi veriyor. Geliştirmek adına söylüyorum. Dönütler herkese faydalı olacaktır.
Sizlerden bir şey daha rica etsem : "U3" hücresine listede olmayan bir değer girildiğinde "hata" yerine en son değer hücrede kalabilir mi?
 

Ömer BARAN

Uzman
Katılım
8 Mart 2011
Mesajlar
13,002
Excel Vers. ve Dili
Office 2013 ( 32 bit ) TÜRKÇE
Tekrar merhaba.
Formülleri tekrar gözden geçirdiğimde gördüğüm hatalar düzeltildi.
Tablodaki değerlerden, V3 hücresine yazılan değere EN YAKIN olan verinin B sütunundaki karşılığı sonuç olarak döndürülür.

-- D3 hücresine (sağa ve aşağı kopyalanacak);
CSS:
=EĞER(YADA(SATIR()-2>(KAÇINCI("ZZZ";$B:$B;1)-2);((SÜTUN(A$1)-1)*(KAÇINCI("ZZZ";$B:$B;1)-2)+(SATIR()-2))>$P$2/$K$2);"";((SÜTUN(A$1)-1)*(KAÇINCI("ZZZ";$B:$B;1)-2)+(SATIR()-2))*$K$2)
-- V3 hücresine;
CSS:
=KAYDIR($B$2;EĞER(U3<K2;1;(YUVARLA(MOD(MİN(P2;U3)/K2;(KAÇINCI("ZZZ";$B:$B;1)-2));0)=0)*(KAÇINCI("ZZZ";$B:$B;1)-2)+YUVARLA(MOD(MİN(P2;U3)/K2;(KAÇINCI("ZZZ";$B:$B;1)-2));0));0)
 
Katılım
11 Şubat 2010
Mesajlar
202
Excel Vers. ve Dili
13 türkçe
Teşekkürler Ömer Bey. Selametle.
 
Üst