excel eklentisi ??

[bad]

merhaba,

yapmak istediğim şey bir excel eklentisi boş bir excel açıldığında ikonlara bir makro ikonu eklesin ve ona bağlı bir makro çalışsın

Sub auto_open()

Application.CommandBars("Formatting").Controls.Add Type:=msoControlButton, ID:=2950, Before:=31
DUZENLE
End Sub

Sub DUZENLE()

Selection.NumberFormat = "#,##0"
End Sub

buradaki sorun şu
1- excel açıldığında sürekli olarak düğme ekleyip duruyor
2- duzenle makrosunu eklememe excel açılıp düğmeyi tıkladığımda tekrar makro ekle diyor
örnek olması açısından dosyayı gönderiyorum

yardımlarınız için şimdiden teşekkürler

 

[nziya]

Sub auto_open()
Dim cbMenu As CommandBarControl

MenuSil

Set cbMenu = Application.CommandBars(1).Controls.Add(msoControlPopup, , , , True)
With cbMenu
.Caption = "&DENEME" 'Araç çubuğuna DENEME isimli menü ekler
.OnAction = "formac"
.Tag = "MyTag"
.BeginGroup = True
End With

If cbMenu Is Nothing Then Exit Sub

Set cbSubMenu = Nothing
Set cbMenu = Nothing
End Sub

Sub MenuSil()
kaldir "MyTag"
End Sub

Private Sub kaldir(CustomControlTag As String)
On Error Resume Next
Do
Application.CommandBars.FindControl(, , CustomControlTag, False).Delete
Loop Until Application.CommandBars.FindControl(, , CustomControlTag, False) Is Nothing
On Error GoTo 0
End Sub

Sub auto_close()
MenuSil
End Sub

Sub formac()
UserForm1.Show
End Sub

 

[Haluk]

http://www.excel.web.tr/viewtopic.php?p=74466#74466

 

[bad]

arkadaşlar hepinize teşekkür ederim işim halloldu..

yalnız şu ikonların nolarını ( MyButton.FaceId = 7 ) gösteren bir liste varmıdır.

 

[xxrt]

şu ikonların nolarını ( MyButton.FaceId = 7 ) gösteren bir liste varmıdır.

http://www.excel.web.tr/viewtopic.php?p=51765#51765

 

[Haluk]

Liste oluşturmak için alternatif;

    'Haluk ® - 17/02/2006
    Sub CommandBarControlID()
        Dim Header1 As String * 5
        Dim Header2 As String * 38
        Dim Header3 As String * 10
        Dim Capt As String * 30
        Dim WinScrObj As Object, MyShortCut As Object
        Dim MyFolder As String, MyFile As String
        Dim TargPath As String

        TargPath = "C:\MS-ExcelControlsID.txt"
        MyFile = "MS-ExcelControlsID.txt"
       
        Header1 = "No"
        Header2 = "Kontrol"
        Header3 = "ID"
            Open TargPath For Output As #1
            Print #1, Header1; Header2; Header3
            Print #1, String(50, "-")
            Print #1,
                For Each Ctrl In CommandBars.FindControls
                    i = i + 1
                    Capt = Replace(Ctrl.Caption, "&", "")
                    CtrlId = Ctrl.ID
                    Print #1, i & ") "; Capt, CtrlId
                Next
            Close #1
           
        Set WinScrObj = CreateObject("WScript.Shell")
        MyFolder = WinScrObj.SpecialFolders("DeskTop")
        Set MyShortCut = WinScrObj.CreateShortcut _
                        (MyFolder & "\" & MyFile & ".lnk")
        With MyShortCut
            .TargetPath = WinScrObj.ExpandEnvironmentStrings(TargPath)
            .WorkingDirectory = WinScrObj.ExpandEnvironmentStrings(TargPath)
            .WindowStyle = 4
            .IconLocation = WinScrObj.ExpandEnvironmentStrings(TargPath & ", 0")
            .Save
        End With
       
        MsgBox "Masaustune dosya icin kisa yol olusturuldu ...", vbInformation, "Rapor !"
        Set WinScrObj = Nothing
        Set MyShortCut = Nothing
    End Sub

 

[bad]

hepinize çooooooooooooooook teşekkür ederimmmmmmm...
:hey: :hey: