not defterine aktarma

[microaim]

değerli arkadaşlar;

excelde yaptığımız bir çalışmayı makro yardımıyla başka bir programa aktarabilirmiyiz?mesela excelde yazılmış kısa bir yazıyı (ya da tabloyu)
commandbutton yardımıyla "not defteri"ne aktarmak mümkün mü?

 

[c_akan]

Merhaba aşağıdaki kodları inceleyebilirsin;

(1)_________

Sub test()

Open ThisWorkbook.Path & "\Adsız.txt" For Append As #1
Print #1, Sheets(1).Range("A1").Value
Close #1

End Sub

(2)_________

Sub ExportToNotepad()

WriteRangeToTextFile Range("A4:C26"), "H:\temp\file1.txt", ","
WriteRangeToTextFile Range("F4:H26"), "H:\temp\file2.txt", ","


Shell "notepad.exe h:\temp\file1.txt", vbMaximizedFocus
Shell "notepad.exe h:\temp\file2.txt", vbMaximizedFocus

End Sub


Sub WriteRangeToTextFile(Source As Range, Path As String, Delimiter As String)
Dim oFSO As Object
Dim oFSTS As Object
Dim lngRow As Long, lngCol As Long


Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oFSTS = oFSO.CreateTextFile(Path, True)

For lngRow = 1 To Source.Rows.Count

For lngCol = 1 To Source.Columns.Count

If lngCol = Source.Columns.Count Then
oFSTS.Write Source.Cells(lngRow, lngCol) & vbCrLf
Else
oFSTS.Write Source.Cells(lngRow, lngCol) & Delimiter
End If

Next lngCol

Next lngRow

oFSTS.Close

Set oFSTS = Nothing
Set oFSO = Nothing

End Sub


Not:Kodlar alıntıdır. Örnek olması açısından gönderdim.

Kolay Gelsin.

 

[microaim]

çok teşekkür ederim..

 

[demirtas]

Kodlar gerçekten çok güzel çalışıyor..
Elinize sağlık..


Peki,

Oluşturulan text dosyalarına isim vermeden (untitled olarak) sadece açıp, içine ilgili verileri yazarak ama dosyayı herhangi bir yere kaydetmeden bırakmak mümkün müdür?

Teşekkürler..

 

[demirtas]

Başka bir örnekte text dosyası ismini inputboxtan aldığı veri ile oluşturduğunu görünce benim sorunum da çözülmüş oldu. Örnek olur diye kodlar ektedir..

Dim inputname1 As Variant
Sub ExportToNotepad()

inputname1 = InputBox("Notepad name", "Text dosyasına isim verin.")
If inputname1 = "" Then Exit Sub
WriteRangeToTextFile Selection, "C:\Documents and Settings\username\Desktop\" & inputname1 & ".txt", " "

Shell "notepad.exe C:\Documents and Settings\username\Desktop\" & inputname1 & ".txt", vbNormalFocus

End Sub