İki tarih arasını kontrol edip sıra no vermek

[cemshan]

Örneğin aşağıdaki gibi bir tablomuz var . Yapılmak istenen önce teslim tarihi en eski den yeni göre kontrol etsin , sonra bu sırası kendi içinde oluşturma tarihine göre tekrar kontrol etsin ve öncelik sırası versin . Olmasını istediğim değerler manuel olarak Öncelik sırası bölümüne yazılmıştır

Sipariş No	Teslim Tarihi	Oluşturma Tarihi	Öncelik Sırası	Formül
1​	1.02.2024	10.01.2024	1
2​	2.02.2024	14.01.2024	4
3​	1.02.2024	15.01.2024	2
4​	1.02.2024	16.01.2024	3

 

[Korhan Ayhan]

Deneyiniz.

Eğer Türkçe sürüm kullanıyorsanız formülü çevirmeniz gerekir. Ayrıca linki inceleyerek profilinizi güncellemenizi rica ederim.

Bilgi - Profillerde yazan "Ofis Sürümü ve Dili" bilgisi hakkında

Merhaba Değerli Forum Üyeleri, Belki dikkatinizi çekmiştir. Son zamanlarda birçok üyemize açtıkları başlıklarda cevap vermeden önce "Kullandığınız ofis sürümü ve dili nedir?" şeklinde mesaj yazıyorum. Bu alanın kullanım amacı sizlere verilecek cevaplar için önem arz etmektedir. Bu sebeple bu...

www.excel.web.tr

=RANK(B2;$B$2:$B$5;1)+SUMPRODUCT(--($B$2:$B$5=B2);--(C2>$C$2:$C$5))

 

[cemshan]

Deneyiniz.

Eğer Türkçe sürüm kullanıyorsanız formülü çevirmeniz gerekir. Ayrıca linki inceleyerek profilinizi güncellemenizi rica ederim.

Bilgi - Profillerde yazan "Ofis Sürümü ve Dili" bilgisi hakkında

Merhaba Değerli Forum Üyeleri, Belki dikkatinizi çekmiştir. Son zamanlarda birçok üyemize açtıkları başlıklarda cevap vermeden önce "Kullandığınız ofis sürümü ve dili nedir?" şeklinde mesaj yazıyorum. Bu alanın kullanım amacı sizlere verilecek cevaplar için önem arz etmektedir. Bu sebeple bu...

www.excel.web.tr

=RANK(B2;$B$2:$B$5;1)+SUMPRODUCT(--($B$2:$B$5=B2);--(C2>$C$2:$C$5))

Teşekkür ederim

 

[52779]

Alternatif olsun

	A​	B​	C​	D​	E​	F​
1​	SN​	Teslim Tarihi​	Kayıt Tarihi​	Öncelik No​	Öncelik No​	​
2​	1​	01.02.2024​	10.01.2024​	1​	1​	​
3​	2​	02.02.2024​	14.01.2024​	7​	7​	​
4​	3​	01.02.2024​	15.01.2024​	3​	3​	​
5​	4​	01.02.2024​	16.01.2024​	4​	4​	​
6​	5​	02.02.2024​	13.01.2024​	5​	5​	​
7​	6​	03.02.2024​	13.01.2024​	8​	8​	​
8​	7​	01.02.2024​	11.01.2024​	2​	2​	​
9​	8​	02.02.2024​	13.01.2024​	5​	6​	​

Tablonuzdaki Tarihler B2 : B9 ve C2 : C9 hücrelerinde olsun.

Dikkat edilirse 6.ncı ve 9. satırlardaki tarihler AYNI.
Öncelik No sıralaması için,
AYNI değerlere AYNI Sıra No verilecekse sıralama D kolonundaki gibi,
AYNI değerlere FARKLI Sıra No verilecekse de sıralama E kolonundaki gibi olacaktır.

AYNI değerlere AYNI Sıra No verilecekse
Excel2010 ve üzeri versiyonlarda D2 hücresine yazılır aşağıya doğru kopyalanır

=EĞERSAY($B$2:$B$9;"<"&B2)+ÇOKEĞERSAY($B$2:$B$9;B2;$C$2:$C$9;"<"&C2)+1

Excel 2003 ve üzeri versiyonlarda D2 hücresine yazılır aşağıya doğru kopyalanır

=TOPLA.ÇARPIM(--(B2&"|"&C2>$B$2:$B$9&"|"&$C$2:$C$9))+1

ya da tarihlerin SAYI (ya da Sayı görünümlü Metin) olmasından dolayı

=TOPLA.ÇARPIM(--(B2+C2/10^6>$B$2:$B$9+$C$2:$C$9/10^6))+1

Excel 2021 ve üzeri versiyonlarda, önce D2 den itibaren D kolonunu silin ve D2 hücresine yazın, sonuçlar dökülecektir.

=LET(a;SIRALA(B2:C9;{1;2});KAÇINCI(B2:B9&"|"&C2:C9;İNDİS(a;;1)&"|"&İNDİS(a;;2);0))

ya da

KAÇINCI(B2:B9+C2:C9/10^6;SIRALA(B2:B9+C2:C9/10^6);0)

AYNI değerlere FARKLI Sıra No verilecekse
Excel2010 ve üzeri versiyonlarda D2 hücresine yazılır aşağıya doğru kopyalanır

=EĞERSAY($B$2:$B$9;"<"&B2)+ÇOKEĞERSAY($B$2:$B$9;B2;$C$2:$C$9;"<"&C2)+ÇOKEĞERSAY($B$2:$B2;B2;$C$2:$C2;C2)

Excel 2003 ve üzeri versiyonlarda D2 hücresine yazılır aşağıya doğru kopyalanır

