Mevcut Sayfadaki Veriyi Seçtiğim Excel Dosyasına Aktarma

[cengizyener]

Merhabalar,

Elimde Deneme diye bir excel dosya var burdaki verileri A2:G9 a kadar olan verileri benim seçeceğim klasörün ve seçeceğim kapalı excel dosyanın içine değerleri kopyala yapıştır kaydet ve kapatmak istiyorum. Bir türlü böyle ir makro bulamadım. Yardımcı olur musunuz

 

[Korhan Ayhan]

Merhaba,

Aşağıdaki kodu kendi isteğinize göre düzenlersiniz...

Kapalı dosyada veri aktarımının yapılacağı sayfanın adını Sayfa1 olarak baz aldım. Siz istediğiniz gibi düzenlersiniz.

Option Explicit

Sub Verileri_Farklı_Dosyaya_Aktar()
    Dim My_Area As Range, Target_File As Variant, Target_Sheet As Worksheet
    
    Set My_Area = Range("A2:G9")
    
    Target_File = Application.GetOpenFilename( _
                  FileFilter:="Excel Dosyaları (*.xls;*.xlsb;*.xlsx;*.xlsm),*.xls;*.xlsb;*.xlsx;*.xlsm", _
                  Title:="Lütfen bir dosya seçiniz...", MultiSelect:=False)

    If Target_File = False Then
        MsgBox "İşleme devam edebilmeniz için dosya seçmelisiniz!", vbCritical
        Exit Sub
    End If
    
    On Error Resume Next
    Set Target_File = Workbooks.Open(Target_File, True, False)
    Set Target_Sheet = Nothing
    Set Target_Sheet = Target_File.Sheets("Sayfa1")
    On Error GoTo 0
    
    If Not Target_Sheet Is Nothing Then
        Target_Sheet.Range("A1").Resize(My_Area.Rows.Count, My_Area.Columns.Count).Value = My_Area.Value
        Target_File.Close True
        MsgBox "Veri aktarımı tamamlanmıştır.", vbInformation
    Else
        MsgBox "Sayfa bulunamadı!", vbCritical
        Target_File.Close False
    End If
    
    Set My_Area = Nothing
    Set Target_Sheet = Nothing
    Set Target_File = Nothing
End Sub

 

[cengizyener]

Korhan bey çok teşekkür ederim emeğinize sağlık. Tam ihtiyacım olduğu gibi olmuş. Zahmet olmazsa bu kodların yanlarına öğrenmek için kısaca anlamlarını yazabilir misiniz ? Tahmin ettiğimden daha karmaşık geldi kodlar yeni yeni öğreniyorumda