Formülün boş hücrede sıfır değer alması

[leventunc]

Merhabalar değerli forum sakinleri,

Bu çalışmamızda, küçükten büyüğe doğru sıralama işlemini yapan 2 tane formülümüz mevcut. Bunlardan I21 hücresinde yer alan formülde ufak bir düzenleme yapmak istiyoruz.

I21 Hücresindeki formülün işlevi: H21 hücresine manuel girilen değerlerin G21 hücresindeki sıralamada kaçıncı sırada olduğunu bize gösteriyor.


Yapmak istediğimiz: H21 hücresi boş olduğu zaman I21 hücresinin 0 gözükmesi. H21 hücresindeki değerler silinince I21 hücresindeki formül 111 halini alıyor. Bu da ilintili olduğu başka hücrelerin yanlış değer vermesine sebep oluyor.


Örnek çalışma LAB-IVa isimli dosya ekinde mevcuttur.

 

[Ömer]

Merhaba,

Deneyiniz.

=EĞER(H21="";0;MBUL(SOLDAN(H21;1);G21)&MBUL(PARÇAAL(H21;2;1);G21)&MBUL(PARÇAAL(H21;3;1);G21))

 

[leventunc]

Harikasınız Ömer bey, tebrik ederiz. Hazır sizi yakalamışken rica etsek G21 hücresinde yer alan formüle de göz atabilir misiniz lütfen? Onu biraz daha derleyip toparlayıp, sadeleştirebilir miyiz acaba?

 

[Ömer]

G21 hücresinde yapılmak isteneni detaylı açıklar mısınız.

 

[leventunc]

Kısa Bilgi: Başlıkta yer alan ABCDEF harfleri, sırayla 123456 rakamlarını temsil etmektedir. (Örnek: A=1, B=2, C=3, D=4, E=5, F=6)

G21 Hücresindeki Formülün İşlevi: A21:F21 aralığına manuel girilen değerleri otomatikmen G21 hücresinde küçükten büyüğe doğru sıralama işlevini yerine getiriyor.

Yapmak İstediğimiz: Formül çok uzun ve karmaşık gözüküyor. Çalışmanın başka noktalarına uyarlamada biraz zorluk yaşıyoruz. Aynı işleve sahip biraz daha sade bir formül olması çalışmadaki hızımızı arttıracağı kanaatini taşıyoruz.

 

[Ömer]

Merhaba,

Sonuçları birleştirme yaptığınız için makro dışında kısaltma yolu yok maalesef.

Normalde aşağıdaki formül bu istediğinizi karşılar fakat sonuçları bir işleme sokmadan birleştirme yapmak istediğiniz için diziyi dışarıya istediğinizi gibi çıkartamıyoruz.

Aşağıdaki formülü hücreye kopyaladıktan sonra, formülün içine girip "F9" tuşuna basarsanız sonuç diziyi görebilir ve söylemek istediğimi daha kolay anlayabilirsiniz.

=KAÇINCI(KÜÇÜK(A21:F21;SÜTUN(A21:F21));A21:F21;0)

F9 dan sonra;

={5;2;3;4;6;1}

.

 

[leventunc]

Şu aşamada işlemlerin otomatik yapılması, çalışmalarımızda daha hızlı sonuçlar alıp, bir üst basamağa geçip zamandan kazanmamızda büyük önem arz ediyor. Bu formül de ikinci bir seçenek olarak formüllerimiz arasındaki yerini aldı. İlgilendiğiniz için tekrardan çok teşekkür ederiz Ömer bey.

 

[leventunc]

Merhabalar Ömer bey, yine bu çalışmamızın daha kapsamlı haliyle ilgili bir düzenleme yapmak istiyoruz. Bu konuda bize yardımcı olabilirseniz çok mutlu oluruz.

1. Formülün İşlevi: A20:L20 aralığına manuel girilen değerleri otomatikmen M20 hücresinde küçükten büyüğe doğru sıralama işlevini yerine getiriyor.

2. Formülün İşlevi: N20 hücresine manuel girilen rakamların (Ör: 3,11,6), M20 hücresinde yer alan rakamlar içinde kaçıncı sırada olduğunu bize otomatikmen geliş sırasına göre O20 hücresinde işlevini yerine getiriyor.

Yapmak İstediğimiz: M20 ve O20 hücrelerindeki karmaşanın önüne geçmek. Yani rakamların arasına virgül koymak. (Örnek: 1,12,3,9,11.......)

 

[Ömer]

Merhaba,

İmleç M20 hücresinde olsun ve aşağıdakileri uygulayın. Yani M20 aktif olsun.

