Excel'den Outlook Web ile mail göndermek.

[Cengiz Demir]

Forumu araştırdım fakat outlook web ile ilgili bilgi bulamadım.
Excelden seçili verileri outlook uygulamasıyla mail olarak gönderebilen makrolora ulaşabildim.
Hatta birisini test ettim sorunsuz çalışıyor.
Kodlar aşağıda. (Kimden alıntı yaptığımı hatırlamıyorum. aşağıdaki kodlar için o kişiye de ayrıca teşekkürler .)

Mümkün mü bilmiyorum ? Mümkünse aşağıdaki kodlardan nerelerde değişiklik yapmak gerekiyor ?

İlgilenen herkese çok teşekkürler.

Not: Bu kodların çalıştırılacağı bilgisayarda (işyeri bilgisayarı) eski sürüm outlook(2010) var
ve o sürüm şirketin outlook serveri tarafından desteklenmediği için, hesap yapılandırılamıyor.
Yeni sürüm outlook yükleme imkanımız da yok.

Sub mail_secili_alan()
      Dim wrdEdit
      Dim alan As Range
     
       Set alan = Range("A11:H11", "A1:H9").SpecialCells(xlCellTypeVisible)
 
           
      Set OutApp = CreateObject("Outlook.Application")
      Set OutMail = OutApp.CreateItem(0)
      With OutMail
       .To = "mailadresi1@isim.com;mailadresi2@isim.com;"
       .CC = ""
       .BCC = ""
       .Subject = "mail konu"
       .Display
     
       'Maili otomatik göndermek için .send deki tırnak işaretini kaldırın.
       '.send
       .HTMLBody = RangetoHTML(alan) & .HTMLBody
       End With
     
      Set wrdEdit = Nothing
      Set OutMail = Nothing
      Set OutApp = Nothing
End Sub

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2013
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function