Köprü Formülü Oluşturma

[gnroses]

Merhabalar,
Şöyle bir sorum olacak. Yapmak istediğim şey ilk sayfadaki D1 satırından ikinci sayfadaki B11 satırına köprü atmak. Daha sonra D2'den B22'ye sonra D3'ten B33'e şeklinde gideceğim. Ancak her hücre için sonra da her ay için tek tek uğraşmak çok vaktimi alacak.
Acaba D1 hücresindeki formülü bozmadan, o formülün içine ya da yanına köprü formülü girilebiliyormu ve aşağıya doğru çektiğimde istediğim köprülerin oluşması sağlanabilir mi?
Teşekkür ederim.

Saygılarımla.

 

[Ömer]

Merhaba,

D3 hücresindeki formülü aşağıdaki gibi değiştirerek alt hücrelere kopyalayınız..

=KÖPRÜ("["&YERİNEKOY(YERİNEKOY(HÜCRE("dosyaadı";A1);"[";"");"9";"U9!B")&EĞER(A4="";ARA(2;1/(AĞU9!$B$1:$B$65003<>"");SATIR(AĞU9!$B$1:$B$65003));KAÇINCI(TARİH(YIL($A$1);AY($A$1);A3+1);AĞU9!A:A;0)-1);DOLAYLI("AĞU9!B"&EĞER(A4="";ARA(2;1/(AĞU9!$B$1:$B$65003<>"");SATIR(AĞU9!$B$1:$B$65003));KAÇINCI(TARİH(YIL($A$1);AY($A$1);A3+1);AĞU9!A:A;0)-1)))

.

 

[gnroses]

Ömer Bey, Allah razı olsun sizden. Ellerinize sağlık öle büyük kolaylık olduki bana. Tekrar tekrar teşekkür ederim.
Bir de bir şeyi hiç anlamadım Ömer Bey formüldeki kırmızı işaretlediğim U9! neyi ifade ediyor acaba. Çünkü başka aylara uyarlama yaparken bi kaçında sıkıntı yaşadım tam anlayamadığım için.

KÖPRÜ("["&YERİNEKOY(YERİNEKOY(HÜCRE("dosyaadı";A1);"[";"");"9";"U9!B")

Saygılarımla.

 

[Ömer]

=HÜCRE("dosyaadı";A1)

formülü yazdığınız dosya adının tamamını verir buda;

C:\Documents and Settings\user\Desktop\[günlük hareketler.xls]AĞ9

kırmızı ile işaretli bölüm benim bilgisayarımdaki dosya yoludur bu değişken olduğu için formülü bu şekilde yazdım. Köprü formülünde kullanmak için burdan elde etmemiz gereken metin,

[C:\Documents and Settings\user\Desktop\günlük hareketler.xls]AĞU9 olmadı idi..

birince yerinekoy formülü ile sayfa adı başındaki [ kaldırılır ve formülün başına "["& ile eklenmiştir.sondaki sayfa adıda formülü yazdığımız sayfa adı değil veriyi cektiğimiz sayfa adı olması gerektiği için ikinci yerinekoy formülü ile sayfa adını AĞU9 olarak değiştirtik.

AĞ9 buradaki 9 yerine U9 koyduğumuz için U9!B yazılmıştır. !B bunu ilave etmemizin nedeki diğer sayfanın B sütununu kullanmamız gerektiği içindir.

Anlamadığınız yer olursa daha fazla açabilirim..

.

 

[gnroses]

Önce anladım sandım ama beceremedim açıkçası Ömer Bey.

Tıkandığım yer OC1 ve OCA1 arasında oldu. Değişikliği aşağıdaki gibi yaptım.

=KÖPRÜ("["&YERİNEKOY(YERİNEKOY(HÜCRE("dosyaadı";A1);"[";"");"1";"A1!B")

Ama olmadı. Hatam nedir acaba?

Saygılarımla

 

[Ömer]

Başvuru yapmak istediğiniz sayfa ismi başında yada sonunda boşluk olabilir kontrol ediniz.

KÖPRÜ("["&YERİNEKOY(YERİNEKOY(HÜCRE("dosyaadı";A1);"[";"");"OC1";"'OCA1'!B"))

Bu şekilde denemeniz daha mantıklı olacaktır.. ' eklediğim için küçük bir değişiklik yaptım..

formülün yazıldığı sayfa adı : OC1

başvuru yapılacak sayfa adı : OCA1

Bunlara rağmen düzelmesse hatalı dosyanızı eklerseniz kontrol edebilirim..

.

 

[gnroses]

Tamam oldu Ömer Bey. Değerli yardımlarınız için tekrar çok teşekkür eder iyi günler dilerim.

Saygılarımla.