Soru Hücre değeri renkli ise farklı işlem konusunda yardım

[com5]

Merhaba bir konuda yardımınızı rica ediyorum.


Hücre değeri yenilenen değer ile renklendirilmiş bir veriyi, makro kullanmadan farklı bir işlem yaptırabilirmiyim. Böyle birşey mümkünmüdür.

Mesela hücre değeri kırmızı ise, çalışma süresini 2 ile çarptırmak istiyorum yada işlem yaptırmamak istiyorum. Yardımcı olabilirmisiniz.

 

[YUSUF44]

Farklı bir çözüm olarak F2 hücresine aşağıdaki formülü yazıp aşağı doğru kopyalayın. Formül, her ismin ilk geçtiği satırda toplam çalışma süresini yazar. Hücre biçimini saat olarak ayarlamayı unutmayın:

=EĞER(EĞERSAY($B$1:B2;B2)=1;ETOPLA($B$2:$B$9;B2;$E$2:$E$9);"")

 

[com5]

Farklı bir çözüm olarak F2 hücresine aşağıdaki formülü yazıp aşağı doğru kopyalayın. Formül, her ismin ilk geçtiği satırda toplam çalışma süresini yazar. Hücre biçimini saat olarak ayarlamayı unutmayın:

=EĞER(EĞERSAY($B$1:B2;B2)=1;ETOPLA($B$2:$B$9;B2;$E$2:$E$9);"")

hocam toplam süresini almayı değilde farklı işlem yaptırmak istiyorum mesela hücre değeri kırmızı ise boş bırak gibi

Örnek
eğer(b2=[kırmızı];"";e2) gibi

 

[YUSUF44]

Renge göre formül yok bildiğim kadarıyla. Kullanıcı tanımlı formüller yapılabilir ama galiba o da size uymaz çünkü sizin verilerinizde renkler koşullu biçimlendirme ile elde ediliyor. Eğer birden fazla olan veriler boş kalsın diyorsanız aşağıdaki formülü deneyin:

=EĞER(EĞERSAY($B$1:$B$9;B2)>1;"";E2)

 

[com5]

hocam, geç dönüş yaptığım için özür diliyorum.

hocam , günde 300 kişinin puantajını tutuyorum ve işverenim benden ceza sistemi yapmamı istedi. fakat şöyle bir sorun yaşadım.




Sorun şu : bir personel farklı sutunlarda farklı görevlere yazıldığında Q satırında bulunan formül fazladan hesaplıyor.
Normalde tek satıra yazınca formül sağlıklı çalışıyor.

Örnek olarak : Kadir kök personel 08:30-20:00 arası çalışmış, fakat bu personel 08:30-17:00 bir işte 17:00-20:00 arası bir işte çalıştığını belirtince ceza formülü (Q) sutunudaki formül fazladan ceza yazıyor. Bunu nasıl çözebilirim. Bunun bir çözümü varmıdır.

Ceza formülü (Q) satırı

=EĞER(EBOŞSA(J2);"";(EĞER(VE(L2>=AYARLAR!$AB$2;L2<=AYARLAR!$AC$2);AYARLAR!$AD$2)+EĞER(VE(M2>=AYARLAR!$AB$3;M2<=AYARLAR!$AC$3);AYARLAR!$AD$3)+EĞER(VE(M2>=AYARLAR!$AB$4;M2<=AYARLAR!$AC$4);AYARLAR!$AD$4)))

 

[YUSUF44]

Öncelikle toplam Çalışma süresini bulmak için O2'deki formülü aşağıdakiyle değiştirip aşağı doğru kopyalayın, böylece kişinin ilk geçtiği satırda toplam çalışma süresi görünecektir:

=EĞER(ÇOKEĞERSAY($A$1:A2;A2;$G$1:G2;G2)=1;ÇOKETOPLA($N$2:$N$10;$G$2:$G$10;G2;$A$2:$A$10;A2);"")

Sonraki ve asıl istediğiniz durum için ise daha fazla açıklamaya ihtiyaç var. Q, R ve S sütunlarındaki formüllerin mantığı nedir, nasıl bir yoldan gidip nasıl bir sonuca ulaşmak istiyorsunuz? Bunu bizim anlayabileceğimiz şekilde açıklarsanız iyi olur.

 

[com5]

bu formül "O" Sutununda mevcut ( siz başka forum başlığında yardım etmiştiniz)

Cezadaki amaç

CEZALAR 1. KURAL 2. KURAL CEZA AÇIKLAMA
1.CEZA 08:21 08:45 00:30 SABAH 08:20 - 08:45 ARASI GİRENLERDEN 30 DAKİKA KESİNTİ
2.CEZA 16:50 17:07 01:00 AKŞAM 16:50 - 17:07 ARASI ÇIKANLARDAN 1 SAAT KESİNTİ
3.CEZA 19:50 19:59 00:30 AKŞAM 19:50 - 19:59 ARASI ÇIKANLARDAN 30 DAKİKA KESİNTİ


sabah 08:21 ile 08:45 arası girenlerden toplam çalışma süresinden 30 dakika kesilmesini istiyorlar.
tek satırda olan bir kişide sorun yok formül çalışıyor fakat bir (G) sutunu personel aynı tarihte başka işlerde çalıştıysa formül çalışmıyor.

   
    

 

[YUSUF44]

Çözemedim maalesef.

 

[com5]

Çözemedim maalesef.

değerli zamanınızı ayırıp en azından ilgilenmeniz bile benim için çok önemliydi. Çok teşekkür ederim.
değerli vaktinizi aldım. kusura bakmayın.

 

[YUSUF44]

Q2'de aşağıdaki formülü dener misiniz?

=EĞER(EBOŞSA(J2);"";(EĞER(VE(ÇOKEĞERSAY($G$1:G2;G2;$A$1:A2;A2)=1;L2>=AYARLAR!$AB$2;L2<=AYARLAR!$AC$2);AYARLAR!$AD$2)+EĞER(ÇOKEĞERSAY(G3:$G$11;G2;A3:$A$11;A2)=0;EĞER(VE(M2>=AYARLAR!$AB$3;M2<=AYARLAR!$AC$3);AYARLAR!$AD$3)+EĞER(VE(M2>=AYARLAR!$AB$4;M2<=AYARLAR!$AC$4);AYARLAR!$AD$4);0)))

 

[com5]

Q2'de aşağıdaki formülü dener misiniz?

=EĞER(EBOŞSA(J2);"";(EĞER(VE(ÇOKEĞERSAY($G$1:G2;G2;$A$1:A2;A2)=1;L2>=AYARLAR!$AB$2;L2<=AYARLAR!$AC$2);AYARLAR!$AD$2)+EĞER(ÇOKEĞERSAY(G3:$G$11;G2;A3:$A$11;A2)=0;EĞER(VE(M2>=AYARLAR!$AB$3;M2<=AYARLAR!$AC$3);AYARLAR!$AD$3)+EĞER(VE(M2>=AYARLAR!$AB$4;M2<=AYARLAR!$AC$4);AYARLAR!$AD$4);0)))

hocam çok teşekkür ederim. işe yaradı. elinize sağlık. beni büyük bir dertten kurtardınız. size borcumu nasıl ödeyebilirim. ?

 

[YUSUF44]

Eyvallah, borç yok, dua edin yeter.

 

[com5]

Eyvallah, borç yok, dua edin yeter.

Gerçekten çok teşekkür ederim, dualarım sizinle...