Sayfadaki Verileri Çıktı Sayfasına Aktarıp Çıktı Sayfasını Dışarı Aktarmak

[sahir73]

Başlıkta belirttiğim durumun çoğunu yapabilecek yetkinlikte olduğumu düşünüyordum ama bazen insan tıkanıyor bende şuan o noktadayım. Yapmak istediğim şu ekte belirtiğim çalışmamda bulunan "TevdiListesi" sayfasındaki verileri kopyalayıp "Print" Sayfasın A4 hücresinden başlamak üzere yapıştırma işlemi yapıp "Print" Sayfasını içinde bulunan tarih ismiyle dışarı aktarmak ve eğer içinde bulunan tarih isiminde daha önce dışarı aktarılmış bir sayfa var iste " Tevdi listesi daha önce oluşturulmuş " şeklinde uyarı verdirmek. Bu işlem frmAnaSayfa' da bulunan " Tevdi Listesi Oluştur" butonunu tetikleme sonucu gerçekleşecek. Şimdiden yardımlarınız için teşekkür ederim.

 

[Korhan Ayhan]

Deneyiniz.

Option Explicit

Sub Aktar()
    Dim S1 As Worksheet, S2 As Worksheet, Son As Long, Dosya_Adi As String
    
    Set S1 = Sheets("TevdiListesi")
    Set S2 = Sheets("Print")
    
    S2.Range("A4:I" & S2.Rows.Count).ClearContents
    
    Son = S1.Cells(S1.Rows.Count, 1).End(3).Row
    If Son > 1 Then
        S1.Range("A2:I" & Son).Copy S2.Cells(S2.Rows.Count, 1).End(3)(2, 1)
        S2.Copy
        Dosya_Adi = ThisWorkbook.Path & Application.PathSeparator & Format(Date, "gg_aa_yyyy") & ".xlsx"
        If Dir(Dosya_Adi) <> "" Then
            MsgBox "Tevdi listesi daha önce oluşturulmuş!", vbCritical
        Else
            ActiveWorkbook.SaveAs Dosya_Adi, 51
            ActiveWorkbook.Close
        End If
    End If
    
    Set S1 = Nothing
    Set S2 = Nothing
End Sub

 

[sahir73]

Korhan Ayhan bey ne kadar teşekkür etsem azdır. Emeğinizden dolayı çok teşekkür ederim. Tam istediğim gibi. Sağ olun var olun.