En son aya karşılık gelen tutarı çağırma

[ATEMİ]

Merhaba arkadaşlar,
Her ay bitiminde gerçekleşen tutarların olduğu bir tabloda
En son hareket gören aya karşılık gelen tutarı çağırmak istiyorum nasıl bir fonksiyon kullanmam gerekir
Teşekkür ederim

 

[ÖmerBey]

Merhaba,
Deneyiniz...

=ARA(9999999999999;A5:L5;A5:L5)

 

[Korhan Ayhan]

Bunlarda alternatif olsun..

=ARA(2;1/(A5:L5<>"");A5:L5)

=İNDİS(A5:L5;;ÇAPRAZEŞLEŞTİR(1;--(A5:L5<>"");0;-1))

=KAYDIR(A5;;ÇAPRAZEŞLEŞTİR(1;--(A5:L5<>"");0;-1)-1)

=İNDİS(A5:L5;;MAK(EĞER(A5:L5<>"";COLUMN(A5:L5))))

=KAYDIR(A5;;MAK(EĞER(A5:L5<>"";COLUMN(A5:L5)))-1)

 

[ATEMİ]

Ömer bey ve Korhan bey çok teşekkür ederim geç döndüm kusura baymayın lütfen

 

[ATEMİ]

Her bir ayda 2 sütun olması durumunda nasıl yapabiliriz
gri renkli olanlar arasında ayrı yeşil olanları ayrı ayrı olarak

 

[ÖmerBey]

Deneyiniz...

=ARA(2;1/((A5:X5<>"")*(TEKMİ(SÜTUN(A5:X5))));A5:X5)
=ARA(2;1/((A5:X5<>"")*(ÇİFTMİ(SÜTUN(A5:X5))));A5:X5)

 

[ATEMİ]

Ömer bey çok teşekkür ediyorum saygılar

 

[ATEMİ]

Ömer bey her ayda iki sütun içinde iki değişken üzerinden bunu yaptık
üçüncü bir sütun olsa ama bu sadece oran gösterge sütunu olsa
yine değişkenler esas alınarak yapılacak ancak bir sütunun daha varlığı söz konusu olacak bu durumda ne yapmamız gerekir

 

[ÖmerBey]

TEKMİ ya da ÇİFTMİ ile sorgulanan şartı MOD formülüyle istediğiniz sayıya göre (ileride ihtiyaç olması durumunda 4, 5, 6…) ayarlayabilirsiniz. Örneğin;
MOD(SÜTUN(A5:X5);3)=0 üçe tam bölünen sütunları ifade eder.
İyi çalışmalar...

 

[ATEMİ]

Ömer bey denedim ama sonuç istediğim gibi olmadı
=ARA(2;1/((A5:AJ5<>"")*MOD(SÜTUN(A5:AJ5);3)=0))

 

[Korhan Ayhan]

Deneyiniz.

=ARA(2;1/(($A5:$AJ5<>0)*(MOD(SÜTUN($A5:$AJ5)-1;3)+1=SÜTUN(A$1)));$A5:$AJ5)

Bu da Ofis 365 için alternatif olsun. Dökülmeli olduğu için tek hücreye uygulamanız yeterlidir..

=AL(FİLTRE(A5:AJ5;A5:AJ5<>0);;-3)

 

[ATEMİ]

Korhan bey çok güzel çalıştı yeşil renkte olan veriler için formülde neyi değiştirmeliyim

 

[ATEMİ]

SÜTUN($A5:$AJ5)-2;3) bu sanırım doğru mu

 

[ATEMİ]

Korhan bey tam istediğim gibi oldu teşekkür ederim
Ömer bey size de çok teşekkür ediyorum sağlıcakla kalın

 

[Korhan Ayhan]

Birşey yapmanıza gerek yok.

Formülü ilk hücreye uyguladıktan sonra sağa doğru sürükleyiniz..

 

[ATEMİ]

Aynen çok güzel oldu tekrar teşekkür ederim saygılar