renge göre sıralama

[mrt.13]

Merhaba,

Belli bir sütunda yüzlerce veri var. Buna formul girip aradğımı yazıp renkledirip bulabiliyorum. İstediğim otomatik olarak arama yapma sırama göre bunları sıralasın veya yan hücrelere yine aynı şekilde arama sırama göre numara versin

 

[yanginci34]

Merhaba girmiş olduğunuz formül ne? Arama ve sıralama kriteriniz ne? ve nasıl bir numaralandırma istiyorsunuz. Bunları bir örnek dosya ile açarsanız daha çabuk sonuca ulaşa bilirsiniz.

 

[HücrelereFısıldayanAdam]

Yapmaya çalıştığınız şey çok anlamlı durmuyor. Nasıl bir veriden neleri elde ediyorsunuz / araştırıyorsunuz, bunları da veriyle birlikte anlatırsanız, daha mantıklı analiz yollar bulunmakta.

 

[mrt.13]

İlginiz için teşekkürler. Şöyle anlatayım örneğin a sütununda

46542328
78997888
74874887
78798324
.
.
.
.
.

bu şekilde devam eden binlerce sayı var. Bunların aralarından diyelimki bana 30 tanesi lazım. Arama yaptıkça bu 30 adet sayının yine aynı sütünda en üste gelmesini istiyorum. Veya farklı bir sütüna ayrı olarak gelebilir.

 

[HücrelereFısıldayanAdam]

Aranılacak veri kümesini A sütununa koyun,
Aranan sayıları içeren bir liste oluşturun bu B sütununa koyun,
C sütuna amacınıza uygun formül yazılır, Peki amacınız nedir?
Bu mevcut durumda amacınız belli değil, B'deki veri A'da var mı? Ya da hangileri Yok, B'deki veri A'da kaç kere var?.... gibi bir çok farklı amaç olabilir.

 

[mrt.13]

aradağım numaralar yazılı bir şekilde yok. foto üzerinden okuyup listede olanları mecburen yazıp arama yapmam gerekiyor. Yani arama yapacak veri kümem yok tek tek manuel yazmam gerekicek tek bir veriyi yazdığım anda bulup onları alt alta sıralasın istiyorum

 

[HücrelereFısıldayanAdam]

Hocam önceki mesajlarınıza baktım

"a1 hücresine a yazdığımda sonra sırasıyla b,c,d yazdığımda yan sütundaki hücreleri bu ifadelerle alt alta doldurmasını istiyorum. Yanına da otomatik olarak 1 2 diye sıra verebilirmi... örneğin a1 e murat yazdım b1 e murat gelsin daha sonra a1deki ifadeyi silip yerine tekrar ahmet yazdım bu sefer b2 ye ahmet yazsın"

demişsiniz.

Yani, Şunu demek istiyorsunuz:
1- Dinamik bir liste tutacaksınız
2- Bu listeye A1'e her yeni veri girdiğinizde, B sütununa, önceki veri kayıtları korunarak, son satıra yeni veriyi eklenecek.
3- C sütununda ayrıca sıra numarası yer alacak.

Böyle bir şeye neden ihtiyaç duyduğunuzu hala anlayamadım ama bir private sub ile yapmak mümkün.

1. Bir excel kitabı oluşturun, makro kaydedebilir biçimde kaydedin.
2. Kitapta, Sayfa1 adlı sayfa adına sağ tıklayın,
3. "kod görüntüle"
4. Aşağıdaki kodu buraya yapıştırın.

A1 hücresi sizin veri giriş alanınız.
B Sütununda istediğiniz dinamik liste oluşturulacak.

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim KeyCell As Range
    Dim LastRow As Long
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Sheets("Sayfa1")
    Set KeyCell = Range("A1")
    If Not Application.Intersect(KeyCell, Range(Target.Address)) Is Nothing Then
        With ws
            LastRow = .Cells(.Rows.count, "B").End(xlUp).row + 1
            .Cells(LastRow, 2).Value = KeyCell.Value
            .Cells(LastRow, 3).Value = LastRow - 1
        End With
    End If
