Soru Boşluklu veri dizisini, boşluksuz olarak sıralama

[yusiskan]

		5
5		6
6		10
		11
10
11

Merhaba, Excelde yukarıdaki tablodaki gibi 1 sütunda (A sütunu) bulunan aralarında boş hücre olan verileri 3. Sütundaki (C Sütunu) gibi aralarında boş hücre olmadan sıralamak istiyoum nasıl yapabilirim ?

 

[Korhan Ayhan]

Merhaba,

Deneyiniz.

DİZİ formüldür. Hücreye uyguladıktan sonra cursor hücre içindeyken hücreyi CTRL+SHIFT+ENTER tuşlarına basarak terk etmelisiniz.

C1;

=İNDİS(A$1:A$1000;KÜÇÜK(EĞER(A$1:A$1000<>"";SATIR(A$1:A$1000));SATIR(A1));1)

 

[Korhan Ayhan]

Ek olarak A sütununda ki verilerin tamamı sayı ise sanırım aşağıdaki formülde isinizi görecektir.

Sonuç listesi büyükten küçüğe sıralı olacaktır.

C1;

=BÜYÜK(A$1:A$1000;SATIR(A1))

 

[Ali]

Başka bir alternatif

• İlgili aralık seçilir.
• F5 tuşuna basılır.
• Açılan menüden Özel seçilir. Sabitler seçilip Tamam tuşu tıklanır.
• CTRL+C (Kopyala).
• Yan sütunu seç
• CTRL+V (Yapıştır)

Dolu olan listeyi yan tarafta boşluksuz listelemiş olursunuz.

 

[Carpintero]

Merhaba,

Deneyiniz.

DİZİ formüldür. Hücreye uyguladıktan sonra cursor hücre içindeyken hücreyi CTRL+SHIFT+ENTER tuşlarına basarak terk etmelisiniz.

C1;

=İNDİS(A$1:A$1000;KÜÇÜK(EĞER(A$1:A$1000<>"";SATIR(A$1:A$1000));SATIR(A1));1)

Sayın Hocam Merhaba
formül #SAYI! hatası veriyor bu hatanın önüne geçilebilir mi acaba ?
şöyle ki;
A1:A1000 aralığında 900 dolu hücre var diyelim formülü B sütununa uyguladığımızda
B900:B1000 aralığında #SAYI! hatası oluşuyor.

 

[Korhan Ayhan]

Deneyiniz.

=EĞERHATA(İNDİS(A$1:A$1000;KÜÇÜK(EĞER(A$1:A$1000<>"";SATIR(A$1:A$1000));SATIR(A1));1);"")

 

[Carpintero]

Elinize sağlık.
teşekkür ederim.

 

[Korhan Ayhan]

Bu da olabilir..

Normal formül..

=EĞERHATA(İNDİS(A$1:A$1000;TOPLAMA(15;6;SATIR(A$1:A$1000)/(A$1:A$1000<>"");SATIR(A1));1);"")