Filtre yapılan bölümde veri saydırma

[vurkan]

Arkadaşlar merhaba. Basit bir müşteri takip çizelgesi hazırlıyorum. Bu konuda bir iki sorunum var.

1. A sütununda filtreleme yaptığımda D2 hücresine Filtrelenen alandaki "ÇIKTI" kelimesinin sayısını D3 hücresine ise filtrelenen bölümdeki boş hücre sayısını (Alttoplam alır gibi) yazdıracak bir formül nasıl olmalı. EĞERSAY dediğimde tüm sütunu sayıyor.

2. B sütununa müşteri adı girilip enter yapılınca eğer o sütunda o kişi daha önce yazılmış ise C sütununa telefonunu, GHI sütunlarına adres bilgilerini önceki kayıttan alarak yazmasını sağlayan bir kod yazılabilir mi?

3. Günlük veriler girileceğinden veri girilecek satırın ekranın ortasında olması için veri girdikçe satırlar yukarı kaydırılabilir mi? Saygılar.

İndir KARGO TAKİP

Dosyayı indir KARGO TAKİP

dosya.co

 

[Korhan Ayhan]

1. sorunuz için;

D2 hücresine;

=TOPLA.ÇARPIM(ALTTOPLAM(3;KAYDIR($A$3;SATIR($A$4:$A$30)-3;))*($D$4:$D$30="ÇIKTI"))

D3 hücresine;

=TOPLA.ÇARPIM(ALTTOPLAM(3;KAYDIR($A$3;SATIR($A$4:$A$30)-3;))*($D$4:$D$30=""))

2. ve 3. sorunuz için;

Sayfanızın kod bölümüne aşağıdaki kodu uygulayınız.

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Bul As Range
    If Intersect(Target, Range("B4:B" & Rows.Count)) Is Nothing Then Exit Sub
    Set Bul = Range("B4:B" & Target.Row - 1).Find(Target, , , xlWhole)
    If Not Bul Is Nothing Then
        Target.Offset(0, 1) = Bul.Offset(0, 1)
        Target.Offset(0, 5) = Bul.Offset(0, 5)
        Target.Offset(0, 6) = Bul.Offset(0, 6)
        Target.Offset(0, 7) = Bul.Offset(0, 7)
    End If
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim Ust_Satir As Long, Aktif_Satir As Long, Satir_Say As Long
    Ust_Satir = ActiveWindow.ActivePane.ScrollRow
    Aktif_Satir = Target.Row
    Satir_Say = Windows(1).VisibleRange.Rows.Count
    If Ust_Satir <= Aktif_Satir Then
    ActiveWindow.SmallScroll Down:=Aktif_Satir - Ust_Satir - (Satir_Say / 2)
    End If
End Sub

 

[vurkan]

Sayın Korhan Ayhan her zamanki gibi ilgi, bilgi ve emeğinizi esirgememişsiniz. Rabbim razı olsun. çok teşekkürler.