Birden çok kritere göre "x" tarihinden büyük veya küçük olanları sayma

[aktarmamd]

Üstadlar Merhaba;

Birden çok kriter merkez alınarak, referans tarihe göre; bu tarihe eşit, öncesinde ve sonrasında kaç eylem gerçekleşmiş saydırmam gerekiyor. Tarihe eşit olanları saydırmak çok kolay fakat öncesini ve sonrasını saydırırken kullandığım "ÇOKEĞERSAY" fonsiyonunda sonuç alamadım. Tarihe ait sütundaki hücre biçimlendirmelerini de düzeltmeme rağmen sonuç alamadım. Amacım ek te gönderdiğim örnekteki ham verilere göre beklediğim formüllemeyi yapmak.

Desteğinizi bekliyorum.

 

[ÖmerBey]

Merhaba,
Dosyanızdaki tarihler metin olarak gözüküyor, bu sebeple işlem yaptıramıyorsunuz.
Herhangi bir hücreye 1 yazıp o hücreyi kopyalayınız.
Tarihin yer aldığı hücreleri seçip > Sağ tık > Özel Yapıştır > Çarp > Tamam yolunu takip ederek hücreleri topluca tarih sayısına çevirebilirsiniz. Daha sonra da hücre biçimlendirmesini tarih yaptıktan sonra istediğiniz hesaplamaları yaptırabilirsiniz.

Bu haliyle işlem yaptırmak için aşağıdaki formülü deneyiniz...

=TOPLA.ÇARPIM((1*report!$E$2:$E$50<TARİH(2021;12;9))*(report!$G$2:$G$50="Depoda")*(report!$J$2:$J$50="İSTANBUL"))

 

[aktarmamd]

=TOPLA.ÇARPIM((1*report!$E$2:$E$50<TARİH(2021;12;9))*(report!$G$2:$G$50="Depoda")*(report!$J$2:$J$50="İSTANBUL"))

Bu formül çok işime yaradı üstad emeğine sağlık. Beklentiyi Bi tık yukarıya çıkarıyorum.. bu formüle göre;

1- başvuruları metin olarak değilde yani tırnak içinde yazan tarih-depoda-istanbul değilde hücreden alıyor olsak,
2-Küçük,büyük,eşit kriterine küçük ve eşittiri de eklesek?
3-"Depoda"kiler + "teslimatta" kileri birlikte saydırsak ?

Örnek dosyayı ek te gönderiyorum. Desteğin için şimdiden teşekkürler.

 

[ÖmerBey]

Mantık aynı olacaktır:
1 - Formüldeki metin ifadeleri yerine hücre adresi yazdığınızda hücredeki değere göre çalışacaktır.
2 - Formülde istediğiniz operatörü kullanabilirsiniz (>,<,=,>=,<= fark etmez.)
3 - Şartların arasına + işareti koyarak iki şarta göre işlem yaptırabilirsiniz.
Sonuçta formülünüz yaklaşık olarak aşağıdaki gibi olacaktır. Sanırım diğer şarta uygun formülü de siz oluşturabilirsiniz.

=TOPLA.ÇARPIM((1*report!$E$2:$E$50<=$A$2)*((report!$G$2:$G$50=$F$2)+(report!$G$2:$G$50=$G$2))*(report!$J$2:$J$50=$A3))

İyi çalışmalar...

 

[aktarmamd]

Mantık aynı olacaktır:
1 - Formüldeki metin ifadeleri yerine hücre adresi yazdığınızda hücredeki değere göre çalışacaktır.
2 - Formülde istediğiniz operatörü kullanabilirsiniz (>,<,=,>=,<= fark etmez.)
3 - Şartların arasına + işareti koyarak iki şarta göre işlem yaptırabilirsiniz.
Sonuçta formülünüz yaklaşık olarak aşağıdaki gibi olacaktır. Sanırım diğer şarta uygun formülü de siz oluşturabilirsiniz.

=TOPLA.ÇARPIM((1*report!$E$2:$E$50<=$A$2)*((report!$G$2:$G$50=$F$2)+(report!$G$2:$G$50=$G$2))*(report!$J$2:$J$50=$A3))

İyi çalışmalar...

