Fonksiyon hataları

[ATEMİ]

Merhaba,
Aşağıdaki formülü kullandığımda "#Sayı/0!" hatası alıyorum,
EĞER($N$6="";"";(EĞER($A$3="Dikey Analiz";(N7/$N$6);EĞER($A$2=1;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-D7)/D7;EĞER($A$2=2;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-F7)/F7;EĞER($A$2=3;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-H7)/H7;EĞER($A$2=4;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-J7)/J7;EĞER($A$2=5;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-L7)/L7;0))))))))

formülü bu şekilde yaptığımda ise, "Bu formül geçerli dosya biçiminde kullanabileceğinizden daha fazla iç içe yerleştirme düzeyi kullanıyor" hatası veriyor
EHATALIYSA(EĞER($N$6="";"";(EĞER($A$3="Dikey Analiz";(N7/$N$6);EĞER($A$2=1;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-D7)/D7;EĞER($A$2=2;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-F7)/F7;EĞER($A$2=3;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-H7)/H7;EĞER($A$2=4;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-J7)/J7;EĞER($A$2=5;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-L7)/L7;0))))))));0)

ne yapmam gerekiyor yardımcı olabilirseniz sevinirim

 

[ÖmerFaruk]

Bu şekilde anlamak ve düzeltmek çok zor.
Sizden ricam Excel Versiyon ve dilinizi İmza kısmına yazmanız (ki sorunuzun çözümü buna göre değişmektedir)
Formülün kullanıldığı sayfaların ve hücrelerin var olduğu 3-4 satırlık bir veri dosyanız.
Hatta sonuçta ne görmk istediğinizi de formülün uygulanacağı hücrede Manuel olararak yazarsanız güzel olur

 

[ATEMİ]

Haklısınız, imzamı düzelttim
Veri dosyası yüklemem çok zor olacak çünkü bir çok sayfaya bağlı formüller var
dönemler itibariyle değişim oranı elde etmek istiyorum aşağıdaki formül istediğim sonucu veriyor tek sıkıntım
ilgili hücre boş olduğunda "#Sayı/0!" hatayı alıyorum buna çözüm olarak ehatalıysa fonksiyonunu kullandığımda
"Bu formül geçerli dosya biçiminde kullanabileceğinizden daha fazla iç içe yerleştirme düzeyi kullanıyor" hatası alıyorum

 

[1Al2Ver]

Merhaba,

N6 boş ise boş kurgusu sonucunda devam eden formülde ;

boş hücre, boş hücreye bölündüğünde "#Sayı/0!" hatası alırsınız,

Bence boş hücreler yerine sıfır yazdırıp, sıfırları gizleye bilir yada rengini beyaz yapabilir siniz.

Teşekkür ederim.

 

[ATEMİ]

Sıfırların görünmesinde sakınca yok ama bu hatayı almamam lazım ben teşekkür ederim

 

[1Al2Ver]

Merhaba,

=EĞER($N$6="";0;(EĞER($A$3="Dikey Analiz";(N7/$N$6);EĞER($A$2=1;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-D7)/D7;EĞER($A$2=2;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-F7)/F7;EĞER($A$2=3;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-H7)/H7;EĞER($A$2=4;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-J7)/J7;EĞER($A$2=5;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-L7)/L7;0))))))))

şeklinde denediniz mi ?

 

[ÖmerFaruk]

Hatayı almanız doğal. içiçe eğer sayınız limitlerin dışında.

Ben halen imzanızı göremedim. Şimdi yardımcı olacağım fonksiyon hata verdi diyeceksiniz. Excel 2003 mü yoksa 365 mi kullanıyorsunuz.

Örnek dosyanızı Şirket veya Şahıs ismi vermeden, varsa formüllerinizi DEĞER olarak aynı bölgeye yapıştırarak verebilirsiniz. Formül dahil 3 sayfa var formülünüzde. Zor olmasa gerek.

 

[ATEMİ]

Sayın Ömer Faruk yazınızdan hemen sonra imzama ekledim bende görünüyor sanırım teknik bir sıkıntı olmuş. Office2016 Türkçe
Dosyayı yüklüyorum çok haklısınız görmeden zor olur.

 

[ATEMİ]

Sayın 1AI2Ver denedim bu şekilde olmuyor

 

[ÖmerFaruk]

Elde verileriniz olmadığı için deniyorum. Halbuki ilk mesajımda dediğim gibi toplam 3 sayfadan oluşan ve excel sayfanızı Özel yapıştır değerleri diyerek yeni bir dosya oluştursaydınız daha kolay olacaktı.
Yine de bir sürü eğer arasında cebelleşip takip edebildiğim kadarıyla parantez hatası yapıyorsunuz.

=EĞER($N$6="";0;EĞER($A$3="Dikey Analiz";(N7/$N$6);EĞER($A$2=1;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-D7)/D7;EĞER($A$2=2;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-F7)/F7;EĞER($A$2=3;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-H7)/H7;EĞER($A$2=4;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-J7)/J7;EĞER($A$2=5;(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-L7)/L7;0)))))))

Sol baştan 2.eğerin solundaki parantez hatalıydı.
Bunun dışında bir şey görebilmek için verilerinize ihtiyaç var.

Verileriniz olmadan belki doğru çözmüşümdür. Aşağıdaki formülü daha kısa olarak kullanabilirsiniz.
=EĞERHATA(EĞER($A$3="Dikey Analiz";(N7/$N$6);(DÜŞEYARA($B7;'Cari Dönem Mizan (B)'!$B:$F;5;0)-KAYDIR($B$7;0;2*$A$2;1;1))/KAYDIR($B$7;0;2*$A$2;1;1));0)

 

[ATEMİ]

Ömer Faruk Bey, öncelikle size zahmet verdiğim için ve buna rağmen ilgilendiğiniz için teşekkür ederim
İlk formül olmadı ama sizin yazdığınız formül başarılı görünüyor emeğiniz için çok sağ olun