Düşeyara ile Sağdan Sola Bakma

[Hacı Bayram ÖZKAN]

Merhaba arkadaşlar sitede inceledim, düşeyarada genellikle soldan sağa yapılmış, benim isteğim ekli dosyamda düşeyara ile Sağdan Sola veriler bulunabilir mi yoksa makro ile mi olur, yardımcı olursanız sevinirim. Teşekkürler.

 

[Orion1]

Merhaba.
İndis,ve kaçıncı formüllerini bir arada kullanarak bulabilirsiniz.
Forumda arama yapınız.

 

[Korhan Ayhan]

Excelde tablolar sağa doğru genişlemektedir. Bu sebeple formüllerde soldan sağa doğru işlem yaparlar.

İhtiyaç doğrultusunda farklı fonksiyonlar kullanarak çözüme gidebilirsiniz.

 

[Hacı Bayram ÖZKAN]

Teşekkürler sayın hocam, buldum şu formülü kendi dosyama uyarladım oldu. Teşekkür ederim
=İNDİS(Sayfa1!$A$2:$A$100;KAÇINCI(A2;Sayfa1!$D$2:$D$100;0))
Her aradığımı için harfi değiştirdim oldu, teşekkürler iyi geceler.

 

[Hacı Bayram ÖZKAN]

Hocam =İNDİS(Sayfa1!$A$2:$A$100;KAÇINCI(A2;Sayfa1!$D$2:$D$100;0)) Buradaki sıfır tam eşleşme için miş peki ben yaklaşık değer için burayı nasıl yapmalıyım yani düşerada YANLIŞ VE DOĞRU da olduğu gibi...

 

[YUSUF44]

Eğer sürümünüz uygunsa ÇAPRAZARA formülünü deneyiniz.

Excel yardımında şu şekilde açıklanmış:

Söz dizimi
DÜŞEYARA işlevi bir aralığı veya diziyi arar ve bulduğu ilk eşleşmeye karşılık gelen öğeyi döndürür. Eşleşme yoksa, DÜŞEYARA en yakın (yaklaşık) eşleşmeyi geri getirenin.
=ÇAPRAZARA(aranan_değer, aranan_dizi, döndürülen_dizi, [bulunamadığında], [eşleştirme_modu], [arama_modu])

