Çoklu kritere göre toplam almak

[Korhan Ayhan]

Merhaba Arkadaşlar,

İdris beyin daha önce forumda paylaştığı ekteki dosyada kriter alanından bir alanı komple içerik olarak sildiğimde formül sıfır sonucunu üretiyor.

Bu formülün bu durumda var olan kriterlere göre sonuç üretmesi için çözüm öneriniz nedir?

Yada bu şekilde kullanabileceğim farklı bir fonksiyon öneriniz olabilir mi?

Tabloda yardımcı sütun kullanabilirim. Bu yönde önerileriniz olursa uygulamak isterim.

Desteğiniz için teşekkür ederim.

 

[Merhum İdris SERDAR]

.

Sanırım Durum / Durumlara göre IF koşulu ile çözümler bulunabilir.


.

 

[sakman26]

selam,
yardımcı kolon kullanılarak
N3 hücresinde

=EĞER(BOŞLUKSAY(H3:L3)=SÜTUNSAY(H3:L3);"";TOPLA.ÇARPIM((ESAYIYSA(MBUL(H3;ürün)))*(ESAYIYSA(MBUL(I3;renk)))*(ESAYIYSA(MBUL(J3;voltaj)))*(ESAYIYSA(MBUL(K3;ebat)))*(ESAYIYSA(MBUL(L3;Ay)))*Adet))

formülü kullanıldı.

Eki inceleyebilirsiniz..
Not : Ek, Sn. İdris Serdar Bey'in orijinal dosyasından alıntılanarak hazırlandı.

 

[Erdem Akdemir]

Korhan bey,

Dosyayı incelediğimde bulunmak istenen sonucu tam olarak anlayamadım.
Nasıl bir sonuç üretmek isteniyor. 24 sonucunun anlamı nedir.

 

[Korhan Ayhan]

Sn. Kuvari,

Dosyadaki kriter alanındaki değerlere bakılarak tablodan uygun kayıtların adet bilgisine ulaşılıyor.

Eğer kriter alanından RENK bölümünü komple içerik olarak silerseniz formül sonucu sıfır veriyor.

Ben silinen kriterin kullanılan formülün içinde de yokmuş gibi kalan kriterlere göre hesap yapmasını istiyorum.

Sn. Sakman elinize sağlık. Yardımcı sütun kullanılarak sonuca gitmişsiniz. Eğer tek hücrede formülle cevap alternatifleri gelmezse sizin önerinizi deneyeceğim.

 

[sakman26]

selam,
alternatif olarak,
yine yardımcı kolon kullanarak
(DİZİ formül yazacak arkadaşlara belki faydası olabilir amacıyla)

=EĞER(BOŞLUKSAY(H3:L3)=SÜTUNSAY(H3:L3);"";TOPLA.ÇARPIM((ESAYIYSA(MBUL(EĞER(H3="";"*";H3)&EĞER(I3="";"*";I3)&EĞER(J3="";"*";J3)&EĞER(K3="";"*";K3)&EĞER(L3="";"*";L3);ürün&renk&voltaj&ebat&Ay)))*Adet))

formülünü de yazabilirsiniz...

kolay gelsin..

 

[Erdem Akdemir]

Sn. Kuvari,

Dosyadaki kriter alanındaki değerlere bakılarak tablodan uygun kayıtların adet bilgisine ulaşılıyor.

Eğer kriter alanından RENK bölümünü komple içerik olarak silerseniz formül sonucu sıfır veriyor.

Ben silinen kriterin kullanılan formülün içinde de yokmuş gibi kalan kriterlere göre hesap yapmasını istiyorum.

Sn. Sakman elinize sağlık. Yardımcı sütun kullanılarak sonuca gitmişsiniz. Eğer tek hücrede formülle cevap alternatifleri gelmezse sizin önerinizi deneyeceğim.

Korhan bey,

Veri satırında sadece ikinci satırdaki veri kalsın. A3'ten itibaren diğerlerini silin, sonuç yine 24 çıkıyor. Bu tabloyu hiç anlayamadım.:???:

 

[Korhan Ayhan]

Sn. Kuvari,

Veri alanından değil, kriter alanından renk bölümünü silin ve deneyin.

 

[Erdem Akdemir]

Korhan bey,

Kriter alanından sildiğimde sonuç sıfır oluyor o kısmını anladım ama çıkan sonucu veri alanı ile ilişkilendiremiyorum. A3'ten itibaren bütün veriyi sildiğimde neden sonuç yine 24 çıkıyor. Bu tablo ile amaçlanan nedir kafam orda biraz karıştı açıkçası.

 

[Korhan Ayhan]

Orası da ayrı bir sorun. Sanırım EĞERSAY fonksiyonu o durumda ters işlem yaparak sonuç üretiyor.

 

[sakman26]

selam,
Tek hücrede toplam alabilmek için

=TOPLA.ÇARPIM((ESAYIYSA(MBUL(DEVRİK_DÖNÜŞÜM(EĞER(ürünk="";"*";ürünk)&EĞER(renkk="";"*";renkk)&EĞER(voltajk="";"*";voltajk)&EĞER(ebatk="";"*";ebatk)&EĞER(Ayk="";"*";Ayk));ürün&renk&voltaj&ebat&Ay)))*Adet)

