makro kaydetme sorunu

[sedatulukus]

Sub PdfKayıt()

Path = Worksheets("AYARLAR").Range("J11").Text

ADISOYADI = Worksheets("İZİN FORMU").Range("C5").Value

Worksheets("İZİN FORMU").ExportAsFixedFormat xlTypePDF, Filename:=Path & ADISOYADI & "_" & Date & ".pdf"

End Sub

Merhaba,
Bu şekil de kaydetmek için çalıştırdığım bir makrom var fakat dosya adın da bir den fazla kaydetmek isteyince bir önceki kayıtlı dosya üzerine kayıt yapmakta 2 dosyanın da sonuna rakam ekleyerek aynı isimde birden fazla kaydetme yi nasıl yapabilirim
yardımcı olursanız sevinirim.

 

[mustafa1205]

Sub PdfKayıt()

Dim Path As String
Dim ADISOYADI As String
Dim DosyaAdi As String
Dim TamYol As String
Dim Sayac As Integer

Path = Worksheets("AYARLAR").Range("J11").Text
ADISOYADI = Worksheets("İZİN FORMU").Range("C5").Value

' Tarihi formatlı alalım
DosyaAdi = ADISOYADI & "_" & Format(Date, "dd.mm.yyyy")
TamYol = Path & DosyaAdi & ".pdf"

Sayac = 1

' Aynı isimde pdf varsa numara ekle
Do While Dir(TamYol) <> ""
TamYol = Path & DosyaAdi & "_" & Sayac & ".pdf"
Sayac = Sayac + 1
Loop

' PDF kaydet
Worksheets("İZİN FORMU").ExportAsFixedFormat _
Type:=xlTypePDF, _
Filename:=TamYol

MsgBox "PDF başarıyla kaydedildi:" & vbCrLf & TamYol, vbInformation

End Sub


Dener misiniz...

 

[sedatulukus]

süper oldu çok teşekkür ederim çok sağ olun.