Çözüldü Gün Farkı Hesaplama

[gicimi]

Merhaba;

Ekteki dosya da A Sütunundaki Malzeme No aynı sayfasının "H" sütununda arama yapıp bulması durumda giriş tarihlerini çıkararak gün farkını nasıl hesaplayabilirim.

Listede olmayan Malzeme No için "Listede Yok" yazmasını ve Sayfa2 ye H - L sütunlarına ait bilgilerinin aktarılmasını istiyorum.
Dosyada satır sayısı: 5.000 Adettir.

Formül olarak sadece gün farkı nasıl hesaplanabilir. Şimdiden teşekkür ederim.

 

[Orion1]

Dosyanız ektedir.
=EĞER(EĞERSAY($A$2:$A$15;$H2)=0;"Listede Yok";$L2-DÜŞEYARA($H2;$A$2:$E$15;5;0))

 

[gicimi]

@Orion1 Evren Hocam formül için teşekkür ederim. Elinize sağlık.

 

[Orion1]

Rica ederim.
İyi çalışmalar.

 

[gicimi]

Makro konusu güncel yardımlarınız lütfen.

 

[Orion1]

Buyurun.

Sub malzemeno_59()
Dim i As Long, sonsat1 As Long, sonsat2 As Long, k As Range
sonsat1 = Cells(Rows.Count, "A").End(xlUp).Row
sonsat2 = Cells(Rows.Count, "H").End(xlUp).Row
Range("M2:M" & Rows.Count).ClearContents
For i = 2 To sonsat2
    Set k = Range("A2:A" & sonsat1).Find(Cells(i, "H").Value, , xlValues, xlWhole)
    If Not k Is Nothing Then
        Cells(i, "M").Value = Cells(i, "L").Value - k.Offset(0, 4).Value
    Else
        Cells(i, "M").Value = "Listede Yok"
    End If
Next i
MsgBox "bitti"
End Sub

 

[gicimi]

@Orion1 hocam süpersin teşekkür ederim.

 

[Orion1]

@Orion1 hocam süpersin teşekkür ederim.

Rica ederim.
İyi çalışmalar.

 

[Korhan Ayhan]

Alternatif;

Sub Gun_Farki_Hesapla()
    Application.ScreenUpdating = False
    Son = Cells(Rows.Count, "H").End(3).Row
    Range("M2:M" & Rows.Count).ClearContents
    With Range("M2:M" & Son)
        .Formula = "=IF(COUNTIF(A:A,H2)=0,""Listede Yok"",L2-VLOOKUP(H2,A:E,5,0))"
        .Value = .Value
        .Columns.AutoFit
    End With
    Application.ScreenUpdating = True
End Sub

 

[gicimi]

@Korhan Ayhan Bey alternatif için teşekkür ederim.
"Listede olmayan Malzeme No için ("Listede Yok") yazanları da Sayfa2 ye H -I-J-K-L sütunundaki değerlerini aktarabilir misiniz.

 

[Korhan Ayhan]

Deneyiniz.

Sub Aktar()
    Range("H1:M" & Rows.Count).AutoFilter 6, "Listede Yok"
    Son = Cells(Rows.Count, "H").End(3).Row
    If Son > 1 Then
        Sheets("Sayfa2").Cells.Clear
        Range("H1:L" & Son).Copy Sheets("Sayfa2").Range("A1")
    End If
    ActiveSheet.ShowAllData
End Sub

 

[gicimi]

Korhan Bey Elinize sağlık teşekkür ederim.