çoklu sütunla arama yapmak.

[Enb2016]

Benim sorunum, iki çalışma sayfasında aynı satıra( satırlarda 3, 4 sütun var) sahip olanları bulup bunlara kod verebilmek veya bunları renklendirebilmek. Forumlardaki başlıklarda bu soruma cevap olabilecek başlıklar var, inceledim ama içinden çıkamadım konuların.(düşey aralarla, eğerlerle, özdeşlerle yapmaya çalıştım olmadı) Yardımcı olursanız gerçekten çok ikrama geçecek. Ekte, örnek karşılaştırma gönderiyorum.
Teşekkür ederim...Ekli dosyayı görüntüle EXCEL FORUM.xlsx

 

[citiboyy]

Anladığım kadarıyla yaptım Buyrun dosya ekte

 

[Necdet]

Merhaba,

Aşağıdaki kodları deneyiniz.

Option Compare Text
Sub Karsilastir()
    Dim i   As Long, _
        Son As Long, _
        Adr As String, _
        c   As Range, _
        s1  As Worksheet, _
        s2  As Worksheet
    
    Set s1 = Sheets("1.veritabanı")
    Set s2 = Sheets("2.VERİTABANI")
    s1.Select
    Application.ScreenUpdating = False
    Son = s1.Cells(Rows.Count, "A").End(3).Row
    Range("E2:E" & Son).ClearContents
    
    For i = 2 To Son
        With s2.Range("A:A")
            Set c = .Find(s1.Cells(i, "A"), LookIn:=xlValues)
            If Not c Is Nothing Then
                Adr = c.Address
                Do
                    If s1.Cells(i, "B") = s2.Cells(c.Row, "B") And _
                       s1.Cells(i, "C") = s2.Cells(c.Row, "C") And _
                       s1.Cells(i, "D") = s2.Cells(c.Row, "D") Then
                       s1.Cells(i, "E") = 0
                    End If
                    Set c = .FindNext(c)
                Loop While Not c Is Nothing And c.Address <> Adr
            End If
        End With
    Next i
    
    Son = s2.Cells(Rows.Count, "A").End(3).Row
    s2.Range("E2:E" & Son).ClearContents
    
    For i = 2 To Son
        With s1.Range("A:A")
            Set c = .Find(s2.Cells(i, "A"), LookIn:=xlValues)
            If Not c Is Nothing Then
                Adr = c.Address
                Do
                    If s2.Cells(i, "B") = s1.Cells(c.Row, "B") And _
                       s2.Cells(i, "C") = s1.Cells(c.Row, "C") And _
                       s2.Cells(i, "D") = s1.Cells(c.Row, "D") Then
                       s2.Cells(i, "E") = 0
                    End If
                    Set c = .FindNext(c)
                Loop While Not c Is Nothing And c.Address <> Adr
            End If
        End With
    Next i
    MsgBox "Karşılaştırma Bitmiştir....", vbInformation, "N.YEŞERTENER --> [URL="http://www.excel.web.tr"]www.excel.web.tr[/URL]"
End Sub

 

[Enb2016]

Yardımlarınız için çok teşekkür ederim. İlk defa soru soruyorum bu foruma; soruma bu kadar çabuk geri dönüşüm olabileceğini düşünmemiştim doğrusu. Tekrar teşekkürler....

 

[teo966]

çoketopla formülüne benzer bir förmül ile sayısal olmayan bir veriyi bulabilir miyiz.

Arkadaşlar,

çoketopla bildiğiniz gibi birden fazla kriteri seçerek sayısal bir veriyi döndürmekte.

Acaba tıpkı çoketopla fonksiyonu gibi birden fazla kriteri seçerek sayısal olmayan bir veriyi nasıl bulabiliriz.

Teşekkür eder, saygılar sunarım.