Combobox'daki değerleri listeleme

[fehdur]

Aşağıdaki kod ile Yapmaya çalıştım ama başaramadım.Yapmak istediğim E sütununda tekrarlayan muhtelif isimler var Comboboxdan seçtiğim isme ait verileri Listview1' de listelemek istiyorum.Örnekte listview 1.sütuna yazdırmaya çalıştım.Toplam sütun sayısı 5 olacak.Sonradan düzenlenebilir önemli değil.İlgilenecek arkadaşa teşekkürler.

On Error Resume Next
With ListView1
ListView1.ListItems.Clear
Set S1 = Sheets("Tahsilat")
Say = S1.Range("E65536").End(xlUp).Row
For j = 1 To Say
If CStr(S1.Cells(j, "e")) = CStr(ComboBox1) Then
i = ListView1.ListItems.Count + 1
.ListItems.Add , , S1.Cells(j, "e")
.ListItems(i).SubItems(1) = Sheets("Tahsilat").Cells(i, 5).Value
End If
Next j
End With

 

[Muzaffer Ali]

Merhaba.
Aşağıdaki kodları kullanın.

Private Sub ComboBox1_Change()
    Dim S1 As Worksheet
    Dim Bak As Long
    Dim List As ListItem
    With ListView1
        .ListItems.Clear
        Set S1 = Sheets("Tahsilat")
        For Bak = 1 To S1.Cells(Rows.Count, "E").End(xlUp).Row
            If CStr(S1.Cells(Bak, "e")) = CStr(ComboBox1) Then
                Set List = .ListItems.Add(, , S1.Cells(Bak, "E").Text)
                List.ListSubItems.Add , , S1.Cells(Bak, "F").Text
                List.ListSubItems.Add , , S1.Cells(Bak, "G").Text
            End If
        Next
    End With
End Sub

Private Sub UserForm_Initialize()
    With ListView1
        .View = lvwReport
        .ColumnHeaders.Add , , "Başlık1"
        .ColumnHeaders.Add , , "Başlık2"
        .ColumnHeaders.Add , , "Başlık3"
    End With
End Sub