Soru Makro ile iki tarih arası günü yazdırma.

[hamza2011]

Merhaba;

Örnek dosyada paylaştığım A sütunun 14. satırından itibaren başlayan tarihlerin bugünkü tarih ile arasındaki gün farkını yine B sütunun 14. satırından başlamak üzere tüm sütuna makro ile yazdırmak istiyorum. Fakat A sütunu boş ise B sütununda boş göstermeli.

Konu hakkında lütfen yardım eder misiniz.

 

[Korhan Ayhan]

Deneyiniz.

Sub Gun_Farki()
    Application.ScreenUpdating = False
    
    Son = Cells(Rows.Count, 1).End(3).Row
    
    With Range("B14:B" & Son)
        .Formula = "=IF(A14="""","""",TODAY()-A14)"
        .Value = .Value
    End With
    
    Application.ScreenUpdating = True
End Sub

 

[Ömer BARAN]

Merhaba, alternatif olsun.

Sub GUN_FARKI()
Dim a(), b()
Dim brn, brn2, i As Integer
Range("B14:B" & Rows.Count).Clear
Application.Calculation = xlCalculationManual
Application.ScreenUpdating = False
    a = Range("A14:A" & Cells(Rows.Count, "A").End(3).Row).Value
    ReDim b(1 To UBound(a), 1 To 1)
    For i = 1 To UBound(a)
        brn = brn + 1
        If a(i, 1) = "" Then b(brn, 1) = "": brn2 = brn2 + 1
        If a(i, 1) <> "" Then b(brn, 1) = Date - a(i, 1)
    Next i
    If brn > 0 Then [B14].Resize(brn, 1) = b
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
MsgBox "İşlem tamamlandı." & vbLf & brn - brn2 & _
        " adet tarih için gün farkı hesaplandı.", vbInformation, "..:: Ömer BARAN ::.."
    Erase a: Erase b: brn = Empty: brn2 = Empty: i = Empty
End Sub

 

[hamza2011]

Hocam sizlere çok teşekkür ediyorum. İyi ki varsınız.