Soru mail gönderme kod yardımı

[spacebar]

arkadaşlar merhaba. kodda yardıma ihtiyacım var. excel belgesini pdf e çevirip mail atan bir makrom var. gönderilen kişiyi J2 hücresindeki formülden alacak şekilde düzenleyebilirmiyiz. .To = "" kısmını .Item.To = [J2] yaptım olmadı. yardımlarınız için teşekkürler...

Sub Metinkutusu2_Tıklat()
    Dim OutApp As Object
    Dim OutMail As Object
    Dim Yol As String, Dosya_Adi As String

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Yol = ThisWorkbook.Path
    Dosya_Adi = Yol & "\" & Format(Range("B7").Value, "yyyy-mm-dd-hh-mm") & " - " & Format(Now, "dd-mm-yy hh.mm") & " - PDA.pdf"
    
    Sheets("EMAİL BA").Range("A1:I21").ExportAsFixedFormat Type:=xlTypePDF, _
    FileName:=Dosya_Adi, Quality:=xlQualityStandard, IncludeDocProperties:=True
    
    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .To = ""
        .CC = ""
        .BCC = ""
        .Subject = Format(Range("B7").Value, "yyyy-mm-dd-hh-mm") & " - " & Format(Now, "dd-mm-yy hh.mm") & " - PDA"
        .Body = "İyi günler," & Chr(10) & Chr(10) & "Proforma ekte sunulmuştur." & Chr(10) & Chr(10) & "İyi çalışmalar."
        .Attachments.Add Dosya_Adi
        .Display
    End With
    On Error GoTo 0

    Set OutMail = Nothing
    Set OutApp = Nothing

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With

End Sub

 

[EmrExcel16]

Şu şekilde deneyiniz..

.To = Range("J2").Value

 

[spacebar]

üstad çok teşekkür ederim. ellerinize sağlık.

 

[EmrExcel16]

üstad çok teşekkür ederim. ellerinize sağlık.

Rica ederim , iyi çalışmalar .

 

[spacebar]

üstad daha önce farketmedim belgeyi kaydetmemesi için nasıl düzenlememiz gerekiyor.

 

[EmrExcel16]

Anlamadım , biraz daha açar mısınız ?

 

[spacebar]

exceldeki belgeyi pdf e çevirip ekinde mail atıyor. pdf dosyasının bir örneğini de dosya konumuna kaydediyor. ben kaydetmesin istiyorum. teşekkürler...

 

[EmrExcel16]

End Sub dan önce şu satırı ekleyin.

Kill Dosya_Adi

 

[spacebar]

üstad harikasınız. tuttuğunuz altın olsun. teşekkürler...

 

[EmrExcel16]

, kolay gelsin..