Hücre içindeki son boşluktan sonrasını silmek

[pedasabyem]

Merhaba,

Hücre içlerinde cümleler var.
Hücredeki en son boşluk neredeyse, o boşluktan itibaren sağında ne varsa silmek mümkün müdür.

Örnek:
Hücre içi:"Excel kullanmaya yeni başladıysanız sorularınızı buraya gönderebilirsiniz."

ise

Sonuç:"Excel kullanmaya yeni başladıysanız sorularınızı buraya"

Saygılar


Not:
Bazı sayfalarınıda örnekleri inceledim ama uygulayamadım. Mesala aşağıdaki formüller benim sorunuma uygun mudur bilmiyorum ama denedim olmadı:
=SOLDAN(A2;MBUL(" ";A2;1)-1)
=SAĞDAN(A2;UZUNLUK(A2)-MBUL(" ";A2;MBUL(" ";A2;1)+1))

 

[Erdem Akdemir]

A1 hücresinde olduğunu varsayarsak,

Dizi formülüdür, CTRL+SHIFT+ENTER ile kapatmayı unutmayın.

=SOLDAN(A1;MAK(EĞER(PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1)=" ";SATIR(DOLAYLI("1:"&UZUNLUK(A1)))))-1)

 

[pedasabyem]

Elinize bilginize sağlık, almak istediğim sonuç tam olarak buydu. Çok teşekkür ederim üstad.

 

[hamitcan]

Kelimeler arasında tek boşluk olduğunu varsayarak bir formül yazdım belki işinize yarar. Belki çift boşluk yerine farklı bir karakter ile formül daha işlevsel hale getirilebilir.

=PARÇAAL(A1;1;MBUL("  ";YERİNEKOY(A1;" ";"  ";UZUNLUK(A1)-UZUNLUK(YERİNEKOY(A1;" ";""))))-1)

 

[GTMAN]

A1 hücresinde olduğunu varsayarsak,

Dizi formülüdür, CTRL+SHIFT+ENTER ile kapatmayı unutmayın.

=SOLDAN(A1;MAK(EĞER(PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1)=" ";SATIR(DOLAYLI("1:"&UZUNLUK(A1)))))-1)

Erdem bey, bu örnekteki cümlenin en sonundaki boşluktan sonraki kelimeyi almak istiyorum nasıl yapabilirim

teşekkür ederim

 

[Haluk]

=YERİNEKOY(SAĞDAN(A1;UZUNLUK(A1)-BUL("@";YERİNEKOY(A1;" ";"@";UZUNLUK(A1)-UZUNLUK(YERİNEKOY(A1;" ";"")));1));" ";"")

.

 

[Erdem Akdemir]

Erdem bey, bu örnekteki cümlenin en sonundaki boşluktan sonraki kelimeyi almak istiyorum nasıl yapabilirim

teşekkür ederim

=KIRP(SAĞDAN(YERİNEKOY(KIRP(A1);" ";YİNELE(" ";99));99))

 

[GTMAN]

=KIRP(SAĞDAN(YERİNEKOY(KIRP(A1);" ";YİNELE(" ";99));99))

Erdem bey, çok teşekkür ederim

 

[muratgunay48]

A1 hücresinde olduğunu varsayarsak,

Dizi formülüdür, CTRL+SHIFT+ENTER ile kapatmayı unutmayın.

=SOLDAN(A1;MAK(EĞER(PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1)=" ";SATIR(DOLAYLI("1:"&UZUNLUK(A1)))))-1)

Hocam emeğinize sağlık. Yalnız solda tek karakter olunca neden olmadı. Nerede hata yapıyorum acaba? Teşekkür ederim.

 

[Korhan Ayhan]

Erdem bey önerisinde SOLDAN fonksiyonunu kullanmış. Siz ise SAĞDAN fonksiyonunu kullanmışsınız. Sorun bu olabilir mi?

 

[muratgunay48]

Erdem bey önerisinde SOLDAN fonksiyonunu kullanmış. Siz ise SAĞDAN fonksiyonunu kullanmışsınız. Sorun bu olabilir mi?

Hocam, ben o şeklide düşünmemiştim. Yürüttüğüm mantık, ilk boşluk ya da son boşluk şeklindeydi. İlk satırdaki örnekte ilk boşluktan öncesini silmek şeklinde söyleyemez miyiz? 2. Satırda da aynı prensiple çalışması gerekmez mi? Anlamak için soruyorum hocam.
Teşekkür ederim.

 

[Korhan Ayhan]

Formüller ne yapmak istediğinize göre değişir.

Siz tam olarak ne yapmak istiyorsunuz?

 

[muratgunay48]

Formüller ne yapmak istediğinize göre değişir.

Siz tam olarak ne yapmak istiyorsunuz?

Hocam, sayı ya da harf olsa da tek karakter olsa da ilk boşluktan öncesini silmek. Yani buradaki örnekte sadece 1 rakamını silmesi.
Teşekkür ederim hocam.
Ayrıca öğrenmek için soruyorum hocam. 4-5-6 karakterli olunca siliyor ama tek karakter olunca bozuyor, neden acaba?

 

[Korhan Ayhan]

Bunu deneyebilirsiniz.

=PARÇAAL(A1;BUL(" ";A1)+1;UZUNLUK(A1)-BUL(" ";A1))

 

[muratgunay48]

Bunu deneyebilirsiniz.

=PARÇAAL(A1;BUL(" ";A1)+1;UZUNLUK(A1)-BUL(" ";A1))

Hocam çok teşekkür ederim. Emeğinize sağlık.

 

[Korhan Ayhan]

Çözüme ulaştık..

Yürüttüğüm mantık, ilk boşluk ya da son boşluk şeklindeydi.

Ama siz kendi kullanımınızdaki sorunu sormuştunuz..

Burada önemli olan kurulan fonksiyonu okuyabilmektir. Yanlış okuyunca istenmeyen sonuçlar ortaya çıkacaktır.

=SAĞDAN(A1;MAK(EĞER(PARÇAAL(A1;SATIR(DOLAYLI("1:"&UZUNLUK(A1)));1)=" ";SATIR(DOLAYLI("1:"&UZUNLUK(A1)))))-1)

Bu formülde kalın fontlu bölüm metindeki boşluk karakterlerini arar ve en büyük indexi size verir. Yani kısaca en sondaki boşluk karakterinin konumunu size verir.

Mesela kalın fontlu bölüm sonuç olarak 15 değerini verdiyse siz formülde A1 hücresindeki metinin SAĞDAN 15 karakterini al demiş oluyorsunuz. Bu da bazı metinlerde doğru sonuç verirken bazı metinlerde hatalı sonuç çıkmasına sebep olmaktadır. Çünkü doğru bir kullanım değildir.

Kısaca her formül istenen çözüme göre tasarlanmaktadır. Her formülü her yerde kullanamayız...