=TOPLA.ÇARPIM(--(B2&"|"&C2>$B$2:$B$9&"|"&$C$2:$C$9))+TOPLA.ÇARPIM(--(B2&"|"&C2=$B$2:$B2&"|"&$C$2:$C2))

ya da tarihlerin SAYI (ya da Sayı görünümlü Metin) olmasından dolayı

=TOPLA.ÇARPIM(--(B2+C2/10^6>$B$2:$B$9+$C$2:$C$9/10^6))+TOPLA.ÇARPIM(--(B2+C2/10^6=$B$2:$B2+$C$2:$C2/10^6))

Excel 2021 ve üzeri versiyonlarda, önce D2 den itibaren D kolonunu silin ve D2 hücresine yazın, sonuçlar dökülecektir.

=LET(a;B2:B9+C2:C9/10^6+SIRALI(SATIRSAY(B2:B9))/10^9;KAÇINCI(a;SIRALA(a);0))

Excel 2024 / Excel365 versiyonlarda, önce D2 den itibaren D kolonunu silin ve D2 hücresine yazın, sonuçlar dökülecektir.

=AL(SIRALA(YATAYYIĞ(SIRALI(SATIRSAY(B2:B9));B2:C9);{2;3});;1)

 

[cemshan]

Alternatif olsun

	A​	B​	C​	D​	E​	F​
1​	SN​	Teslim Tarihi​	Kayıt Tarihi​	Öncelik No​	Öncelik No​	​
2​	1​	01.02.2024​	10.01.2024​	1​	1​	​
3​	2​	02.02.2024​	14.01.2024​	7​	7​	​
4​	3​	01.02.2024​	15.01.2024​	3​	3​	​
5​	4​	01.02.2024​	16.01.2024​	4​	4​	​
6​	5​	02.02.2024​	13.01.2024​	5​	5​	​
7​	6​	03.02.2024​	13.01.2024​	8​	8​	​
8​	7​	01.02.2024​	11.01.2024​	2​	2​	​
9​	8​	02.02.2024​	13.01.2024​	5​	6​	​

Tablonuzdaki Tarihler B2 : B9 ve C2 : C9 hücrelerinde olsun.


Dikkat edilirse 6.ncı ve 9. satırlardaki tarihler AYNI.
Öncelik No sıralaması için,
AYNI değerlere AYNI Sıra No verilecekse sıralama D kolonundaki gibi,
AYNI değerlere FARKLI Sıra No verilecekse de sıralama E kolonundaki gibi olacaktır.

AYNI değerlere AYNI Sıra No verilecekse
Excel2010 ve üzeri versiyonlarda D2 hücresine yazılır aşağıya doğru kopyalanır

=EĞERSAY($B$2:$B$9;"<"&B2)+ÇOKEĞERSAY($B$2:$B$9;B2;$C$2:$C$9;"<"&C2)+1

Excel 2003 ve üzeri versiyonlarda D2 hücresine yazılır aşağıya doğru kopyalanır

=TOPLA.ÇARPIM(--(B2&"|"&C2>$B$2:$B$9&"|"&$C$2:$C$9))+1

ya da tarihlerin SAYI (ya da Sayı görünümlü Metin) olmasından dolayı

=TOPLA.ÇARPIM(--(B2+C2/10^6>$B$2:$B$9+$C$2:$C$9/10^6))+1

Excel 2021 ve üzeri versiyonlarda, önce D2 den itibaren D kolonunu silin ve D2 hücresine yazın, sonuçlar dökülecektir.

=LET(a;SIRALA(B2:C9;{1;2});KAÇINCI(B2:B9&"|"&C2:C9;İNDİS(a;;1)&"|"&İNDİS(a;;2);0))

ya da

KAÇINCI(B2:B9+C2:C9/10^6;SIRALA(B2:B9+C2:C9/10^6);0)

AYNI değerlere FARKLI Sıra No verilecekse
Excel2010 ve üzeri versiyonlarda D2 hücresine yazılır aşağıya doğru kopyalanır

=EĞERSAY($B$2:$B$9;"<"&B2)+ÇOKEĞERSAY($B$2:$B$9;B2;$C$2:$C$9;"<"&C2)+ÇOKEĞERSAY($B$2:$B2;B2;$C$2:$C2;C2)

Excel 2003 ve üzeri versiyonlarda D2 hücresine yazılır aşağıya doğru kopyalanır

=TOPLA.ÇARPIM(--(B2&"|"&C2>$B$2:$B$9&"|"&$C$2:$C$9))+TOPLA.ÇARPIM(--(B2&"|"&C2=$B$2:$B2&"|"&$C$2:$C2))

ya da tarihlerin SAYI (ya da Sayı görünümlü Metin) olmasından dolayı

=TOPLA.ÇARPIM(--(B2+C2/10^6>$B$2:$B$9+$C$2:$C$9/10^6))+TOPLA.ÇARPIM(--(B2+C2/10^6=$B$2:$B2+$C$2:$C2/10^6))

Excel 2021 ve üzeri versiyonlarda, önce D2 den itibaren D kolonunu silin ve D2 hücresine yazın, sonuçlar dökülecektir.

=LET(a;B2:B9+C2:C9/10^6+SIRALI(SATIRSAY(B2:B9))/10^9;KAÇINCI(a;SIRALA(a);0))

Excel 2024 / Excel365 versiyonlarda, önce D2 den itibaren D kolonunu silin ve D2 hücresine yazın, sonuçlar dökülecektir.

=AL(SIRALA(YATAYYIĞ(SIRALI(SATIRSAY(B2:B9));B2:C9);{2;3});;1)

ilginiz ve mesajlarınız için teşekkür ederim