Puantaj Tablosuna Tek Sütunda İzin ve Rapor Alanların İzinlerini ve Aynı Sütuna Özel Günleri Ekleme

[Betülkrdnz]

Merhaba,

Mecvutta olan puantaj tablosuna ek bir sekme açarak buraya izin, rapor ve şirket dışı görevleri manuel olarak eklemem gerekli. Sonra mevcut tabloda bir sütun daha açarak bunları düşeyara ile ana tabloya aktarmam gerekli bunlara ek olarak özel gün resmi tatil bayram varsa onlarda eklenecek.
Yani o sütunda bir kişi izin rapor ve şirket dışı görev aldıysa yan sekmeden onlar gelecek ayrıca aynı sütunda özel gün bayram resmi tatil varsa bunlar, geriye kalan günler ise iş günü ve hafta sonu olarak görünmesi gerekmektedir. Ekte puantaj tablosunu ve yöneticimin bana örnek olsun diye göndermiş olduğu dosyayı ekliyorum.

Teşekkür ederim,

 

[Suskun]

Çalışma durumu sütununun D2 hücresine Personel ve izinde Farklı isimler olacaksa, aşağıdaki dizi formülü yapıştırıp Ctrl+Shift+Enter tuşuna basın ve aşağıya doğru kopyalayın

=EĞERYOKSA(İNDİS('Rapor ve İzin'!C:C;KAÇINCI(1;('Rapor ve İzin'!B:B=İstenen!C2)*('Rapor ve İzin'!A:A=İstenen!A2);0));"")  Ctrl+Shift+Enter

Eğer sadece bir personel için işlem yapılırsa D2 hücresine aşağıdaki kodu yapıştırıp aşağıya doğru kopyalayın.

=EĞERYOKSA(İNDİS('Rapor ve İzin'!C:C;KAÇINCI(C13; 'Rapor ve İzin'!B:B;0));"")

 

[Betülkrdnz]

Birinci iletmiş olduğunuz formül çalışıyor onun için teşekkür ediyorum.

Fakat burada eksik olan durum şu benden istenen D2 sütununda resmi tatil bayram özel günlerin de yazıyor olması onun tarihlerini de puantaj tablosuna "Özel Gün Tarihleri" sekmesi olarak ekledim. Ayrıca geriye kalan günlerde Pazartesi Cuma çalıştığımız için bu aralıkta izin bayram vs. yok ise "İş Günü" yazıyor olması hafta sonuna denk gelen gün ise "Hafta Sonu" olarak yazılması.

 

[Suskun]

D sütünundaki Birinci formülün olduğu tüm hücreleri temizleyip yerine aşağıdaki dizi formülü D2 hücresine yapıştırıp Ctrl+Shift+Enter Yapın (C2 sütunundaki 31 nisan tarihini 30 nisan yapmazsanız ilk satır Değer hatası verir) sonra aşağıya doğru kopyalayın.

=EĞER(HAFTANINGÜNÜ(C2;2)<6;EĞERYOKSA(İNDİS('Rapor ve İzin'!C:C;KAÇINCI(1;('Rapor ve İzin'!B:B=İstenen!C2)*('Rapor ve İzin'!A:A=İstenen!A2);0));"")&EĞERHATA(İNDİS('Özel Gün Tarihleri'!B:B;KAÇINCI(C2; 'Özel Gün Tarihleri'!A:A;0));"");"Hafta Sonu") ctrl+shift+Enter

 

[Betülkrdnz]

Haftasonu ve özel günler geldi ama maalesef geriye kalan günlerde "İş Günü" yazmıyor son olarak onu sorsam size

 

[Suskun]

Formül sonundaki
;"");"Hafta Sonu"
nu
;"İş günü");"Hafta Sonu"
Yapın

 

[Betülkrdnz]

Bu şekilde bir hata oldu yani yıllık izin rapor olanların yanına da iş gününü getirdi. Ekte iletiyorum size örneğini

 

[Suskun]

D sütununa aşağıdaki dizi formülünü kopyalayın

=EĞERYOKSA(İNDİS('Rapor ve İzin'!C:C;KAÇINCI(1;('Rapor ve İzin'!B:B=İstenen!C16)*('Rapor ve İzin'!A:A=İstenen!A16);0));EĞERYOKSA(İNDİS('Özel Gün Tarihleri'!B:B;KAÇINCI(C16;'Özel Gün Tarihleri'!A:A;0));EĞER(HAFTANINGÜNÜ(C16;2)<6;"İş Günü";"Hafta Sonu"))) Ctrl+shift+Enter

 

[Betülkrdnz]

Çokk çok teşekkür ediyorum sizi çok uğraştırdım ama oldu sonunda

 

[Suskun]

Rica ederim.Kolay gelsin.

 

[Betülkrdnz]

Ben bu tabloya bir de çalışma saati ekledim İş Günü ve Şirket Dışı Görev olunca 9 saat izin rapor vs. günlerde 0 olarak göstermesi için. Formül bu şekilde.

=EĞER(D2="İş Günü";"09:00:00";EĞER(D2="Şirket Dışı Görev";"09:00:00";"00:00:00"))

Ama ayrılan personel için de aynı bu şekilde hesaplıyor. Onu bu formülün için yazabilir miyiz ayrılan personel için her günü sıfır göstermesi için?

Yaptığım tabloyu ekte iletiyorum.

 

[Suskun]

Deneyin

=EĞER(VE(D2="İş Günü";B2<>"Ayrılan Personel");"09:00:00";EĞER(D2="Şirket Dışı Görev";"09:00:00";"00:00:00"))

 

[Betülkrdnz]

Çok teşekkür ediyorum