en üstte yazılan sayı veya metin

[modoste]

merhaba sayın hocalarım
bir listede en alta yazılanı bulma ile ilgili formüller kullanmaktayız
mesela B20:B100 aralığında ilk veri (B32 de diyelim) aralarda boşluk var. üstte veri olan ilk değeri nasıl buluruz.

B20:B100 arasında boş olmayan hücrelerin 1. si dizi formülüyle buldum ama başka formül =ARA(2;1... gibi olan)

 

[Muzaffer Ali]

Merhaba.

En üstteki değer eğer metinse aşağıdaki formül ile satır numarasını bulabilirsiniz.

=KAÇINCI("*";B20:B100;0)

 

[modoste]

en üstte olan veri (formülle veride bulabilir, formül sonucu EĞERHATA gibi ;"" da olabilir, sayıda olabilir, metinde olabilir)
yani en üstte boşluk olmayan ilk veriyi bulmalıyım

 

[Korhan Ayhan]

Deneyiniz.

=İNDİS(B20:B100;KAÇINCI(DOĞRU;İNDİS((B20:B100<>"");0);0))

Ya da;

=İNDİS(B20:B100;KAÇINCI(1;--İNDİS((B20:B100<>"");0);0))

 

[modoste]

Korhan Hocam, 2. formül doğru sonuç bulmuyor, ilk formül doğru sonuçlar buluyor.

 

[Korhan Ayhan]

2. formül dizi formül olabilir. Ofis 365 sürümünde dizi yapmaya gerek olmadığı için bazen ayırt edemiyorum.

 

[modoste]

dizi formülü ile denedim çözüm buldu hocam
(aslında son mesajımı yazmadan öncede dizi formülü CTRL+SHİFT+ENTER) ile denemiştim ama biryerde hata yaptım demek

 

[Korhan Ayhan]

Dizi formül ile alternatifler..

=DOLAYLI("B"&MİN(EĞER((B20:B100<>"");SATIR(B20:B100))))

=KAYDIR(B1;MİN(EĞER((B20:B100<>"");SATIR(B20:B100)))-1;)

=DOLAYLI("B"&KÜÇÜK(EĞER((B20:B100<>"");SATIR(B20:B100));1))

=KAYDIR(B1;KÜÇÜK(EĞER((B20:B100<>"");SATIR(B20:B100));1)-1;)

=İNDİS(B:B;KÜÇÜK(EĞER((B20:B100<>"");SATIR(B20:B100));1))

=İNDİS(B:B;MİN(EĞER((B20:B100<>"");SATIR(B20:B100))))

Ofis 365 sürümü için altenatif...

=İNDİS(FİLTRE(B:B;B:B<>"");1)

=AL(FİLTRE(B:B;B:B<>"");1)

=BIRAK(FİLTRE(B20:B100;B20:B100<>"");-(BAĞ_DEĞ_DOLU_SAY(FİLTRE(B20:B100;B20:B100<>""))-1))

 

[modoste]

=EĞERHATA(İNDİS(KAYDIR($AX$6;;KAÇINCI(D$5;$AX$3:$RK$3;0)-1;300;1);KAÇINCI(DOĞRU;İNDİS((KAYDIR($AX$6;;KAÇINCI(D$5;$AX$3:$RK$3;0)-1;300;1)<>"");0);0));"")

sizden gelen formülü kaydır ile kullanıp dinamik hale dönüştürdüm teşekkürler Korhan Hocam

 

[Korhan Ayhan]

Ofis 365 ile ilgili 2 adet daha alternatif ekledim.