Teşekkürler üstad, tam istediğim gibi oldu emeğine sağlık.

 

[ÖmerBey]

Rica ederim,
Küçük bir uyarı: Topla.Çarpım dizi formülleri gibi çalıştığı için fazla kullanımda dosyanızı yavaşlatacaktır, bilginize...
İyi çalışmalar...

 

[aktarmamd]

Üstadlar Merhaba;

Konunun devamı olarak, ek teki örnekte de formül sorgusunu açıklamaya çalıştım. Kısaca birden fazla birbirini tamamlayan değeri bulup bir sutundakaç adet olduğunu, eğer o sütun boş ise diğer başvuracağı sütundaki sayıyı bulması gibi bir senaryo. Biraz karmaşık gelebilir ama örnekte detaylı açıklamaya çalıştım. Desteklerinizi bekliyorum.

Syg

 

[Ömer]

Merhaba,

Tabloda; H da değer yoksa J de var yada H da değer varsa J de yok. Sanırım tablonuz bu standart yapıda.

=TOPLA.ÇARPIM((--report!E2:E50<=A6)*(report!F2:F50=F6)*(report!G2:G50=G6)*(report!I2:I50=H6)*(report!H2:H50&report!J2:J50=A7))

 

[aktarmamd]

Merhaba,

Tabloda; H da değer yoksa J de var yada H da değer varsa J de yok. Sanırım tablonuz bu standart yapıda.

=TOPLA.ÇARPIM((--report!E2:E50<=A6)*(report!F2:F50=F6)*(report!G2:G50=G6)*(report!I2:I50=H6)*(report!H2:H50&report!J2:J50=A7))

Üstad Merhaba;

İfade ederken eksik anlatmışım ve örneği de eksik vermişim doğal olarak. "H" sütunu referans önce oraya bakacak eğer orası boşsa "J" ye bakarak sayacak.. Buna göre düzenlenebilir mi?

Syg

 

[Ömer]

H ve J sütunlarındaki aynı satıra denk gelen aralıklarının aynı anda dolu olma ihtimali var mı?
Örneğin; H5 dolu iken J5 dolu olabilir mi? Yada tam tersi.

 

[aktarmamd]

H ve J sütunlarındaki aynı satıra denk gelen aralıklarının aynı anda dolu olma ihtimali var mı?
Örneğin; H5 dolu iken J5 dolu olabilir mi? Yada tam tersi.

Aynen öyle üstad, biri boşken diğeri dolu oluyor.

 

[Ömer]

O halde diğer mesajda verdiğim formül istediğinizi yapıyor olması gerekir. Denediniz mi?

 

[aktarmamd]

O halde diğer mesajda verdiğim formül istediğinizi yapıyor olması gerekir. Denediniz mi?

Pardon yoğunluktan yanlış ifade ettim. Şimdi farkettim.. H5 dolu iken J5 te dolu olabiliyor, aynı şekilde tam terside mümkün..

 

[Ömer]

Dizi formülüdür.

=TOPLA((--report!E2:E50<=A6)*(report!F2:F50=F6)*(report!G2:G50=G6)*(report!I2:I50=H6)*(EĞER(report!H2:H50<>"";report!H2:H50;report!J2:J50)=A7))

 

[aktarmamd]

Dizi formülüdür.

=TOPLA((--report!E2:E50<=A6)*(report!F2:F50=F6)*(report!G2:G50=G6)*(report!I2:I50=H6)*(EĞER(report!H2:H50<>"";report!H2:H50;report!J2:J50)=A7))

Üstad teşekkür etmeyi ihmal ettim. İşimi çözdü sağolasın..

 

[aktarmamd]

Dizi formülüdür.

=TOPLA((--report!E2:E50<=A6)*(report!F2:F50=F6)*(report!G2:G50=G6)*(report!I2:I50=H6)*(EĞER(report!H2:H50<>"";report!H2:H50;report!J2:J50)=A7))

https://www.excel.web.tr/threads/huecreye-sag-tiklandiginda-detay-rapor-olusturulmasi.198590/

Üstad Merhaba;

Yeni konu olarak formda açtım ama sizde muhakkak buna uygun bir çözüm vardır. yardımcı olabilirmisiniz?