DİZİ formülünü deneyiniz.

#3 mesajımdaki ek güncellendi. Gerek yardımcı kolon 2 ve gerekse tek hücre formülü eklendi.

 

[Erdem Akdemir]

Korhan bey merhaba,

Ek'teki örnek dosyaya bakabilir misiniz. Sizin istediğiniz ekteki gibi bir çalışma mı?

 

[bzace]

Merhaba,
Dosyayı görmeden bir şey diyemeyeceğim ama Sn. Sakman26'nın formüldende kısmen anladığım kadarıyla deneyiniz.

• A1:A10 kriterlerin olduğu birinci alan,
• B1:B10 kriterlerin olduğu ikinci alan,
• C1:C10 kriterlerin olduğu üçüncğ alan,
• D1: D10 farklı farklı sayılar,
• E1 , E2 , E3 sırasıyla arayacağımız kriterler,

=TOPLA(--EĞER(E1="";1;A1:A10=E1)*--EĞER(E2="";1;B1:B10=E2)*
  --EĞER(E3="";1;C1:C10=E3)*D1:D10)
[COLOR="Blue"]Formül dizi formülüdür.CTRL+SHIFT+ENTER ile tamamlayınız.[/COLOR]

Not: Örnek olduğu için MBUL fonksiyonunu kullanmadım. Örnek doğru sonuç veriyorsa siz ekleyebilirsiniz.
Sn. Sakman26 formülleri açık paylaştığınız için ayrıca TEŞEKKÜRLER.

Saygılar,
Kafe

 

[sakman26]

selam,

Sn. Sakman26 formülleri açık paylaştığınız için ayrıca TEŞEKKÜRLER.

Sn.bzace , teşekkür ediyorum.. Ama yine de dosya paylaşım siteleri vasıtasıyla örnek dosyayı yüklemem, daha güzel olurdu...
kolay gelsin..

Bu vesileyle
örnek dosya ektedir..

link : http://s2.dosya.tc/server2/283471/Ornek01.xlsx.html

 

[Korhan Ayhan]

Değerli Arkadaşlar,

Verdiğiniz formüllerin hepsi için ekli dosyada örnekleme yaptım. Hatalı sonuçlar çıkıyor.

Sn. sakman26'nın vermiş olduğu yardımcı sütun ile ilgili çözüm doğru sonuç veriyor. (Tam olarak test etmedim.)

Örnek dosyayı ekliyorum. Sanırım sorumu net olarak anlatamadım.

Ben bu formülü muhasebe kayıtlarını özetlemek için kullanmak istiyorum. Bununla ilgili olarak net bir örnek dosya ayrıca ekleyeceğim.

 

[bzace]

Korhan Bey,
Dosyayı harici paylaşabilir misiniz? Akşam bakmaya çalışacağım.

Sn. Sakman26 paylaşdığınız dosyada yardımcı sütunlu örneğiniz yoksa ekleyebilir misiniz?

 

[sakman26]

selam,
ek teki dosyada gerekli açıklamaları da yaptım.
Verilen DİZİ formülünde (her 3 kolonun da BOŞ olması durumu değerlendirilmedi), KRİTER kolonlarında en az bir kolonda veri olmalı. Dolayısıyla seçim aralığını ona göre düzenlemek gereklidir. Sanıyorum bunu bir önceki mesajımda belirtememişim..

Düzenlenmiş dosya ek tedir.

link : http://s4.dosya.tc/server2/ht7gav/Ornek_Formuller.xlsx.html

Sn. bzace gönderdiğim dosyadaki yardımcı sütunlar ve Q5 hücresinde DİZİ formülü mevcut. Ama şu anda gönderdiğimde de mevcut.

 

[sakman26]

selam,
Korhan Bey'in yazdığı şekilde ve de boşlukları da değerlendirme kapsamına alırsak eğer DİZİ formülünü şu şekilde yazabiliriz.

=TOPLA.ÇARPIM((ESAYIYSA(MBUL(EĞER(DEVRİK_DÖNÜŞÜM(EĞER($H$2:$H$10="";"*";$H$2:$H$10)&EĞER($I$2:$I$10="";"*";$I$2:$I$10)&EĞER($J$2:$J$10="";"*";$J$2:$J$10))<>"***";DEVRİK_DÖNÜŞÜM(EĞER($H$2:$H$10="";"*";$H$2:$H$10)&EĞER($I$2:$I$10="";"*";$I$2:$I$10)&EĞER($J$2:$J$10="";"*";$J$2:$J$10)));A2:A10&B2:B10&C2:C10))*D2:D10))

 

[Korhan Ayhan]

Değerli Arkadaşlar,

Tablomun örnek hali ektedir.

Rapor isimli sayfaya gerekli açıklamayı yazdım.

İstenen tek formülle (tabi ki mümkünse) bütün satırlara uygun değerleri getirmek.

Örnek Dosya

 

[Erdem Akdemir]

Korhan bey merhaba,

Bir önceki eklemiş olduğunuz dosya için istediğiniz şekilde formülü oluşturdum. Yeni oluşturduğunuz dosyaya kendiniz uyarlayabilirsiniz.