Çözüldü Kritere Bağlı Olarak Kayıt Silme

[Tasarım]

Herkese merhaba, arkadaşlar bir izin takip programı üzerinde çalışma yapıyorum fakat bir konuda takıldım. Bu yüzden bilen ve yardımcı olabilecek arkadaşlara sormak istedim.
Sorunum şu: Bir personel ayrıldığı zaman Izin_Takip sayfasından o kişinin tc kimlik numarasına ait ne kadar kayıt varsa silmesini istiyorum. Bu konuda yardım edebilecek arkadaşlara şimdiden teşekkür ederim.

Örnek dosyayı ekledim.

 

[Tasarım]

@Korhan Ayhan hocam bu konuda da bir yardım etseniz.

 

[Korhan Ayhan]

Deneyiniz.

Not : Silme işlemi olduğu için verilerinizi yedeklemenizi öneririm.

Private Sub cmdSil_Click()
    Dim WS As Worksheet, TC_Bul As Range, Rng_Adres As String, Rng As Range
    
    If tckimlik.Value = "" Then
        MsgBox "Lütfen TC KİMLİK NO giriniz!", vbCritical
        tckimlik.SetFocus
        Exit Sub
    End If
    
    Set WS = Sheets("Izin_Takip")
    
    Set TC_Bul = WS.Range("A:A").Find(tckimlik.Value, LookAt:=xlWhole)
    If Not TC_Bul Is Nothing Then
        Rng_Adres = TC_Bul.Address
        Do
            If Rng Is Nothing Then
                Set Rng = TC_Bul
            Else
                Set Rng = Application.Union(Rng, TC_Bul)
            End If
            
            Set TC_Bul = WS.Range("A:A").FindNext(TC_Bul)
        Loop While Not TC_Bul Is Nothing And TC_Bul.Address <> Rng_Adres
    End If
    
    If Not Rng Is Nothing Then
        If MsgBox("Bulunan kayıtlar silinecektir." & vbCrLf & vbCrLf & "Onaylıyor musunuz?", vbYesNo + vbCritical + vbDefaultButton2) = vbYes Then
            Rng.EntireRow.Delete
            MsgBox "Kayıtların tümü silinmiştir.", vbOKOnly
        Else
            MsgBox "SİLME işlemi iptal edilmiştir.", vbInformation
        End If
    Else
        MsgBox "Uygun kayıt bulunamadı!", vbCritical
    End If

    Set Rng = Nothing
    Set TC_Bul = Nothing
    Set WS = Nothing
End Sub

 

[Tasarım]

@korhan hocam sağolun, varolun.