Bağımsız değişken	Açıklama
aranan_değer Gerekli*	Aranan değer *Atlanırsa, DÜŞEYARA işlevi hücrede bulduğu boş lookup_array.
aranan_dizi Gerekli	Aranan dizi veya aralık
döndürülen_dizi Gerekli	Geri dönecek dizi veya aralık
[bulunamadığında] İsteğe bağlı	Geçerli bir eşleşme bulunamasa, tedarik if_not_found[ metnini girin. Geçerli bir eşleşme bulunamıyorsa ve [if_not_found] yoksa, #N/A döndürülür.
[eşleştirme_modu] İsteğe bağlı	Eşleşme türünü belirtin: 0 - Tam eşleşme. Hiçbiri bulunamıyorsa, #N/A. Varsayılan ayar budur. -1 - Tam eşleşme. Hiçbiri bulunamıyorsa, bir sonraki küçük öğeyi geri girin. 1 - Tam eşleşme. Hiçbiri bulunamıyorsa, bir sonraki büyük öğeyi geri girin. 2 - *, ?, ve ~ karakterlerinin özel anlamı olan joker karakter eşleşmesi.
[arama_modu] İsteğe bağlı	Kullanmak üzere arama modunu belirtin: 1 - İlk öğeden başlayarak bir arama gerçekleştirin. Varsayılan ayar budur. -1 - Son öğeden başlayarak ters arama gerçekleştirin. 2 - Artan düzende sıralanmış lookup_array ikili arama gerçekleştirin. Sıralanmazsa, geçersiz sonuçlar döndürülür. -2 - Azalan düzende sıralanmış lookup_array ikili arama gerçekleştirin. Sıralanmazsa, geçersiz sonuçlar döndürülür.

 

[Hacı Bayram ÖZKAN]

Sayın Yusuf bey sizin dediğiniz bende mevcut değilmiş, ancak farklı bir dosya hazırlayarak isteğimi anlattım, Sayfa2 deki G sütundaki veriler, sağdan 6 hane kırpılarak yani 28.250.194.7049.28.67.01.03.02.30.01 böyle bir kodu Sayfa birden bulurken 28.250.194.7049.28.67.01.03.02.30.01 kırmızı ile yazılan kısmı kırparak nasıl bulur. Yani sağdan her değer için sondan noktalar dahil 6 değeri görmeyecek. Örnek dosya ekte.

 

[Ömer]

Merhaba,

Sorunuzu tam anlayamadım. C2 hücresine yazıp yana ve alt hücrelere kopyalayın.

=İNDİS(Sayfa1!C$2:C$100;KAÇINCI(SOLDAN($G2;UZUNLUK($G2)-6)&"*";Sayfa1!$G$2:$G$100;0))

İstediğiniz bu mu?

.

 

[Hacı Bayram ÖZKAN]

Merhaba Ömer Bey; şöyle olacak efendim, aşağıdaki formülle işlemi yapıyorum, ancak Şu formülü =SOLDAN($G2;UZUNLUK($G2)-6)

=İNDİS(Sayfa1!$C$2:$C$100;KAÇINCI(G4;Sayfa1!$G$2:$G$100;0))


=SOLDAN($G2;UZUNLUK($G2)-6) bunu yukarıda kırmızı ile yazılı yere yani Sayfa1 için G2 ile G 100 için uyarlarsak olacak saygılarımla...

Kısaca Sayfa1 deki G2 ile G100 arasındaki verileri 6 hane görmeden arama yapacak.

Ömer bey şöyle birşey olacak =İNDİS(Sayfa1!$C$2:$C$100;KAÇINCI(G4;SOLDAN(Sayfa1!$G2:$G100;UZUNLUK(Sayfa1!$G2:$G100)-6);0))

ama yazamadım...

 

[Korhan Ayhan]

@Ömer beyin önerisini denediniz mi?

Denediyseniz ne gibi bir sorun çıkardı?

 

[Hacı Bayram ÖZKAN]

Korhan bey sorun şu oldu, dosyaya yapıştırdım, Sayfa1 deki C, D, E, F sütunlardaki verileri alamadım, burada =SOLDAN($G2;UZUNLUK($G2)-6) bu formül ile yapılan kısaltma Sayfa1 için olacak.

Tekrar açıklama ve olması gerekeni yüklüyorum. teşekkürler.

 

[Korhan Ayhan]

Formülü alt satırlara kopyaladınız mı?

C3 hücresinden itibaren farklı formül var. Kontrol ediniz.

 

[Hacı Bayram ÖZKAN]

Evet Korhan bey Kopyaladım, ama bakın Sayfa1 deki verilerimi alamadım. Sayfa1 in E sütununda 1 den 88 e kadar veri var, F de ise 89 dan 176 kadar veri var bunların Sayfa2 ye gelmesi lazım ama gelmedi. Farklı sonuçlar geldi, tekrar atıyorum.

YENİ dosyada Gelmesi Gerekeni yazdım, Sayfa2 de çok farklı gelir, bakarsanız sevinirim, saygılarımla.... iyi geceler...

 

[Korhan Ayhan]

Bunu deneyiniz.

DİZİ formüldür.

=İNDİS(Sayfa1!C$2:C$100;KAÇINCI($G2;SOLDAN(Sayfa1!$G$2:$G$100;UZUNLUK(Sayfa1!$G$2:$G$100)-6);0))

 

[Hacı Bayram ÖZKAN]

Yarın inşallah hayırlı geceler cumanız mübarek olsun

 

[Suskun]

Formüller çalışıyor. Düşeyara ile SAĞDAN SOLA cözüm :

=DÜŞEYARA(G2;EĞER({1;0}; SOLDAN(Sayfa1!$G$2:$G$100;UZUNLUK(Sayfa1!$G$2:$G$100)-6);Sayfa1!$C$2:$C$100);2;0)

Formülünü Sayfa2 C2 sutununa yapıştırın.Dizi Formülüdür ctrl+shit+enter Yaptıktan sonra aşağı doğru kopyalayın.

 

[Hacı Bayram ÖZKAN]

Sayın hocalarım çok teşekkür ederim, sizleri yordum bu sayede dizi formül hakkında bilgi edindim. Formüller çalıştı teşekkürler. Herkesin eline sağlık....

 

[Hacı Bayram ÖZKAN]

Merhaba Korhan hocam; sizin yazdığınız şu formüle
=İNDİS(Sayfa1!C$2:C$100;KAÇINCI($G2;SOLDAN(Sayfa1!$G$2:$G$100;UZUNLUK(Sayfa1!$G$2:$G$100)-6);0))
Ekleme yapmak istiyorum, buna YADA eklemek istiyorum, yani
=İNDİS(Sayfa1!C$2:C$100;KAÇINCI($G2;SOLDAN(Sayfa1!$G$2:$G$100;UZUNLUK(Sayfa1!$G$2:$G$100)-3);0))

Birinci formülü girince ikinci formül olanı bulmuyor, ikinciyi girince birinci formülleri bulmuyor bunun yerine her iki formülüde kullanmak için YADA yı nasıl eklerim.

Şunu anlatmak istiyorum, önce birinci formüle bakacak, bulamazsa yada deyip ikinci formüle bakacak, bu nasıl olur.

 

[Korhan Ayhan]

Böyle kullanabilirsiniz.

=EĞERHATA(İNDİS(Sayfa1!C$2:C$100;KAÇINCI($G2;SOLDAN(Sayfa1!$G$2:$G$100;UZUNLUK(Sayfa1!$G$2:$G$100)-6);0));İNDİS(Sayfa1!C$2:C$100;KAÇINCI($G2;SOLDAN(Sayfa1!$G$2:$G$100;UZUNLUK(Sayfa1!$G$2:$G$100)-3);0)))

 

[Hacı Bayram ÖZKAN]

Evet sayın abim oldu, çok teşekkür ederim, dua ile kal... iyi geceler..