Formüllü hücrelerde Son boş hücre

[mozdem]

Merhabalar,
Bu sorunun cevabı sitenizde vardı ama bulamadım. Ben bugüne kadar son dolu hücreyi bulmak için

son_sat = Sheets("DATA").Range("O" & Rows.Count).End(xlUp).Row

yazıyordum. Sayfamda formül var. formül sonucu boş ("") olsa da yukarıdaki kod dolu gibi gösteriyor.
Nasıl bir kod yazmalıyım. Teşekkür ederim.

 

[tugkan]

Formülle boş (“”) görünen hücreleri de dolu olarak algılamayan bir yöntem için, hücrelerin gerçekten veri içerip içermediğini kontrol eden bir VBA kodu kullanabilirsiniz. Aşağıdaki kod, formül sonucu boş olan hücreleri atlayarak son dolu hücreyi bulur:

Dim son_sat As Long
With Sheets("DATA")
    son_sat = .Cells(.Rows.Count, "O").End(xlUp).Row
    Do While .Cells(son_sat, "O").Value = ""
        son_sat = son_sat - 1
    Loop
End With

Bu kod, önce Range("O" & Rows.Count).End(xlUp).Row ile son dolu hücreyi bulur, ardından Do While döngüsüyle hücre değeri gerçekten boş ("") ise bir üst satıra geçer. Bu şekilde, formül sonucunda boş olan hücreler atlanır ve son gerçekten dolu olan hücreye ulaşılır.

 

[mozdem]

Teşekkür ederim.

 

[Korhan Ayhan]

Döngüsüz daha hızlı sonuç verecek alternatifler..

Option Explicit

Sub Last_Row_1()
    Dim Last_Row As Long
    
    Last_Row = Columns("O").Find(What:="*", LookIn:=xlValues, SearchDirection:=xlPrevious).Row
    
    MsgBox "Son dolu hücre satır numarası: " & Last_Row
End Sub

Option Explicit

Sub Last_Row_2()
    Dim Last_Row As Long
    
    Last_Row = Evaluate("LOOKUP(2,1/(O:O<>""""),ROW(O:O))")
    
    MsgBox "Son dolu hücre satır numarası: " & Last_Row
End Sub

 

[mozdem]

Çok teşekkür ederim hocam

Döngüsüz daha hızlı sonuç verecek alternatifler..

Option Explicit

Sub Last_Row_1()
    Dim Last_Row As Long
   
    Last_Row = Columns("O").Find(What:="*", LookIn:=xlValues, SearchDirection:=xlPrevious).Row
   
    MsgBox "Son dolu hücre satır numarası: " & Last_Row
End Sub

Option Explicit

Sub Last_Row_2()
    Dim Last_Row As Long
   
    Last_Row = Evaluate("LOOKUP(2,1/(O:O<>""""),ROW(O:O))")
   
    MsgBox "Son dolu hücre satır numarası: " & Last_Row
End Sub