Power BI Dinamik URL Yenileme Sorunu

[mekist]

Merhaba

Power BI' da aşağıdaki fonksiyonu sorguyla çağırıp dinamik url oluşturuyorum
Desktopta yenileme yapıyor, Dinamik ulr olduğu için portalde yenileme yapmıyor, aşmanın yolu var mıdır

"Aşağıdaki veri kaynakları şu anda yenilemeyi desteklemediğinden bu anlamsal model için yenileme planlayamazsınız "

(produceName as text) as table =>
let
    Kaynak = Json.Document(Web.Contents("https://www.isyatirim.com.tr/_layouts/15/IsYatirim.Website/Common/Data.aspx/MaliTablo?companyCode=" & produceName & "&exchange=TRY&financialGroup=XI_29&year1=2024&period1=12&year2=2024&period2=9&year3=2024&period3=6&year4=2024&period4=3")),
    value = Kaynak[value],
    #"Tabloya Dönüştürüldü" = Table.FromList(value, Splitter.SplitByNothing(), null, null, ExtraValues.Error),
    #"Genişletilen Column1" = Table.ExpandRecordColumn(#"Tabloya Dönüştürüldü", "Column1", {"itemCode", "itemDescTr", "itemDescEng", "value1", "value2", "value3", "value4"}, {"Column1.itemCode", "Column1.itemDescTr", "Column1.itemDescEng", "Column1.value1", "Column1.value2", "Column1.value3", "Column1.value4"})
in
    #"Genişletilen Column1"

 

[pitchoute]

Merhabalar, bu şekilde deneyip sonucu paylaşabilir misiniz;

(produceName as text) as table =>
let
    baseUrl = "https://www.isyatirim.com.tr",
    relativeUrl = "/_layouts/15/IsYatirim.Website/Common/Data.aspx/MaliTablo",
    queryParams = [
        companyCode = produceName,
        exchange = "TRY",
        financialGroup = "XI_29",
        year1 = "2024",
        period1 = "12",
        year2 = "2024",
        period2 = "9",
        year3 = "2024",
        period3 = "6",
        year4 = "2024",
        period4 = "3"
    ],
    Kaynak = Json.Document(Web.Contents(baseUrl, [RelativePath = relativeUrl, Query= queryParams])),
    value = Kaynak[value],
    #"Tabloya Dönüştürüldü" = Table.FromList(value, Splitter.SplitByNothing(), null, null, ExtraValues.Error),
    #"Genişletilen Column1" = Table.ExpandRecordColumn(#"Tabloya Dönüştürüldü", "Column1", {"itemCode", "itemDescTr", "itemDescEng", "value1", "value2", "value3", "value4"}, {"Column1.itemCode", "Column1.itemDescTr", "Column1.itemDescEng", "Column1.value1", "Column1.value2", "Column1.value3", "Column1.value4"})
in
    #"Genişletilen Column1"

 

[mekist]

Merhaba

teşekkür ederim, elinize sağlık
Güvenlik düzeyiyle ilgili bir sorun vardı, onu da çözdüm, manüel yeniledim sorun çıkmadı, 23:00 için sisteme yenileme kurdum oradan izleyeceğim

 

[mekist]

tekrar teşekkür ederim, yabancı forumlara yazıp çözememiştim

 

[pitchoute]

Rica ederim, iyi çalışmalar