inputbox-şifreli karekter

[ownn]

selam;
öncelikle arama yaptığımı içinde lik verilen bir mesaj bulduğumu ve linkteki adresin içinden gerekli dosyayı indiremediğimi söyleyerek başlamak istiyorum söze.

inputbox da girdiğim değerler password karekter olarak gözüksin istiyorum... mümkünse add-in tarzı eklentiler yapmadan..
çok mu şey istiyorum..

ilgi ve alakanız için şimdiden teşekürler..

 

[Levent Menteşoğlu]

Aşağıdaki linki inceleyin.

http://www.xcelfiles.com/API_09.html

 

[ozdi]

link için saul :icelim:

 

[Ongun]

Sayın Leventm, linki inceledim ama çözemedim. aşağıdaki kodların neresine kod yazarsak password karekter olarak görünmesini sağlayabilirmiyiz. Saygılarımla,
*********
Private Sub UserForm_Activate()
Sheets("sayfa1").Select
UserForm1.TextBox40.Value = Cells(1, 4)
Dim Þifre As String
Dim Tekrar As Integer
Tekrar = 0
Þifre = InputBox("LÜTFEN ÞİFRENİZİ GİRİNİZ!", " KULLANICI ÞİFRESİ GİRİÞ EKRANI ")
Do Until Þifre = UserForm1.TextBox40.Value
Tekrar = Tekrar + 1
If Tekrar = 3 Then
MsgBox "ÜZGÜNÜM.DENEME HAKKINIZ DOLMUÞTUR.", 16, "UYARI"
ActiveWorkbook.Save
Excel.Application.Quit
End
End If
MsgBox "HATALI ÞİFRE GİRDİNİZ."
Þifre = InputBox("LÜTFEN ÞİFRENİZİ GİRİNİZ!", " KULLANICI ÞİFRESİ GİRİÞ EKRANI ")
Loop
End Sub

 

[Haluk]

Bence, aşağıdaki linke mutlaka göz atın...

http://www.excel.web.tr/viewtopic.php?p=1898#1898

Not: Eğer OfficeXP kullanıyorsanız, güvenlik ayarlarından "VBA projelerine erişimine izin ver..." seçeneğini onaylamanız gerekir.

 

[Levent Menteşoğlu]

Ã?ncelikle aşağıdaki kodları boş bir module sayfasına kopyalayın.

[vb:1:7843056451]Option Explicit
''/////////////////////////////////////////////////////////////////
''// 25 May 2003 //
''// Amended Ivan F Moala
''/////////////////////////////////////////////////////////////////
Public Declare Function GetActiveWindow _
Lib "user32" () _
As Long
Public Declare Function FindWindowEx _
Lib "user32" _
Alias "FindWindowExA" ( _
ByVal hWnd1 As Long, _
ByVal hWnd2 As Long, _
ByVal lpsz1 As String, _
ByVal lpsz2 As String) _
As Long
Public Declare Function SendMessage _
Lib "user32" _
Alias "SendMessageA" ( _
ByVal hwnd As Long, _
ByVal wMsg As Long, _
ByVal wParam As Long, _
lParam As Any) _
As Long
Public Declare Function SetTimer _
Lib "user32" ( _
ByVal hwnd As Long, _
ByVal nIDEvent As Long, _
ByVal uElapse As Long, _
ByVal lpTimerFunc As Long) _
As Long
Public Declare Function KillTimer _
Lib "user32" ( _
ByVal hwnd As Long, _
ByVal nIDEvent As Long) _
As Long
Public Declare Function GetForegroundWindow _
Lib "user32" () _
As Long
Private Const nIDE As Long = &H100
Private Const EM_SETPASSWORDCHAR = &HCC
Private hdlEditBox As Long
Private Fgrndhdl As Long
Public Function TimerFunc( _
ByVal hwnd As Long, _
ByVal wMsg As Long, _
ByVal nEvent As Long, _
ByVal nSecs As Long) As Long

Dim hdlwndAct As Long

'// Do we have a handle to the EditBox
If hdlEditBox > 0 Then Exit Function

'// Get the handle to the ActiveWindow
hdlwndAct = GetActiveWindow()

'// Get the Editbox handle
hdlEditBox = FindWindowEx(hdlwndAct, 0, "Edit", "")

'// Set the password character for the InputBox
SendMessage hdlEditBox, EM_SETPASSWORDCHAR, Asc("*"), ByVal 0

End Function

Public Function InPutBoxPwd(fPrompt As String, _
Optional fTitle As String, _
Optional fDefault As String, _
Optional fXpos As Long, _
Optional fYpos As Long, _
Optional fHelpfile As String, _
Optional fContext As Long) As String

Dim sInput As String

'// Initialize
hdlEditBox = 0
Fgrndhdl = GetForegroundWindow
'// Windows-Timer
SetTimer Fgrndhdl, nIDE, 100, AddressOf TimerFunc

'// Main InputBox
If fXpos Then
sInput = InputBox(fPrompt, fTitle, fDefault, fXpos, fYpos, fHelpfile, fContext)
Else
sInput = InputBox(fPrompt, fTitle, fDefault, , , fHelpfile, fContext)
End If

'// Kill the correct Timer
KillTimer Fgrndhdl, nIDE
'// Pass result
InPutBoxPwd = sInput
End Function[/vb:1:7843056451]

[vb:1:7843056451] Þifre = InputBox("LÜTFEN ÞİFRENİZİ GİRİNİZ!", " KULLANICI ÞİFRESİ GİRİÞ EKRANI ")
[/vb:1:7843056451]

daha sonrada userformunuzda yazılı yukarıdaki satırı aşağğıdaki gibi değiştirin.

[vb:1:7843056451]şifre = InPutBoxPwd("LÜTFEN ÞİFRENİZİ GİRİNİZ!", " KULLANICI ÞİFRESİ GİRİÞ EKRANI ")
[/vb:1:7843056451]

Not: Bu işi bence bir textboxla yapmak çok daha kolay.

 

[Ongun]

Sayın Raider, yukarıdaki kodlara ilave edeceğim kodları vermeniz mümkün mü şifre girişinin "********" görünmesini bu şekilde sağlayabilirmiyim. Yoksa hangi yöntemi izlemem lazım. İlginize teşekkür ederim.saygılarımla.,

 

[Exelans]

Properties kısmından Pasword Character olarak * derseniz olacaktır

 

[Ongun]

Sayın Leventm, verdiginiz kodlar işe yaradı sorunumu çözdüm. Size ve ilgilenen diğer adkadaşlara teşekkürlerimi sunarım. Her şey gönlünüzce olsun.
Selamlar :hey: