filtre ve devrik dönüşüm hk.

[zetkatamet]

Arkadaşlar,
Ekteki dosyaya bakabilirmisiniz. Eksik ve tekrarlanan saatlerin bulunması ile ilgilidir.

 

[Korhan Ayhan]

Merhaba,

Tekrar eden tarih ve saatler için...

=LET(X;FİLTRE(E2:E1000;EĞERSAY(E2:E1000;E2:E1000)>1);
 ÖZETÖLÇÜT(SIRALA(TAMSAYI(X));SIRALA(MOD(X;1));MOD(X;1);BAĞ_DEĞ_SAY))

Sonuçlar dökülmeli gelecektir. Başlık hücrelerini TARİH ve SAAT olarak biçimlendirmeniz gerekir.

Diğer sorunuz içinde akşam müsait olursam cevap yazarım.

 

[Korhan Ayhan]

Diğer sorunuz içinde bunu deneyebilirsiniz. Yine tüm liste dökülmeli olarak listelenir.

=LET(X;LET(
     Tarih;BENZERSİZ(TAMSAYI(E2:E40));
     Zaman;SIRALI(24;1;0;1/24);
     Liste;SÜTUNA(Tarih+DEVRİK_DÖNÜŞÜM(Zaman));
     FİLTRE(Liste;EYOKSA(KAÇINCI(Liste;TAMSAYI(E2:E40)+SAAT(E2:E40)/24;0)))
     );ÖZETÖLÇÜT(SIRALA(TAMSAYI(X));SIRALA(MOD(X;1));MOD(X;1);BAĞ_DEĞ_SAY)
     )

 

[Korhan Ayhan]

Bunlar karışık gelirse ve dikey listeler işimi görür derseniz de aşağıdaki formüller yeterli olacaktır.

Tekrar Eden tarihler;

=FİLTRE(E2:E1000;EĞERSAY(E2:E1000;E2:E1000)>1)

Eksik Listesi için;

=LET(Tarih;BENZERSİZ(TAMSAYI(E2:E40));
     Zaman;SIRALI(24;1;0;1/24);
     Liste;SÜTUNA(Tarih+DEVRİK_DÖNÜŞÜM(Zaman));
     FİLTRE(Liste;EYOKSA(KAÇINCI(Liste;TAMSAYI(E2:E40)+SAAT(E2:E40)/24;0))) )