Koşullu Satır Ekleme (Her 1000.Satırda)

[Baturfurkan]

İyi Akşamlar herkese,
20.000 kişilik isim listem var. Her bin (1.000) kişide bir boş hücre veya satır eklemesini istiyorum. (İlk Satırda başlıklar var. B2 hücresinden aşağıya doğru uzanıyor isimler). Bunun için bir formül var mıdır acaba? Ayrıca bu formülü değişken yapabilir miyiz? Mesela ben açılan bir msgboxa yada H1 hücresine 1.000 yazdığımda 1.000 hücrede bir boşluk bıraksa, 500 yazdığımda 500 hücrede bir bıraksa? Tabiki sadece ilk işlevi yapması da yeterli olur değişken atanamaz ise de vba içine girip değiştirebilirim.
Ayrıca 1.000 kişide bir boş satır ekledikten sonra her ismin yanına virgül (",") eklemem lazım. (Örn: B4 hücresinde "Furkan BATUR" yazıyorsa kod virgül ekleyecek ve b4 hücresinde "Furkan BATUR," yazacak). Bunun için bir kodlanabilir mi? Ben Makro kaydetme ile hücre birleştirme formülünü kaydettim ama pek başarılı olamadım.

Bilgisizliğimi ve yaptıysam anlatım bozukluğunu mazur görün lütfen. Şimdiden yardımlarınız için teşekkür ederim.

 

[ÖmerBey]

Merhaba,
Aşağıdaki kodları deneyiniz...

Sub bosluk_birak()
Dim bosluk As Integer
Dim a As Long, s As Long, son As Long
bosluk = Application.InputBox("Kaç satırda boşluk yapılsın", Type:=1)
If bosluk = False Then Exit Sub
son = Cells(Rows.Count, "B").End(3).Row
s = son - son Mod bosluk + 2 'verilerin başladığı satır

For a = s To bosluk Step -1 * bosluk
    Rows(a).Insert Shift:=xlDown
Next
End Sub

Sub virgul_ekle()
Dim son As Long, a As Long
Dim alan As Range
Dim dz As Variant
Dim ek As String
ek = ","
son = Cells(Rows.Count, "B").End(3).Row
Set alan = Range("B2:B" & son)
dz = alan.Value
For a = LBound(dz) To UBound(dz)
    If dz(a, 1) <> "" Then dz(a, 1) = dz(a, 1) & ek
Next
alan.Value = dz
End Sub

 

[Baturfurkan]

Çok teşekkür ederim. Kod sorunsuz çalışıyor, çok yardımcı oldunuz sağolun

 

[ÖmerBey]

Siz de sağ olun,
İyi çalışmalar...