FARKLI DEĞİŞKENLERE GÖRE TOPLAM ALDIRMAK

[jidame]

ÖRNEK EXCELİM : ÖRNEKSORU


merhabalar
1.SHEET (ÖZET)
A1 hücresi ARABA, MOTOR vb.
B1 hücresi TUTAR - ( 2.Sheet B1 hücresindeki ARABA nın TUTARI )
C1 hücresi SEÇMELİ KİŞİ ( Arama için isim yazacağım kısım )


2.SHEET (LİSTE)
A1 hücresi ARABA
B1 hücresi TUTAR
C1 hücresi AHMET (yada boş)


şimdi ben ÖZET teki TUTAR kısmına ulaşabilmek için; ÖZET deki C1 hücresine kişinin ismini yazınca eğer bu kişi 2.Sheet (LİSTE) deki C1 hücresinde varsa tutarı getiriyor. Ama ben şunu yapmak istiyorum : ARAMA kısmına "isim girmesem" dahi bana ARABANIN/ARABALARIN toplam tutarını getirsin yani (zaten isim yazınca buluyor getiriyor da ben isim yazmadığım da ARABALARIN hepsinin toplamı orada gözüksün; isim yazınca değişsin, yazmadığım da genel gözüksün istiyorum)

kolay ama yapamadım
tşler

 

[çıtır]

Sorunuzu "örnek" excel dosyası ekleyerek sorarsanız, daha hızlı ve doğru cevaplar alabilirsiniz.
Örnek excel dosyası ekleme hakkında bilgi edinmek isterseniz:
https://www.excel.web.tr/threads/soru-ile-ilgili-oernek-excel-dosyasi-ekleme.174755/ bakınız.

 

[jidame]

örnek excelim: SORU EXCELİ

 

[jidame]

Sorunuzu "örnek" excel dosyası ekleyerek sorarsanız, daha hızlı ve doğru cevaplar alabilirsiniz.
Örnek excel dosyası ekleme hakkında bilgi edinmek isterseniz:
https://www.excel.web.tr/threads/soru-ile-ilgili-oernek-excel-dosyasi-ekleme.174755/ bakınız.

ekledim acaba yardımcı olabilir misiniz

 

[çıtır]

Dosyanız.Genel toplam haricindeki formüller dizi formülü.Formülü yazdıkdan sonra ctrl ve shift tuşuna basılı iken enterle çıkmalısınız.Tek formülle çözemedim.Dolaylı fonksiyonu ve satır ,sütun fonksiyonları kullanılarak 2 formülle çözülebilir gibi görünüyor.Her satır ayrı formül.
https://www.dosyaupload.com/6b3j

 

[jidame]

Dosyanız.Genel toplam haricindeki formüller dizi formülü.Formülü yazdıkdan sonra ctrl ve shift tuşuna basılı iken enterle çıkmalısınız.Tek formülle çözemedim.Dolaylı fonksiyonu ve satır ,sütun fonksiyonları kullanılarak 2 formülle çözülebilir gibi görünüyor.Her satır ayrı formül.
https://www.dosyaupload.com/6b3j

evet elinize sağlık , sonuca ulaşabiliyorum ama benim excelim ve tablom bir hayli uzun..
dolayısıyla her birine formül girmek bir hayli iiş

acaba makro yada kod ile çözebiilir miyiz ki?

 

[çıtır]

Sayfa2 de bir yardımcı sütun kullansak olur mu ?

 

[jidame]

Sayfa2 de bir yardımcı sütun kullansak olur mu ?

yeter ki her yere formül girmek zorunda kalmayayım, olabilir ,

 

[çıtır]

Sayfa2 A Sütunda Fare sağ tuş yaparak ekle sütun seçiniz.Eklediğiniz sütunda A2 Hücresine aşağıdaki formülü yazınız.Aşağı doğru çoğaltınız.

=B2&C2

Sayfa1 B2 Hücresine aşağıdaki formülü kopyalayınız.Genel toplama kadar sağa ve aşağı çekerek çoğaltınız.

=EĞERHATA(EĞER($A2="";"";EĞER($G$2<>"";İNDİS(Sayfa2!$D$2:$G$200;KAÇINCI($G$2&B$1;Sayfa2!$A$2:$A$5;0);KAÇINCI($A2;Sayfa2!$D$1:$G$1;0));ETOPLA(Sayfa2!$C$2:$C$200;B$1;KAYDIR(Sayfa2!$C$2;;SATIR($A1);100))));"")