End Sub

 

[mrt.13]

hocam çok teşekkürler elinize sağlık . bir sorum daha olucak . sütündaki verileri arama yaptığımda bulup otomatik olarak sarı ile işaretleyebiliyorum.

Peki bu sarı ile işaretli olan , başka bir hücreye nasıl aktarılır. Örneğin a sütununda

a
b
c
d
e
f
g

şeklinde devam eden verilerden c yi bulup sarı ile işaretledim. B1 hücresine c gelebilir mi. sonra yine e yi aradım diyelim ve e harfi işaretlendi yine b1 hücresinde gözüksün

 

[HücrelereFısıldayanAdam]

Hocam yapmaya çalıştığınız işi mantıklı durmuyor. Mantığını anlamadan da çözüm sunmak mümkün değil.
Ben, çok uzun bir liste içinden bana gerekenleri almak için, ctrl f ile aratıp, solundaki sütuna x yazıp, işim bitince x leri filtreliyorum.
Bu tarz basit işler için, karmaşık yollar aramak bize bişey kazandırmaz bence.

 

[mrt.13]

sizi de uğraştırdım baya, teşekkür ederim çok.
hocam ben de öyle yapıyorum zaten. verilerin içinde ctrl f ile bulup yanlarına sayıları yazıp sıraya göre filtre yapıyorum daha sonra. sıralaması benim için önemli. o yüzden de tek tek aratıyorum. benim niyetim yaptığım arama sırasına göre başka bir köşede alt alta akması. yüzlerce veriden ctrl f yapıp bulup yanına numara yazmak istemiyorum. ctrl f yapıp bulunduktan sonra otomatik olarak başka bi hücreye gelsin. sonra yine aynı işlem tekrarlansın.

 

[Korhan Ayhan]

Peki aradığınız veri birden fazla hücrede geçiyorsa nasıl bir sonuç olmasını istiyorsunuz.

Birde diğer açtığınız başlıkta sanırım bu konuyla aynı içeriğe sahip. Eğer durum böyleyse mükerrer başlık açmamanızı rica ederim.

 

[mrt.13]

Merhaba,

birden fazla hücrede olması imkansız. bütün veriler birbirinden farklı

 

[Korhan Ayhan]

İşlemi yapacağınız sayfa adı üzerinde sağ tıklayıp "KOD GÖRÜNTÜLE" dedikten sonra karşınıza gelen pencereye aşağıdaki kodu uygulayınız.

Sonra excel sayfasına geçip sayfada herhangi bir hücreye çift tıkladığınızda kod sizden aramak istediğiniz veriyi yazmanızı isteyecek ve arama işlemi başlayacaktır.

Bulunan veriler sırayla B sütununa listelenecektir.

Option Explicit

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Dim Searched_Data As Variant, Find_Data As Range
    
    Searched_Data = Application.InputBox("Aramak istediğiniz veriyi giriniz!", "Aranan Veri")
    
    If Searched_Data = "" Then
        MsgBox "Arama işlemine devam edebilmeniz için veri girişi yapmalısınız!", vbCritical
        Exit Sub
    End If

    If Searched_Data = False Then
        MsgBox "Arama işlemi iptal edilmiştir.", vbExclamation
        Exit Sub
    End If
    
    Set Find_Data = Range("A:A").Find(Searched_Data, , , xlWhole)
    If Not Find_Data Is Nothing Then
        If Cells(1, 2) = "" Then
            Cells(1, 2) = Find_Data.Value
        Else
            Cells(1, 2).End(3)(2, 1) = Find_Data
        End If
    Else
        MsgBox "Aranan veri bulunamadı!", vbCritical
    End If
End Sub

 

[mrt.13]

çok sağolun elinize sağlık