Soru Sayfalardan Toplama

ezgi73 · 18 Nisan 2019

Herkese selamlar;

G3 VE H3 hücrelerinden, yıl ve ay seçtiğimde A ve B toplamlarının ,sayfalardan gelerek ve o ayın tarihlerini listeleyerek gelmesini makro ile yapmak mümkünmüdür.

Saygılarımla

EZGİ

Dosya linki : https://dosya.co/g8lyrnimr7us/sayfa_toplamları.xlsx.html

veyselemre · 18 Nisan 2019

Kod:

Sub test()
    krt = WorksheetFunction.Proper([H3] & " " & [G3])
    With CreateObject("Scripting.Dictionary")
        For Each sh In ThisWorkbook.Sheets
            If sh.Name <> "SON" Then
                son = sh.Cells(Rows.Count, 1).End(3).Row
                For i = 2 To son
                    tar = sh.Cells(i, 1).Value
                    If krt = WorksheetFunction.Proper(Format(tar, "MMMM YYYY")) Then
                        .Item(tar) = .Item(tar) + sh.Cells(i, 2).Value
                    End If
                Next i
            End If
        Next sh
        If .Count > 0 Then
            itms = WorksheetFunction.Transpose(.items)
            kys = WorksheetFunction.Transpose(.keys)
            With [c2]
                .Resize(UBound(kys)).Value = kys
                .Offset(, 1).Resize(UBound(kys)).Value = itms
                .Resize(UBound(kys), 2).Sort .Cells(1), , , , , , , xlNo, , , , , xlSortTextAsNumbers
            End With
        End If
    End With
End Sub

ezgi73 · 18 Nisan 2019

çok teşekür ederim hocam YALNIZ SON sayfasında a ve b sütünuna yazması lazım nasıl yapmalıyım saygılarımla

muygun · 18 Nisan 2019

Merhaba;
Alternatif olsun.
Deneyin.
İyi çalışmalar.

Link:
https://dosya.co/wqud68quytu0/ezgi73-sayfa_toplamları.rar.html

ezgi73 · 18 Nisan 2019

muygun' Alıntı:
Merhaba;
Alternatif olsun.
Deneyin.
İyi çalışmalar.

Link:
https://dosya.co/wqud68quytu0/ezgi73-sayfa_toplamları.rar.html

hocam muhteşemsiniz çok teşekür ederim 2 sorum daha olacak eğer zamanınızı çalmıyorsam
1- örnek olarak 2 nolu sayfada c d h sütunlarınıda son sayfasındaki toplama dahil etmem gerekir
2-sorun ise örnek 3 nolu sayfada e stunundaki verileride son sayfasında c stununa sütununa toplamam gerekli
yardımcı olabilirseniz minnetar kalırım

muygun · 18 Nisan 2019

Merhaba;
Örneğinizde 2 nolu sayfada sayfada c d h sütunlarında veri yok
Yine aynı şekilde 3 nolu sayfada da e sütununda veri yok.
Örneğinize ( yada benim eklediğim dosyada ilgili sayfalara) örnek veri uygulayarak dosyayı ekleyin. Tekrar bakalım
İyi çalışmalar.

ezgi73 · 18 Nisan 2019

muygun' Alıntı:
Merhaba;
Örneğinizde 2 nolu sayfada sayfada c d h sütunlarında veri yok
Yine aynı şekilde 3 nolu sayfada da e sütununda veri yok.
Örneğinize ( yada benim eklediğim dosyada ilgili sayfalara) örnek veri uygulayarak dosyayı ekleyin. Tekrar bakalım
İyi çalışmalar.

https://dosya.co/vhjd9lnve2m8/sayfa_toplamları.xlsx.html

hocam dosyayı ekledim sayfaların sütün başlıklarında toplanması gereken yerleri belirledim şimdiden çok çok teşekür ederim
saygılarımla

veyselemre · 18 Nisan 2019

Kod:

Sub veriCek()
    Sheets("SON").Select
    yil = [I1]
    ay = [I2]
    Range("A2:F" & Rows.Count).ClearContents
    Set adoCN = CreateObject("ADODB.Connection")
    adoCN.Provider = "Microsoft.ACE.OLEDB.12.0"
    adoCN.Properties("Data Source") = ThisWorkbook.FullName
    adoCN.Properties("Extended Properties") = "Excel 12.0; HDR=NO"
    adoCN.Open
    Set rs = CreateObject("Adodb.RecordSet")

    son1 = Sheets("1").Cells(Rows.Count, 1).End(3).Row
    son2 = Sheets("2").Cells(Rows.Count, 1).End(3).Row
    son3 = Sheets("3").Cells(Rows.Count, 1).End(3).Row
    son4 = Sheets("4").Cells(Rows.Count, 1).End(3).Row

    strsql = "SELECT tar, SUM(top1), SUM(top2), SUM(top3), SUM(top4), SUM(top5) FROM " & _
             "(" & _
             "SELECT F1 AS tar, F4 AS top1, F7 AS top2, F8 AS top3, F9 AS top4, 0 AS top5 FROM [1$A2:I" & son1 & "] UNION " & _
             "SELECT F1 AS tar, (F4+F5+F6) AS top1, F11 AS top2, F12 AS top3, F14 AS top4, F15 AS top5  FROM [2$A2:O" & son2 & "] UNION " & _
             "SELECT F1 AS tar, (F4+F5+F6) AS top1, F11 AS top2, F12 AS top3, F14 AS top4, F15 AS top5  FROM [3$A2:O" & son3 & "] UNION " & _
             "SELECT F1 AS tar, (F4+F5+F6) AS top1, F11 AS top2, F12 AS top3, F14 AS top4, F15 AS top5  FROM [4$A2:O" & son4 & "] " & _
             ") " & _
             "GROUP BY tar HAVING MONTH(tar)=" & ay & " AND YEAR(tar)=" & yil & " ORDER BY tar"
    rs.Open strsql, adoCN, 1, 1

    [a2].CopyFromRecordset rs
    rs.Close
    adoCN.Close
    Set rs = Nothing
    Set adoCN = Nothing