Sayfa1 Genel toplamın altındaki ilk satıra aşağodaki formülü kopyalayınız.Aşağı doğru yeterinçe çoğaltınız.

=EĞER($A2="";"";TOPLA($B2:$C2))

 

[jidame]

Sayfa2 A Sütunda Fare sağ tuş yaparak ekle sütun seçiniz.Eklediğiniz sütunda A2 Hücresine aşağıdaki formülü yazınız.Aşağı doğru çoğaltınız.

=B2&C2

Sayfa1 B2 Hücresine aşağıdaki formülü kopyalayınız.Genel toplama kadar sağa ve aşağı çekerek çoğaltınız.

=EĞERHATA(EĞER($A2="";"";EĞER($G$2<>"";İNDİS(Sayfa2!$D$2:$G$200;KAÇINCI($G$2&B$1;Sayfa2!$A$2:$A$5;0);KAÇINCI($A2;Sayfa2!$D$1:$G$1;0));ETOPLA(Sayfa2!$C$2:$C$200;B$1;KAYDIR(Sayfa2!$C$2;;SATIR($A1);100))));"")

Sayfa1 Genel toplamın altındaki ilk satıra aşağodaki formülü kopyalayınız.Aşağı doğru yeterinçe çoğaltınız.

=EĞER($A2="";"";TOPLA($B2:$C2))

merhabalar
denedim ama şöyle bir sıkıntımız var ; sanırım sıra sıra toplam alıyor bu formül ve isimlerin tek olduğunu baz alıyor ama aynı isimler listenin ilerleyen kısımlarında tekrar ettiğinde kişiyle ilgili doğru toplamları vermiyor.

SORUMUN ÖZETİ : Arama kısmına isim girdiğimde o kişiyle ilgili toplamlar , isim girmeyince genel toplamlar çıksın

dosyanın son hali : ARAÇ

 

[çıtır]

Dosyanız.Formülü,Sayfa1 B2 hücresine uygulayın sağa ve aşağı doğru çoğaltınız.

=EĞER(VE($G$2<>"";A2<>"");ÇOKETOPLA(DOLAYLI("Sayfa2!"&ADRES(2;SATIR(A3))&":"&ADRES(200;SATIR(A3)));Sayfa2!$A$2:$A$200;$G$2;Sayfa2!$B$2:$B$200;B$1);EĞER(VE($G$2="";$A2<>"");ETOPLA(Sayfa2!$B$2:$B$200;B$1;DOLAYLI("Sayfa2!"&ADRES(2;SATIR(A3))&":"&ADRES(200;SATIR(A3))));""))

https://www.dosyaupload.com/6b8z

 

[Ömer BARAN]

Sorun çözülmüştür diye düşünüyorum, benim önerim de alternatif olsun.
Formülü, Sayfa1'de B2 hücresine uygulayıp sağa ve aşağı doğru kopyalayın.

=TOPLA.ÇARPIM((Sayfa2!$B$2:$B$6=B$1)*(Sayfa2!$C$1:$E$1=$A2)*((Sayfa2!$A$2:$A$6=$G$2)+($G$2="")*(Sayfa2!$A$2:$A$6<>""))*(Sayfa2!$C$2:$E$6))

 

[jidame]

Dosyanız.Formülü,Sayfa1 B2 hücresine uygulayın sağa ve aşağı doğru çoğaltınız.

=EĞER(VE($G$2<>"";A2<>"");ÇOKETOPLA(DOLAYLI("Sayfa2!"&ADRES(2;SATIR(A3))&":"&ADRES(200;SATIR(A3)));Sayfa2!$A$2:$A$200;$G$2;Sayfa2!$B$2:$B$200;B$1);EĞER(VE($G$2="";$A2<>"");ETOPLA(Sayfa2!$B$2:$B$200;B$1;DOLAYLI("Sayfa2!"&ADRES(2;SATIR(A3))&":"&ADRES(200;SATIR(A3))));""))

https://www.dosyaupload.com/6b8z

Sorun çözülmüştür diye düşünüyorum, benim önerim de alternatif olsun.
Formülü, Sayfa1'de B2 hücresine uygulayıp sağa ve aşağı doğru kopyalayın.

teşekkürler, elinize sağlık ikisi de sonuca ulaştırıyor

 

[çıtır]

teşekkürler, elinize sağlık ikisi de sonuca ulaştırıyor

Rica ederim.Dönüş yaptığınız için teşekkür ederim.