Soru Boş Satırları Gizle ve Göster

[Hsn55]

Merhabalar;
Ekli teklif dosyasında veri girişi sayfasında F30:F150 hücre aralığında veri olmayan diğer sayfalarda (Muayene Kabul,Ölçü Tespit Tutanağı,Piyasa Araştırma Tutanağı,Metraj Cetveli,Yaklaşık Maliyet Cetveli) F30:F150 hücre aralığındaki satırlar gizlenebilir mi? Tekrar veri girildiğinde ise veri olan satırlar gösterilebilir mi?. Burada 2 şart var.

1-Veri Girişi ve Bilgi Girişindeki satırlar gizlenmeyecek.
2-Piyasa Araştırma Tutanağında F35:F150 hücre aralığında veri yoksa bu SATIR aralığı gizlenip/gösterilecek
Yardımcı olursanız sevinirim

Bilgi

Bilgi

dosyam.org

 

[Hsn55]

Girilen veriye göre SATIR gizleme ve göstermeyi uyguladım. Fakat "PİYASA ARAŞTIRMA" sayfasında F35:F150 hücre aralığını şarta bağlayamadım. Bakarsanız sevinirim

Private Sub Worksheet_Change(ByVal Target As Range)
Application.ScreenUpdating = False

Dim sat As Long
Dim S1 As Worksheet, S2 As Worksheet, S3 As Worksheet, S4 As Worksheet, S5 As Worksheet, S6 As Worksheet
On Error Resume Next
Set S1 = Worksheets("VERİ GİRİŞİ")
Set S2 = Worksheets("PİYASA ARAŞTIRMA")
Set S3 = Worksheets("MUAYENE KABUL")
Set S4 = Worksheets("ÖLÇÜ TESPİT TUTANAĞI")
Set S5 = Worksheets("METRAJ CETVELİ")
Set S6 = Worksheets("YAKLAŞIK MALİYET CETVELİ")

S2.Range("E30:H150") = S1.Range("E30:H150").Value
S3.Range("E30:H150") = S1.Range("E30:H150").Value
S4.Range("E30:H150") = S1.Range("E30:H150").Value
S5.Range("E30:H150") = S1.Range("E30:H150").Value
S6.Range("E30:H150") = S1.Range("E30:H150").Value

For Each ss In Worksheets
If ss.Name <> "VERİ GİRİŞİ" And ss.Name <> "BİLGİ GİRİŞİ" Then
ss.Rows("30:150").Hidden = False
ss.Range("F30:F150").SpecialCells(xlCellTypeBlanks).EntireRow.Hidden = True
End If
Next
Application.ScreenUpdating = True
End Sub

 

[Hsn55]

Arkadaşlar konuya yardımcı olursanız sevinirim

 

[Korhan Ayhan]

Paylaştığınız kodu denedim. Sorunsuz çalışıyor.

 

[Hsn55]

Korhan bey kodda sıkıntı yok çalışıyor. Benim sadece yapmak istediğim. Diğer sayfalarda F30:F150 arasındaki boş satırlar veri yoksa gizlenecek. Piyasa araştırma sayfasında ise F35:F150 hücre aralığındaki boş satırlar gizlenecek

 

[Korhan Ayhan]

Kullandığınız kod ile sayfa isimleriniz arasında farklar vardı. Onlarıda düzenledim.

Deneyiniz.

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Application.ScreenUpdating = False
    
    Dim S1 As Worksheet, S2 As Worksheet, S3 As Worksheet
    Dim S4 As Worksheet, S5 As Worksheet, S6 As Worksheet
    Dim Sayfa As Worksheet
    
    On Error Resume Next
    
    Set S1 = Worksheets("VERİ GİRİŞİ")
    Set S2 = Worksheets("PİYASA ARAŞTIRMA TUTANAĞI")
    Set S3 = Worksheets("MUAYENE KABUL ")
    Set S4 = Worksheets("ÖLÇÜ TESPİT TUTANAĞI")
    Set S5 = Worksheets("METRAJ CETVELİ")
    Set S6 = Worksheets("YAKLAŞIK MALİYET CETVELİ")
    
    S2.Range("E30:H150") = S1.Range("E30:H150").Value
    S3.Range("E30:H150") = S1.Range("E30:H150").Value
    S4.Range("E30:H150") = S1.Range("E30:H150").Value
    S5.Range("E30:H150") = S1.Range("E30:H150").Value
    S6.Range("E30:H150") = S1.Range("E30:H150").Value
    
    For Each Sayfa In Worksheets
        Select Case Sayfa.Name
            Case "VERİ GİRİŞİ", "BİLGİ GİRİŞİ"
            Case S2.Name
                Sayfa.Rows("35:150").Hidden = False
                Sayfa.Range("F35:F150").SpecialCells(xlCellTypeBlanks).EntireRow.Hidden = True
            Case Else
                Sayfa.Rows("30:150").Hidden = False
                Sayfa.Range("F30:F150").SpecialCells(xlCellTypeBlanks).EntireRow.Hidden = True
        End Select
    Next
    
    Application.ScreenUpdating = True
End Sub

 

[Hsn55]

Teşekkür ederim Korhan bey