Ctrl + H (bul değiştir)
Aranan bölümüne: &
Yeni değer bölümünü: &","&

Yazıp tamam ile işlemi bitirin. Buradaki amaç formülde kullandığınız & simgelerine "," eklemekti. Fazla olduğu için yukarıdaki yol tek tek eklemeye göre daha pratiktir.

O20:
=EĞERHATA(EĞER(N20="";0;MBUL(SOLDAN(N20;1);YERİNEKOY(M20;",";""))&","&MBUL(PARÇAAL(N20;2;1);YERİNEKOY(M20;",";""))&","&MBUL(PARÇAAL(N20;3;1);YERİNEKOY(M20;",";"")));0)

.

 

[leventunc]

Merhabalar Ömer bey, değerleri manuel olarak girdiğimiz N20 hücresinde virgül kullanma zorunluluğumuz doğdu. (Ör: 9,11,1). İkinci formülün yer aldığı O20 hücresi işlevini yitirmeden bu şekilde de sıralama görevini yerine getirmesini istiyoruz. Bunu nasıl yapabiliriz?

 

[Ömer]

O20:

=EĞERHATA(EĞER(N20="";0;MBUL(SOLDAN(N20;1);YERİNEKOY(M20;",";""))&","&MBUL(PARÇAAL(YERİNEKOY(N20;",";"");2;1);YERİNEKOY(M20;",";""))&","&MBUL(PARÇAAL(YERİNEKOY(N20;",";"");3;1);YERİNEKOY(M20;",";"")));0)

.

 

[leventunc]

Ömer bey şöyle bir durum var;
M20'de mevcut olan sıralama: 3,7,9,5,2,6,4,8,10,11,1,12
N21'de 4,11,7 değerleri var (Manuel girilen değerler)
O20'de sıralama olarak 7,9,9 gözüküyor. (Olması gereken doğru sıralama: 7,10,2)

 

[Ömer]

Formülün içeriğini kontrol etmedim. Verdiğiniz örneğe göre, formüllerin eski haliyle doğru sonuç alıyor muydunuz?

 

[leventunc]

M20'de mevcut olan sıralama: 3,7,9,5,2,6,4,8,10,11,1,12
N21'de 4,11,7 değerleri var (Manuel girilen değerler)
O20'de sıralama olarak 7,9,9 gözüküyor. (Olması gereken doğru sıralama: 7,10,2)

Yine aynı şekilde bu değerlerle virgül eklenmemiş formül ile denediğimizde aynı sonucu veriyor (7,9,9). Dediğiniz gibi formülde bir sorun var. Lütfen bu formüle tez vakitte bir el atmanızı rica ediyoruz.

 

[leventunc]

Şuan yapmış olduğumuz denemeler neticesinde, bu formül ile 9. basamağa (1,2,3,4,5,6,7,8,9) kadar doğru sonuç elde ediyoruz. 10,11,12 basamaklarında karışıklık yaşanıyor.

 

[Ömer]

Bu şekilde deneyiniz.

=EĞERHATA(EĞER(N20="";0;MBUL(SOLDAN(N20;BUL(",";N20)-1);YERİNEKOY(M20;",";""))&","&MBUL(SOLDAN(PARÇAAL(N20;BUL(",";N20)+1;256);BUL(",";PARÇAAL(N20;BUL(",";N20)+1;256))-1);YERİNEKOY(M20;",";""))&","&MBUL(SAĞDAN(N20;UZUNLUK(N20)-BUL("*";YERİNEKOY(N20;",";"*";UZUNLUK(N20)-UZUNLUK(YERİNEKOY(N20;",";"")))));YERİNEKOY(M20;",";"")));0)

.

 

[leventunc]

''This is it!'' demekten başka bir şey bulamıyoruz. Çok teşekkür ederiz.

 

[Ömer]

Önemli değil, yalnız aralıklar ve şartlar artıkça formül karmaşası sizi yorabilir. Benim tavsiyem yine formül fakat kullanıcı tanımlı formül(makro ile) kullanmanızdır.

Ekteki örnekte, M24 ve O24 hücrelerinde uygulanmış hali mevcuttur ve kullanımı kolaydır.

.

 

[leventunc]

Şuanki noktada herşeyi kendi kontrolümüz altında tutacak şekilde ilerleme kat etmek zorundayız. Onun için makro kullanımını en sona bırakıyoruz. Yine de düşündüğünüz için çok teşekkür ederiz.

 

[Ömer]

Bir kenarda dursun fikriniz değişirse kullanırsınız Aralıkları formül gibi siz seçeneğiniz için kontrol yine sizde oluyor.