Soru MAKRO İLE DÜŞEY ARA ve DEĞİŞTİR

[zulfuernek]

CV sayfasında kişiye ait sicil kısmına yazıp enter tuşuna basınca SYSTEM sayfasında kişiye ait bilgileri bulup ilgili yerlere yazmasını makro kodu ile sağlamak istiyorum.
örnek dosya ektedir

 

[Muzaffer Ali]

Merhaba.
CV sayfasının kod kısmına aşağıdaki kodu kopyalayın.

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Bul As Range
    If Not Intersect(Target, Range("E2")) Is Nothing Then
        With Worksheets("SYSTEM")
            Set Bul = .Range("A:A").Find(what:=Target, lookat:=xlWhole)
            If Bul Is Nothing Then
                MsgBox "Sicil: " & Target.Text & vbLf & "Aradığınız sicil bulunamadı kontrol ederek yeniden deneyiniz.", vbInformation
                Target.Select
                Exit Sub
            Else
                Range("E3") = Bul(1, "B")
                Range("E4") = Bul(1, "C")
                Range("E5") = Bul(1, "D")
                Range("E6") = Bul(1, "E")
            End If
        End With
    End If
End Sub

 

[zulfuernek]

Emeğinize sağlık. tam istediğim gibi olmuş.

 

[zulfuernek]

Buna ek olarak cv kısmına bilgiler geldi ben bu sayfada sicil kısmı arama alanı olduğu için ora hariç diğer satırda değişme yaptığımda (örneğin telefon nosunu değişeceğim) cv de bu satırı değişip commad butona tıklayınca ilgili kişide SYSTEM sayfasında bu değişikliği yapabilirmi?

 

[Muzaffer Ali]

Buna ek olarak cv kısmına bilgiler geldi ben bu sayfada sicil kısmı arama alanı olduğu için ora hariç diğer satırda değişme yaptığımda (örneğin telefon nosunu değişeceğim) cv de bu satırı değişip commad butona tıklayınca ilgili kişide SYSTEM sayfasında bu değişikliği yapabilirmi?

CV sayfasına bir buton ekleyip aşağıdaki kodları butona atayın.

Private Sub CommandButton1_Click()
    Dim Bul As Range
    With Worksheets("SYSTEM")
        Set Bul = .Range("A:A").Find(what:=Range("E2"), lookat:=xlWhole)
        If Bul Is Nothing Then
            MsgBox "Sicil: " & Range("E2").Text & vbLf & "Aradığınız sicil bulunamadı kontrol ederek yeniden deneyiniz.", vbInformation
            Range("E2").Select
            Exit Sub
        Else
            Bul(1, "B") = Range("E3")
            Bul(1, "C") = Range("E4")
            Bul(1, "D") = Range("E5")
            Bul(1, "E") = Range("E6")
            MsgBox "Kayıt gerçekleştirildi", vbInformation
        End If
    End With
End Sub