Mail boş gidiyor

[cenkataseven]

Merhaba

belli hücreleri mail sayfasına koplayarak göndermek istiyorum ancak mail her seferinde boş geliyor. aşağıdaki kodda renklendirdiğim yere HtmltoRange eklediğimde ise Sub or Function not defined hatası vermekte.

" You need to use this module with the RangetoHTML subroutine." ne demek? Nasıl ekleniyor? Bilemedim. Yardımcı olabilir misiniz.

Sub Mail()
' You need to use this module with the RangetoHTML subroutine.
' Works in Excel 2000, Excel 2002, Excel 2003, Excel 2007, Excel 2010, Outlook 2000, Outlook 2002, Outlook 2003, Outlook 2007, and Outlook 2010.
    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object
    
    Set rng = Worksheets("Ödeme").Range("C1:C31")

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .To = "biremailadresi@hotmail.com"
        .CC = ""
        .BCC = ""
        .Subject = "YIL"
        [COLOR="red"].HTMLBody = (rng)[/COLOR]
        .Send
    End With
    
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

 

[Zeki Gürsoy]

Kopyalarken eksik almışsınız. Bu Ron amcanın proseduru..

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2013
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

Kendi prosedurunuzde de aşağıdaki kullanacaksınız:

With OutMail
    .To = "biremailadresi@hotmail.com"
    .CC = ""
    .BCC = ""
    .Subject = "YIL"
    .HTMLBody = RangetoHTML(rng)
    .Send
End With

 

[cenkataseven]

Çok teşekkür ederim Zeki Bey