End Sub

muygun · 18 Nisan 2019

Merhaba;
Syn. veyselemre'nin kodlarını denemedim ama alternatif olsun.

Tablonuzu hızlandırmak adına yrd. sayfa kullandım. (bu sayfa veri değişikliği olmadığı sürece farklı aylar için hızlı analiz yapmanızı sağlar)
Eki deneyin.
İyi çalışmalar.

Link:
https://dosya.co/low557c980da/ezgi73-sayfa_toplamları-1.rar.html

ezgi73 · 18 Nisan 2019

veyselemre' Alıntı:

Kod:

Sub veriCek()
    Sheets("SON").Select
    yil = [I1]
    ay = [I2]
    Range("A2:F" & Rows.Count).ClearContents
    Set adoCN = CreateObject("ADODB.Connection")
    adoCN.Provider = "Microsoft.ACE.OLEDB.12.0"
    adoCN.Properties("Data Source") = ThisWorkbook.FullName
    adoCN.Properties("Extended Properties") = "Excel 12.0; HDR=NO"
    adoCN.Open
    Set rs = CreateObject("Adodb.RecordSet")

    son1 = Sheets("1").Cells(Rows.Count, 1).End(3).Row
    son2 = Sheets("2").Cells(Rows.Count, 1).End(3).Row
    son3 = Sheets("3").Cells(Rows.Count, 1).End(3).Row
    son4 = Sheets("4").Cells(Rows.Count, 1).End(3).Row

    strsql = "SELECT tar, SUM(top1), SUM(top2), SUM(top3), SUM(top4), SUM(top5) FROM " & _
             "(" & _
             "SELECT F1 AS tar, F4 AS top1, F7 AS top2, F8 AS top3, F9 AS top4, 0 AS top5 FROM [1$A2:I" & son1 & "] UNION " & _
             "SELECT F1 AS tar, (F4+F5+F6) AS top1, F11 AS top2, F12 AS top3, F14 AS top4, F15 AS top5  FROM [2$A2:O" & son2 & "] UNION " & _
             "SELECT F1 AS tar, (F4+F5+F6) AS top1, F11 AS top2, F12 AS top3, F14 AS top4, F15 AS top5  FROM [3$A2:O" & son3 & "] UNION " & _
             "SELECT F1 AS tar, (F4+F5+F6) AS top1, F11 AS top2, F12 AS top3, F14 AS top4, F15 AS top5  FROM [4$A2:O" & son4 & "] " & _
             ") " & _
             "GROUP BY tar HAVING MONTH(tar)=" & ay & " AND YEAR(tar)=" & yil & " ORDER BY tar"
    rs.Open strsql, adoCN, 1, 1

    [a2].CopyFromRecordset rs
    rs.Close
    adoCN.Close
    Set rs = Nothing
    Set adoCN = Nothing
End Sub

sayın hocam bu kodtta debug hatası verdi anlayamadım
rs.Open strsql, adoCN, 1, 1

veyselemre · 18 Nisan 2019

ay rakamla yazın

ezgi73 · 18 Nisan 2019

muygun' Alıntı:
Merhaba;
Syn. veyselemre'nin kodlarını denemedim ama alternatif olsun.

Tablonuzu hızlandırmak adına yrd. sayfa kullandım. (bu sayfa veri değişikliği olmadığı sürece farklı aylar için hızlı analiz yapmanızı sağlar)
Eki deneyin.
İyi çalışmalar.

Link:
https://dosya.co/low557c980da/ezgi73-sayfa_toplamları-1.rar.html

çok teşekür ederim hocam ellerinize sağlık sağolun varolun istediğim gibi oldu

muygun · 18 Nisan 2019

Ayrıca syn. veyselemre'nin kodlarında ;
yıl ve ay için;
yil = [H1]
ay = [H2]
şeklinde düzenleme yaparsanız sonuç alırsınız.

ezgi73 · 18 Nisan 2019

veyselemre' Alıntı:
ay rakamla yazın

şimdi oldu yüreğinize sağlık saygılarımla

Soru Sayfalardan Toplama

ezgi73

veyselemre

Özel Üye

ezgi73

muygun

Özel Üye

Ekli dosyalar

ezgi73

muygun

Özel Üye

ezgi73

veyselemre

Özel Üye

muygun

Özel Üye

Ekli dosyalar

ezgi73

veyselemre

Özel Üye

ezgi73

muygun

Özel Üye

ezgi73