Combobox Rowsource olayı hakkında.

[acolkesen1]

Merhaba,

Set m = [Sayfa1!P1:CY1].Find(TextBox1, LOOKAT:=xlWhole)
Yukarıdaki kod ile belirlenen hücrenin bir altındaki hücre ile hücrenin bulunduğu kolondaki son satıra kadar olan alanı combobox1 in rowsource olayına yazmak istiyorum.
combobox1.rowsource = "m.Offset(1, 0):m.End(xlDown)" gibi ..İlgilenen arkadaşlara teşekkür ederim.

 

[Korhan Ayhan]

Merhaba,

Aşağıdaki kodu deneyiniz.

Private Sub CommandButton1_Click()
    Dim S1 As Worksheet, Bul As Range, Sutun As Integer, Son_Satir As Long, Adres As String
    
    Set S1 = Sheets("Sayfa1")
    Set Bul = S1.Range("P1:CY1").Find(TextBox1, , , xlWhole)
    
    ComboBox1.RowSource = Empty
    
    If Not Bul Is Nothing Then
        Sutun = Bul.Column
        Son_Satir = S1.Cells(S1.Rows.Count, Sutun).End(3).Row
        Adres = S1.Name & "!" & S1.Cells(1, Sutun).Address & ":" & S1.Cells(Son_Satir, Sutun).Address
        
        ComboBox1.RowSource = Adres
    Else
        MsgBox "Aradığınız değer bulunamadı!", vbInformation
    End If
End Sub

 

[Murat OSMA]

Korhan Bey'in müsadesiyle....


Alternatif olarak bu kodlar da kullanılabilir;

Private Sub CommandButton1_Click()
    Dim i As Integer
    Dim bul As Range
    Set bul = Range("P1:CY1").Find(TextBox1.Text, , , xlWhole)
    If Not bul Is Nothing Then
        For i = 2 To bul.Columns.End(4).Row
            ComboBox1.AddItem Cells(i, bul.Column)
        Next i
    Else: MsgBox "Başlık bulunamadı", vbInformation + vbMsgBoxRtlReading
    End If
    Set bul = Nothing
    i = Empty
End Sub

 

[acolkesen1]

Merhaba sayın Korhan Ayhan ve sayın Murat Osma,
Her ikinize de ilgi ve yardımlarınız için çok teşekkür ederim. Esen kalın..