Makro ile belirtilen hücredeki mail adreslerine mail atma

[ToprakHan]

Merhaba,

İşyerimde kullanmak üzere bir makroya ihtiyacım var.Yapmak istediğim makro P1:T:1 arasında mail adresleri (To olacak adresler),P2:T2 arasında da (CC olacak adresler) mevcut ve A1:K15 arası mail hücresinde de mail yazacagım alan var(bu alanı mail atmak istiyorum.Ve M1 hücresinde mail konum var.Butona bastığımda Butona bastığımda A1:K15 arasındaki mailim,P1:T1 arasındaki mail adreslerine,P2:T2 mail adreslerininde CC de olacak şekilde,M1 hücresindeki konu başlığı ile göndermek istiyorum.
Bu işlemi excelin içerisinde açılan mail görüntüsü ile göndermek istiyorum.

Bu konuda acil desteğinize ihtiyacım var kaç gündür araştırıyorum ancak belirttiğim şekilde birşey bulamadım

Şimdiden teşekkür ederim

 

[hamitcan]

Kaynak: Mail Range/Selection in the body of the mail (rondebruin.nl)

Sub Mail_Selection_Range_Outlook_Body()
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
'Don't forget to copy the function RangetoHTML in the module.
'Working in Excel 2000-2016
    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object

    Set rng = Nothing
    On Error Resume Next
    'Only the visible cells in the selection
    Set rng = Selection.SpecialCells(xlCellTypeVisible)
    'You can also use a fixed range if you want
    'Set rng = Sheets("YourSheet").Range("D4:D12").SpecialCells(xlCellTypeVisible)
    On Error GoTo 0

    If rng Is Nothing Then
        MsgBox "The selection is not a range or the sheet is protected" & _
               vbNewLine & "please correct and try again.", vbOKOnly
        Exit Sub
    End If

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    Tox = [P1] & ";" & [q1] & ";" & [r1] & ";" & [s1] & ";" & [t1]
    CCx = [P21] & ";" & [q2] & ";" & [r2] & ";" & [s2] & ";" & [t2]
    With OutMail
        .To = Tox
        .CC = CCx
        .BCC = ""
        .Subject = [m1]
        .HTMLBody = RangetoHTML(Range("a1:k15"))
        .display
'        .Send   'or use .Display
    End With
    On Error GoTo 0

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub


Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

 

[ToprakHan]

Hamitcan Bey

ilgi ve alakanız için çok teşekkür ederim.İstediğim şey olmuş.Elinize sağlık hayırlı günler dilerim