Otomatik kapanma

[miniatürk]

Arkadaşlar abc adlı çalışma kitabımın , 15 dakika boyunca herhangi bir işlem yapılmadığı taktirde
otomatik olarak kendini kaydedip kapatmasını istiyorum.
Yardımlarınız için şimdiden Teşekkürler

 

[kamil_hoca]

Sn. minatürk;

ADIM 1- Alt+F11 ile VB Düzenleyicisine girip ThisWorkbook bölümüne girip aşağıdaki kodu yapıştırınız.

Private Sub Workbook_Open()
'-----------------------------------------------------------------
nElapsed = TimeSerial(0, 15, 0) '15 minutes

'start a timer to countdown inactivity
nTime = Now + nElapsed
Application.OnTime nTime, "Countdown"
End Sub


'-----------------------------------------------------------------
Private Sub Workbook_BeforeClose(Cancel As Boolean)
'-----------------------------------------------------------------
On Error Resume Next
Application.OnTime EarliestTime:=nTime, Procedure:="Countdown", Schedule:=False

End Sub


'-----------------------------------------------------------------
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
'-----------------------------------------------------------------
'any workbook activity resets the timer
Application.OnTime nTime, "Countdown", , False
nTime = Now + nElapsed
Application.OnTime nTime, "Countdown"
End Sub

ADIM 2- VBA' ya Modül ekleyerek bu bölüme de;

Option Explicit

Public nElapsed As Double
Public nTime As Double

'-----------------------------------------------------------------
Public Sub Countdown()
'-----------------------------------------------------------------
ThisWorkbook.Save
ThisWorkbook.Close
End Sub

kodunu yapıştırınız.

Excel dosyanız 15 dakika kullanılmadığı zaman save edip kapanacaktır.