Soru Kodda Ufak Düzeltme Yardım

[MaliMuavin]

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

Dim syf As String

On Error GoTo Son

If Intersect(Target, Range("F5:F" & Rows.Count)) Is Nothing Then Exit Sub

syf = Target.Value
If syf <> "" Then Sheets(syf).Select
Exit Sub

Son:

MsgBox "Sayfayı Bulamadım", , "excel.web.tr"
Target.Offset(1, 0).Select

End Sub

merhaba bu kod hücreye sayfa ismini yazıyorsun ve o sayfaya gidiyor
sayfa gizli olunca kod sayfayı bulamıyor
sizden ricam bu koda eğer sayfa gizliyse sayfayı açmasını ve kodların çalışmasını sağlıycak bir komut eklemeniz

 

[AdemCan]

Merhaba

If syf <> "" Then Sheets(syf).Select satırını aşağıdaki şekilde değiştiriniz.

If syf <> "" Then
    Sheets(syf).Visible = True
    Sheets(syf).Select
End If

 

[Korhan Ayhan]

Alternatif;

Option Explicit

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Dim S1 As Worksheet
    
    If Intersect(Target, Range("F5:F" & Rows.Count)) Is Nothing Then Exit Sub
    Cancel = True
    
    On Error Resume Next
    Set S1 = Nothing
    Set S1 = Sheets(Target.Text)
    On Error GoTo 0
    
    If Not S1 Is Nothing Then
        If S1.Visible = xlSheetHidden Then
            S1.Visible = xlSheetVisible
            S1.Select
        Else
            S1.Select
        End If
    Else
        MsgBox "Sayfa bulunamadı!", vbCritical
    End If

    Set S1 = Nothing
End Sub